Terraform:Terraform を使用したリソースの迅速な作成

カスタムパラメーターによるリソースの作成

ご要件に応じてパラメーターを設定するには、以下の手順を実行します：

1. Terraform Explorer にログインします。プロダクト および リソースタイプ を選択します。リソースドキュメント を参照しながらパラメーターを入力し、デバッグ開始 をクリックします。

   VPC 作成の主なパラメーターを以下に示します。その他のパラメーターの詳細については、「alicloud_vpc」をご参照ください。

   パラメーター名	説明	例
   vpc_name	VPC 名	tf-test-vpc
   cidr_block	VPC のプライベート CIDR ブロック	192.168.0.0/16
   description	VPC の説明	Terraform を使用して作成された VPC です。

   

2. テンプレートの詳細 タブで、パラメーターが正しく設定されていることを確認します。プレビュー をクリックして実行計画を表示します。

   

3. プレビューの詳細 タブで、作成されるリソースを確認します。実行 をクリックします。

   

4. 実行の詳細 タブで結果を確認します。正常終了時は「Apply complete! Resources: 1 added, 0 changed, 0 destroyed.」と表示されます。失敗した場合は、パラメーターを調整して再度デバッグを行ってください。

   

5. リソースの詳細 タブで、作成されたリソースの情報を表示します。

   

6. （任意）リソースの変更：パラメーターを調整し、プレビューと実行 をクリックします。手順 2～4 を繰り返します。正常に更新された場合は、「Apply complete! Resources: 0 added, 1 changed, 0 destroyed.」と表示されます。

   

7. （任意）リソースのリリース：実行の詳細 タブで リソースの破棄 をクリックします。その後、プレビューの詳細 タブで 実行 をクリックします。

   

サンプルテンプレートによるリソースの作成

リソースのパラメーターに不慣れな場合や、すぐに始めたい場合は、Terraform Explorer のサンプルテンプレートをご利用ください。

1. Terraform Explorer にログインします。プロダクト、リソースタイプ、および サンプルテンプレート を選択し、デバッグ開始 をクリックします。右側の サンプルテンプレート タブでテンプレートの詳細を表示します。

   

2. テンプレートの詳細 タブで、プレビューと実行 をクリックします。

   

3. 実行の詳細 タブで実行結果を確認します。

   

4. （任意）作成したリソースをリリースするには、実行の詳細 タブで リソースの破棄 をクリックします。その後、プレビューの詳細 タブで 実行 をクリックします。

   

Alibaba Cloud Cloud Shell は無料の運用・保守ツールであり、Terraform がプリインストール済みで、認証情報も事前に設定されています。Terraform コマンドを直接実行できます。

インストールの確認

以下のコマンドを実行して、Terraform が正しくインストールされたことを確認します：

terraform version

コマンドが正常に実行され、バージョン番号が表示された場合、インストールは完了しています。

この例では、ECS インスタンスの作成を通じて、Terraform の完全なオーケストレーションワークフロー（VPC の作成 → vSwitch の作成 → セキュリティグループの作成 → ECS インスタンスの作成）を紹介します。

1. 作業ディレクトリを作成し、Terraform 構成ファイル main.tf を作成します：

   mkdir tf-demo && cd tf-demo
   vim main.tf

   以下のコードを main.tf にコピーします：

   provider "alicloud" {
     region = var.region
   }
   
   # リソース作成のリージョン
   variable "region" {
     default = "cn-beijing"
   }
   
   # ECS インスタンス名
   variable "instance_name" {
     default = "tf-cloudshell-test"
   }
   
   # ECS インスタンスタイプ
   variable "instance_type" {
     default = "ecs.n2.small"
   }
   
   # 外向きパブリック帯域幅（値 0 はパブリックネットワークへのアクセス不可を意味します）
   variable "internet_bandwidth" {
     default = 10
   }
   
   # ECS OS イメージ
   variable "image_id" {
     default = "ubuntu_18_04_64_20G_alibase_20190624.vhd"
   }
   
   # ECS システムディスクタイプ
   variable "disk_category" {
     default = "cloud_efficiency"
   }
   # ECS インスタンスのログインパスワード
   variable "password" {
     default = "TF-test@1234"
   }
   
   # VPC の作成
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "tf_test_foo"
     cidr_block = "172.16.0.0/12"
   }
   
   # インスタンスタイプおよびディスクカテゴリに基づいて利用可能なゾーンを照会
   data "alicloud_zones" "default" {
     available_disk_category     = var.disk_category
     available_resource_creation = "VSwitch"
     available_instance_type     = var.instance_type
   }
   
   # vSwitch の作成
   resource "alicloud_vswitch" "vsw" {
     vpc_id     = alicloud_vpc.vpc.id
     cidr_block = "172.16.0.0/21"
     zone_id    = data.alicloud_zones.default.zones.0.id
   }
   
   # セキュリティグループの作成
   resource "alicloud_security_group" "default" {
     security_group_name   = "default"
     vpc_id = alicloud_vpc.vpc.id
   }
   
   # セキュリティグループへのインバウンドルールの作成
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.default.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   resource "alicloud_instance" "instance" {
     # セキュリティグループのアタッチ
     security_groups = alicloud_security_group.default.*.id
     instance_type = var.instance_type
     system_disk_category = var.disk_category
     image_id = var.image_id
     instance_name = var.instance_name
     # vSwitch
     vswitch_id = alicloud_vswitch.vsw.id
     internet_max_bandwidth_out = var.internet_bandwidth
     password  = var.password
   }

   重要

   この例のセキュリティグループルールでは、すべての TCP ポート（1～65535）が開放され、任意の IP アドレス（0.0.0.0/0）からのトラフィックが許可されています。これはテスト環境でのみ使用してください。本番環境では、必要なポートおよび送信元 IP アドレスを適切に制限してください。

2. Terraform 作業ディレクトリを初期化します：

   terraform init

3. どのリソースが作成されるかを確認するため、実行計画をプレビューします：

   terraform plan

   

4. リソースを作成します。「Apply complete!」という出力が表示された場合、成功です：

   terraform apply

   

5. これらのリソースをリリースするには、以下のコマンドを実行します：

   terraform destroy