Virtual Private Cloud:VPC peering connection

ピアリング接続の作成

1. CreateVpcPeerConnection を呼び出して VPC ピアリング接続を作成します。

2. 2 つの VPC が異なるアカウントに属している場合、受信側アカウントの所有者は AcceptVpcPeerConnection を呼び出して VPC ピアリング接続を承諾する必要があります。

   受信側は RejectVpcPeerConnection を呼び出して VPC ピアリング接続を拒否することもできます。

3. 各アカウントから GetVpcPeerConnectionAttribute を呼び出して、もう一方の VPC の CIDR ブロックをクエリします。

4. 各アカウントから CreateRouteEntry を呼び出して、ピアリング接続を指すルートエントリを作成します。

リージョン間ピアリング接続の変更

ModifyVpcPeerConnection を呼び出して、リージョン間 VPC ピアリング接続の帯域幅またはリンクタイプを変更します。

ピアリング接続の削除

• DeleteRouteEntry を呼び出して、ピアリング接続を指すルートエントリを削除します。

• DeleteVpcPeerConnection を呼び出して、VPC ピアリング接続を削除します。

ネットワーク到達性分析

ネットワーク到達性分析を使用して接続性を検証するには、以下の API オペレーションを順番に呼び出します。

1. ネットワーク分析パスの作成

2. ネットワーク到達性分析タスクの作成

3. ネットワーク到達性分析タスクの結果の取得

同一アカウントのピアリング接続

リソース：alicloud_vpc_peer_connection、alicloud_route_entry

データソース：alicloud_account

# VPC を所有するアカウント。
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元 VPC のリージョン。
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # 受信側 VPC のリージョン。リクエスト元リージョンと同じでもかまいません。
}

# リクエスト元 VPC の ID。
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# 受信側 VPC の ID。
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# VPC ピアリング接続を作成します。
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # リクエスト元 VPC の ID。
  accepting_ali_uid    = data.alicloud_account.default.id # 受信側アカウントの ID。   
  accepting_region_id  = "cn-beijing"                     # 受信側 VPC のリージョン。
  accepting_vpc_id     = var.accepting_vpc_id             # 受信側 VPC の ID。
  bandwidth            = 1024                             # 帯域幅 (Mbps)。このパラメーターはリージョン間接続でのみ設定できます。
  link_type            = "Gold"                           # リンクタイプ。このパラメーターはリージョン間接続でのみ設定できます。
}

# リクエスト元 VPC のルートを設定します。
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # リクエスト元インスタンスの vSwitch に関連付けられたルートテーブル。
  destination_cidrblock = "172.16.0.0/12"             # 受信側 VPC の CIDR ブロック。
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続です。
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 受信側 VPC のルートを設定します。
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # 受信側インスタンスの vSwitch に関連付けられたルートテーブル。
  destination_cidrblock = "10.0.0.0/8"                # リクエスト元 VPC の CIDR ブロック。
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続です。
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

クロスアカウントのピアリング接続

リソース：alicloud_vpc_peer_connection、alicloud_vpc_peer_connection_accepter、alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元リージョン。 
}

# 受信側リージョン。リクエスト元リージョンと同じでもかまいません。
variable "accepting_region" {
  default = "cn-beijing"
}

# 受信側アカウント。
variable "accepting_uid" {
  default = "1234******"
}

# 受信側アカウントの AccessKey ID。
variable "access_key_id" {
  description = "The AccessKey ID for operating your infrastructure"
}
# 受信側アカウントの AccessKey Secret。
variable "access_key_secret" {
  description = "The AccessKey Secret for managing your infrastructure"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# リクエスト元 VPC の ID。
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# 受信側 VPC の ID。
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# VPC ピアリング接続を作成します。
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # リクエスト元 VPC の ID。
  accepting_ali_uid    = var.accepting_uid    # 受信側アカウントの ID。
  accepting_region_id  = var.accepting_region # 受信側リージョン。
  accepting_vpc_id     = var.accepting_vpc_id # 受信側 VPC の ID。
  bandwidth            = 1024                 # 帯域幅 (Mbps)。このパラメーターはリージョン間接続でのみ設定できます。
  link_type            = "Gold"               # リンクタイプ。このパラメーターはリージョン間接続でのみ設定できます。
}

# 受信側がピアリング接続リクエストを承諾します。
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# リクエスト元 VPC のルートを設定します。
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # リクエスト元インスタンスの vSwitch に関連付けられたルートテーブル。
  destination_cidrblock = "192.168.0.0/24" # 受信側 VPC の CIDR ブロック。
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続です。
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 受信側 VPC のルートを設定します。
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # 受信側インスタンスの vSwitch に関連付けられたルートテーブル。
  destination_cidrblock = "172.16.0.0/12"  # リクエスト元 VPC の CIDR ブロック。
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続です。
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

ピアリング接続の監視

1. VPC コンソール - VPC ピアリング接続ページに移動します。上部のナビゲーションバーで、VPC があるリージョンを選択します。

2. 対象のリージョン間 VPC ピアリング接続インスタンスの モニター 列で、 アイコンをクリックして、トラフィック、帯域幅、パケット損失などのメトリックを表示します。

CloudMonitor アラート

1. CloudMonitor コンソール - アラートルールページに移動し、アラームルールを作成 をクリックします。

2. VPC ピアリング接続メトリックの各アラートレベルにしきい値を設定します。メトリックがしきい値に達すると、アラーム連絡先グループ は通知を受信します。また、アラートルールの アクション 列にある アラーム履歴 をクリックすると、そのアラートタイムラインを表示できます。

3. アラートルールの アクション 列から、Modify、無効化、または 削除 を行うことができます。