Edge Security Acceleration:Terraform を使用したウェイティングルームの設定

Terraform のインストールと権限の設定

リソース

• サイトの作成： alicloud_esa_site

• ウェイティングルームの作成： alicloud_esa_waiting_room

• ESA インスタンスの照会： alicloud_esa_sites

操作手順

1. ウェイティングルームを設定するために、main.tf という名前のファイルを作成し、次のコードを追加します：

   # 1. Enterprise 版 ESA インスタンスの照会
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # Enterprise 版インスタンスをフィルタリング
   }
   
   # 2. サイトの作成
   resource "alicloud_esa_site" "resource_Site_example" {
     site_name   = "{{DOMAIN}}"  # ご利用のドメイン名 (例: example.com) に置き換えます
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # 海外アクセラレーション
     access_type = "NS"         # NS アクセスモード
   }
   
   # 3. ウェイティングルームの作成
   resource "alicloud_esa_waiting_room" "default" {
     site_id                        = alicloud_esa_site.resource_Site_example.id
     waiting_room_name              = "waitingroom_example"  # ウェイティングルーム名
     description                    = "example"
     status                         = "off"  # デフォルトでは無効。手動で有効にする必要があります。
     waiting_room_type              = "default"
   
     # キューイングポリシーの設定
     queuing_method                 = "fifo"  # FIFO キューイング方式
     session_duration               = "5"    # セッション期間 (分)
     total_active_users             = "300"  # 最大同時接続ユーザー数
     new_users_per_minute           = "200"  # 1分あたりに入室を許可する新規ユーザー数
   
     # マッチングルール：キューイングをトリガーする条件
     host_name_and_path {
       domain    = "sub_domain.com"         # マッチングするホスト名
       path      = "/example"                # マッチングするパス
       subdomain = "example_sub_domain.com."  # マッチングするサブドメイン
     }
   
     # ページ表示設定
     language                       = "zhcn"  # キューイングページの言語：簡体字中国語
     custom_page_html               = ""      # 空の値はデフォルトのキューイングページを使用
     queuing_status_code            = "200"   # キューイング中に返される HTTP ステータスコード
     cookie_name                    = "__aliwaitingroom_example"  # クッキー名
   
     # 詳細オプション
     queue_all_enable               = "off"  # すべてのユーザーをキューに入れるかどうかを指定
     disable_session_renewal_enable = "off"  # セッション更新を無効にするかどうかを指定
     json_response_enable           = "off"  # JSON 応答を返すかどうかを指定
   }

   説明

   コード内のプレースホルダーを実際の値に置き換えてください。DOMAIN をご利用のドメイン名に置き換え、host_name_and_path ブロック内のドメインとパスをキューイング条件に合わせて更新してください。パラメーターの説明については、「関連ドキュメント」セクションをご参照ください。

2. 設定ファイルが含まれるディレクトリに移動します。次に、以下のコマンドを実行して Terraform 環境を初期化します。

   terraform init

   

3. 以下のコマンドを実行して、Terraform ファイルの構文と設定を検証します。

   terraform validate

   出力が次の図のようであれば、検証は成功です。

   

4. 以下のコマンドを実行して、適用される変更をプレビューします。

   terraform plan

5. 以下のコマンドを実行して、Terraform スクリプトを実行します。

   terraform apply

6. プロンプトが表示されたら、yes と入力して操作を確定します。

結果の確認

terraform show

関連ドキュメント

次の表に、コード例で使用されている主要なパラメーターを示します。

パラメーターの詳細については、「alicloud_esa_waiting_room」をご参照ください。

可用性