Virtual Private Cloud:VPC と vSwitch

コンソール

API

コンソールとは異なり、CreateVpc 操作は空の VPC のみを作成します。vSwitch を作成するには、CreateVSwitch 操作を呼び出す必要があります。

• CreateVpc と CreateVSwitch を順番に呼び出して、VPC と vSwitch を作成します。

• DeleteVSwitch と DeleteVpc を順番に呼び出して、vSwitch と VPC を削除します。

  1. vSwitch を削除する前に、vSwitch が共有されておらず、カスタムルートテーブルやネットワーク ACL に関連付けられておらず、クラウドリソースが含まれていないことを確認してください。

  2. VPC を削除する前に、VPC 内のすべてのリソースがリリースされ、VPC が Cloud Enterprise Network (CEN) などのネットワークサービスに関連付けられていないことを確認してください。

Terraform

リソース: alicloud_vpc, alicloud_vswitch

データソース: alicloud_zones

# VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースを使用して、vSwitch を作成できるゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC で vSwitch を作成できるゾーンをクエリします。
  # available_instance_type = "ecs.g7.large"  # VPC で ECS インスタンスを作成できるゾーンをクエリします。
  # available_resource_creation = "slb"  # VPC で SLB インスタンスを作成できるゾーンをクエリします。
}

# VPC を作成します。 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # CIDR ブロックを指定します。 
}

# vSwitch を作成します。 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # CIDR ブロックを指定します。 
  vpc_id       = alicloud_vpc.example_vpc.id                       # vSwitch が属する VPC の ID を指定します。 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # vSwitch が属するゾーンを指定します。
}

コンソール

API

コンソールとは異なり、API を介して IPv6 を有効にしても、IPv6 ゲートウェイは自動的に作成されません。IPv6 ゲートウェイを作成するには、CreateIpv6Gateway を呼び出す必要があります。

• VPC と vSwitch を作成する際に、CreateVpc および CreateVSwitch API 呼び出しで EnableIPv6 パラメーターを設定して、IPv6 を有効または無効にします。Ipv6IpamPoolId と Ipv6CidrMask を渡すと、IPv6 アドレスプールから VPC に IPv6 CIDR ブロックが割り当てられます。

• 既存の VPC と vSwitch の場合、ModifyVpcAttribute と ModifyVSwitchAttribute の EnableIPv6 パラメーターを変更して、IPv6 を有効または無効にします。IPv6 アドレスプールから VPC に IPv6 CIDR ブロックを割り当てるには、AssociateVpcCidrBlock を呼び出します。

Terraform

Terraform は現在、システム割り当ての IPv6 CIDR ブロックのみをサポートしており、IPAM からの割り当てはまだサポートしていません。

リソース: alicloud_vpc, alicloud_vswitch

データソース: alicloud_zones

# VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースを使用して、vSwitch を作成できるゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC で vSwitch を作成できるゾーンをクエリします。
  # available_instance_type = "ecs.g7.large"  # VPC で ECS インスタンスを作成できるゾーンをクエリします。
  # available_resource_creation = "slb"  # VPC で SLB インスタンスを作成できるゾーンをクエリします。
}

# デュアルスタック VPC を作成します。 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # IPv6 を有効にします。値を false に設定すると IPv6 が無効になります。
  ipv6_isp    = "BGP" # IPv6 CIDR ブロックのタイプを指定します。
}

# デュアルスタック vSwitch を作成します。 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # IPv6 を有効にします。値を false に設定すると IPv6 が無効になります。
  ipv6_cidr_block_mask = 1    # vSwitch の IPv6 CIDR ブロックの最後の 8 ビットを指定します。 
} 

コンソール

API

• CreateVSwitchCidrReservation 操作を呼び出して、予約済み CIDR ブロックを作成します。

• GetVSwitchCidrReservationUsage 操作を呼び出して、使用済み IP を表示します。

• DeleteVSwitchCidrReservation 操作を呼び出して、予約済み CIDR ブロックを削除します。

Terraform

リソース: alicloud_vpc_vswitch_cidr_reservation

# VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou" # リソースが存在するリージョン。
}

# vSwitch の ID を指定します。
variable "vsw_id" {
  default = "vsw-xxx" # 値を実際の vSwitch の ID に置き換えます。
}

# 予約済み CIDR ブロックを作成します。
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 予約済み CIDR ブロックを指定します。 
}

コンソール

VPC を作成する前に、IPAM コンソールで IPAM インスタンスとプールを作成していることを確認してください。

1. VPC コンソールの [VPC の作成] ページに移動します。

2. IPv4 CIDR ブロックの設定: [IPAM によって割り当てられた IPv4 CIDR ブロック] オプションを選択します。IPAM プールを選択し、マスクを設定します。システムは、デフォルトで長さに一致する最初の利用可能な CIDR ブロックを割り当てます。プールのプロビジョニングされた CIDR ブロック内で別の IPv4 CIDR ブロックを選択できます。

3. IPv6 の有効化 (必要な場合): [IPAM によって割り当てられた IPv6 CIDR ブロック] を選択します。IPv6 IPAM プールを選択し、マスクを設定するか、IPv6 CIDR ブロックを指定します。

API

• IPAM プールを作成済みの場合は、次のいずれかの方法を選択します。

  • IPv4 の割り当ての場合: CreateVpc 操作を呼び出し、Ipv4IpamPoolId パラメーターを使用して IPAM プールを指定し、Ipv4CidrMask パラメーターを使用してマスクを指定します。または、使用したい正確な CIDR を CidrBlock パラメーターで指定することもできます。

  • IPv6 の割り当ての場合: CreateVpc 呼び出しで Ipv6IpamPoolId と Ipv6CidrMask の両方のパラメーターを指定します。

• IPAM プールを作成していない場合は、次の操作を順番に呼び出して IPAM プールを作成し、その後 VPC を作成します。

  1. OpenVpcIpamService - IPAM 機能のアクティブ化

  2. CreateIpam - IPAM インスタンスの作成

  3. CreateIpamPool - IPAM プールの作成

  4. AddIpamPoolCidr - IPAM プールへの CIDR ブロックのプロビジョニング

Terraform

Terraform は現在、IPAM プールからの IPv4 CIDR ブロックの割り当てのみをサポートしています。IPv6 の割り当てはサポートされていません。

リソース: vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# IPAM インスタンス、IPAM プール、VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# IPAM インスタンスを作成します。
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # IPAM インスタンスが有効になるリージョンを指定します。
}

# IPAM プールを作成します。
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # IPAM プールのスコープを指定します。
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # IPAM プールが有効になるリージョンを指定します。
  ip_version     = "IPv4"                                     # IPAM プールの IP バージョンを指定します。
}

# IPAM プールに CIDR ブロックを割り当てます。
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # CIDR ブロックを指定します。
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # IPAM プールの ID を指定します。
}

# VPC を作成します。
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # IPAM プールの ID を指定します。
  ipv4_cidr_mask    = 24                                                 # IPv4 ネットワークマスク。
}