Virtual Private Cloud：VPC對等串連

建立對等串連

1. 調用CreateVpcPeerConnection建立VPC對等串連。

2. 兩端VPC屬於不同帳號時，需使用接收端帳號調用AcceptVpcPeerConnection接受VPC對等串連。

   接收端可以調用RejectVpcPeerConnection拒絕VPC對等串連。

3. 使用兩端 VPC 所屬帳號，分別調用GetVpcPeerConnectionAttribute查詢兩端VPC的網段。

4. 使用兩端 VPC 所屬帳號，分別調用CreateRouteEntry建立指向對等串連的路由條目。

修改跨地區對等串連

調用ModifyVpcPeerConnection修改跨地區VPC對等串連的頻寬或鏈路類型。

刪除對等串連

• 調用DeleteRouteEntry刪除指向對等串連的路由條目。

• 調用DeleteVpcPeerConnection刪除VPC對等串連。

路徑分析

依次調用以下API來使用路徑分析校正連通性。

1. 建立網路分析路徑

2. 建立網路可達性分析任務

3. 擷取網路可達性分析任務結果

同帳號對等串連

Resources：alicloud_vpc_peer_connection、alicloud_route_entry

Data Sources：alicloud_account

# VPC所屬帳號
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" #發起端VPC所屬地區。
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" #接收端地區。可以和發起端地區相同，需要根據接收端VPC所屬地區配置。
}

# 發起端VPC ID
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# 接收端VPC ID
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# 建立VPC對等串連
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # 發起端VPC ID
  accepting_ali_uid    = data.alicloud_account.default.id # 接收端帳號 ID   
  accepting_region_id  = "cn-beijing"                     # 接收端VPC所屬地區
  accepting_vpc_id     = var.accepting_vpc_id             # 接收端VPCID
  bandwidth            = 1024                             # 頻寬，單位：Mbps。僅發起端地區和接收端地區不同時，可以配置。
  link_type            = "Gold"                           # 鏈路類型，僅發起端地區和接收端地區不同時，可以配置。
}

# 為發起端VPC配置路由
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # 發起端執行個體所屬交換器綁定的路由表
  destination_cidrblock = "172.16.0.0/12"             # 接收端VPC網段
  nexthop_type          = "VpcPeer"                   # 下一跳為VPC對等串連
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 為接收端VPC配置路由
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # 接收端執行個體所屬交換器綁定的路由表
  destination_cidrblock = "10.0.0.0/8"                # 發起端VPC網段
  nexthop_type          = "VpcPeer"                   # 下一跳為VPC對等串連
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

跨帳號對等串連

Resources：alicloud_vpc_peer_connection、alicloud_vpc_peer_connection_accepter、alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" #發起端地區 
}

#接收端地區。可以和發起端地區相同，需要根據接收端VPC所屬地區配置。
variable "accepting_region" {
  default = "cn-beijing"
}

#接收端帳號
variable "accepting_uid" {
  default = "1234******"
}

#接收端帳號AK
variable "access_key_id" {
  description = "The AccessKey ID for operating your infrastructure"
}
#接收端帳號SK
variable "access_key_secret" {
  description = "The AccessKey Secret for operating your infrastructure"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# 發起端VPC ID
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# 接收端VPC ID
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# 建立VPC對等串連
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # 發起端VPC ID
  accepting_ali_uid    = var.accepting_uid    # 接收端帳號ID   
  accepting_region_id  = var.accepting_region # 接收端地區
  accepting_vpc_id     = var.accepting_vpc_id # 接收端VPC ID
  bandwidth            = 1024                 # 頻寬，單位：Mbps。僅發起端地區和接收端地區不同時，可以配置。
  link_type            = "Gold"               # 鏈路類型，僅發起端地區和接收端地區不同時，可以配置。
}

# 接收端接受對等串連請求
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 為發起端VPC配置路由
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # 發送端執行個體所屬交換器綁定的路由表
  destination_cidrblock = "192.168.0.0/24" # 接收端VPC網段
  nexthop_type          = "VpcPeer"        # 下一跳為VPC對等串連
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 為接收端VPC配置路由
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # 接收端執行個體所屬交換器綁定的路由表
  destination_cidrblock = "172.16.0.0/12"  # 發起端VPC網段
  nexthop_type          = "VpcPeer"        # 下一跳為VPC對等串連
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

對等串連監控

1. 前往專用網路控制台 - VPC對等串連，在頁面上方選擇VPC所在的地區。

2. 單擊目標跨地區VPC對等串連執行個體監控列的表徵圖，查看流量頻寬與丟包情況等監控資訊。

CloudMonitor警示

1. 前往CloudMonitor控制台 - 警示規則，單擊建立警示規則。

2. 為VPC對等串連的監控指標項配置各警示層級的閾值，當相應指標達到閾值後，報警聯繫人組將接收到警示通知，也可以在目標警示規則的操作列，點擊報警歷史查看警示時間軸。

3. 在目標警示規則的操作列，修改/禁用/刪除規則。