すべてのプロダクト
Search

このプロダクト

    ApsaraMQ for Kafka:Terraform を使用してコンシューマーグループを管理する

    ドキュメントセンター

    ApsaraMQ for Kafka:Terraform を使用してコンシューマーグループを管理する

    最終更新日:Feb 07, 2025

    このトピックでは、Terraform によって提供される alicloud_alikafka_consumer_group リソースを使用して、ApsaraMQ for Kafka でコンシューマーグループを作成および管理する方法について説明します。

    説明

    このトピックのサンプルコードは、数クリックで実行できます。こちら をクリックしてサンプルコードを実行してください。

    始める前に

    • デフォルトでは、Alibaba Cloud アカウントは、このアカウントに属するすべてのリソースに対するフル 権限 を持っています。 Alibaba Cloud アカウントの資格情報が漏洩した場合、セキュリティリスクが発生する可能性があります。Resource Access Management（RAM）ユーザーを使用し、RAM ユーザーの AccessKey ペアを作成することをお勧めします。 詳細については、「RAM ユーザーを作成する」および「AccessKey ペアを作成する」をご参照ください。

    • RAM を使用して、クラウドリソースへのアクセス 権限 を効率的に管理する必要があります。これは、マルチユーザーコラボレーションの要件を満たすのに役立ち、過剰な 権限 によって引き起こされるセキュリティの脆弱性を防ぐために、最小 権限 の原則に基づいてユーザーに 権限 を付与することを可能にします。 詳細については、「RAM ユーザーに権限を付与する」をご参照ください。

      {
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "ecs:CreateSecurityGroup",
                "ecs:ModifySecurityGroupPolicy",
                "ecs:DescribeSecurityGroups",
                "ecs:ListTagResources",
                "ecs:DeleteSecurityGroup",
                "ecs:DescribeSecurityGroupAttribute",
                "ecs:AuthorizeSecurityGroup",
                "ecs:RevokeSecurityGroup"
            ],
            "Resource": "*"
        },
        {
            "Action": "alikafka:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "connector.alikafka.aliyuncs.com",
                        "instanceencryption.alikafka.aliyuncs.com",
                        "alikafka.aliyuncs.com",
                        "etl.alikafka.aliyuncs.com"
                    ]
                }
            }
        }
    ]
}

    • 次のいずれかの方法を使用して、Terraform の実行環境を準備します。

      • Terraform Explorer で Terraform を使用する: Alibaba Cloud は、Terraform のオンライン実行環境である Terraform Explorer を提供しています。 Terraform Explorer にログインすれば、Terraform をインストールすることなく使用できます。 この方法は、追加費用なしで Terraform を迅速かつ便利に使用およびデバッグしたい場合に適しています。

      • Cloud Shell で Terraform を使用する: Terraform は Cloud Shell にプリインストールされており、ID 資格情報は構成済みです。 Cloud Shell で Terraform コマンドを実行できます。 この方法は、低コストで Terraform を迅速かつ便利に使用およびデバッグしたい場合に適しています。

      • オンプレミス マシンに Terraform をインストールして構成する: この方法は、ネットワーク接続が不安定な場合、またはカスタム開発環境が必要な場合に適しています。

    必要なリソース

    説明

    このトピックで必要な特定のリソースに対して課金されます。 リソースが不要になった場合は、できるだけ早くリソースを解放するか、サブスクライブを解除してください。

    コンシューマーグループを作成する

    次の例では、中国 (深セン) リージョンに tf-example という名前のコンシューマーグループが作成されます。 コンシューマーグループを作成した後、コンシューマーグループの名前を変更することはできません。

    1. 作業ディレクトリと、そのディレクトリに main.tf という名前の構成ファイルを作成します。 次のコードを main.tf 構成ファイルにコピーします。

      • 必要なリソースを作成します。

        variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

# VPC を作成します。
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# vSwitch を作成します。
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# インスタンスを作成します。 ディスクタイプは Ultra ディスク、ディスク容量は 500 GB、トラフィック仕様は alikafka.hw.2xlarge です。
# インスタンスをデプロイします。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

      • main.tf 構成ファイルに、resource "alicloud_alikafka_consumer_group" "default" 設定項目を追加します。

        variable "group_name" {
  default = "tf-example"
}

resource "alicloud_alikafka_consumer_group" "default" {
  consumer_id = var.group_name
  instance_id = alicloud_alikafka_instance.default.id
}

    2. 次のコマンドを実行して、Terraform の実行環境を初期化します。

      terraform init

      次の情報が返された場合、Terraform は初期化されています。

      Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other

    3. 実行計画を作成し、変更をプレビューします。

      terraform plan

    4. 次のコマンドを実行して、リソースを作成します。

      terraform apply

      実行中に、プロンプトが表示されたら yes と入力し、[enter] キーを押します。 コマンドが実行されるまで待ちます。 次の情報が表示された場合、操作は成功です。

      alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the
following symbols:
  + create

Terraform will perform the following actions:

  # alicloud_alikafka_consumer_group.default will be created
  + resource "alicloud_alikafka_consumer_group" "default" {
      + consumer_id = "tf-example"
      + id          = (known after apply)
      + instance_id = "alikafka_post-cn-****"
    }

Plan: 1 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_alikafka_consumer_group.default: Creating...
alicloud_alikafka_consumer_group.default: Creation complete after 2s [id=alikafka_post-cn-****:tf-example]

Apply complete!  Resources: 1 added, 0 changed, 0 destroyed.

    5. 結果を確認します。

      terraform show コマンドを実行する

      terraform show コマンドを実行して、コンシューマーグループに関する情報を表示します。

      terraform show
      # alicloud_alikafka_consumer_group.default:
resource "alicloud_alikafka_consumer_group" "default" {
    consumer_id = "tf-example"
    description = null
    id          = "alikafka_post-cn-****:tf-example"
    instance_id = "alikafka_post-cn-****"
}

      ApsaraMQ for Kafka コンソールを使用する

      ApsaraMQ for Kafka コンソール にログインして、コンシューマーグループに関する情報を表示します。image

    コンシューマーグループをクエリする

    1. main.tf 構成ファイルに、data "alicloud_alikafka_consumer_groups" "consumer_groups_ds" 設定項目を追加し、次のコードスニペットに基づいて設定項目を構成します。

      data "alicloud_alikafka_consumer_groups" "consumer_groups_ds" {
  instance_id = alicloud_alikafka_instance.default.id
}

    2. 実行計画を作成し、変更をプレビューします。

      terraform plan

    3. 次のコマンドを実行して、リソースを作成します。

      terraform apply

      実行中に、プロンプトが表示されたら yes と入力し、[enter] キーを押します。コマンドが実行されるまで待ちます。次の情報が表示された場合、操作は成功です。

      alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]
alicloud_alikafka_consumer_group.default: Refreshing state... [id=alikafka_post-cn-****:tf-example]
data.alicloud_alikafka_consumer_groups.consumer_groups_ds: Reading...
data.alicloud_alikafka_consumer_groups.consumer_groups_ds: Read complete after 1s [id=****]

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are
needed.

Apply complete!  Resources: 0 added, 0 changed, 0 destroyed.

    4. 結果を確認します。 terraform show コマンドを実行して、コンシューマーグループに関する情報を表示します。

      terraform show
      # data.alicloud_alikafka_consumer_groups.consumer_groups_ds:
data "alicloud_alikafka_consumer_groups" "consumer_groups_ds" {
    groups      = [
        {
            consumer_id = "tf-example"
            id          = "alikafka_post-cn-****:tf-example"
            instance_id = "alikafka_post-cn-****"
            remark      = null
            tags        = {}
        },
    ]
    id          = "****"
    ids         = [
        "alikafka_post-cn-****:tf-example",
    ]
    instance_id = "alikafka_post-cn-****"
    names       = [
        "tf-example",
    ]
}

    リソースをクリアする

    Terraform を使用して作成または管理された上記の不要なリソースがある場合は、次のコマンドを実行してリソースを解放します。 terraform destroy コマンドの詳細については、「共通コマンド」をご参照ください。

    terraform destroy

    サンプルコード

    説明

    このトピックのサンプルコードは、数クリックで実行できます。 こちら をクリックしてサンプルコードを実行してください。

    サンプルコード

    variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

variable "group_name" {
  default = "tf-example"
}

provider "alicloud" {
  region = var.region
}

# VPC を作成します。
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# vSwitch を作成します。
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# インスタンスを作成します。ディスクタイプは Ultra ディスク、ディスク容量は 500 GB、トラフィック仕様は alikafka.hw.2xlarge です。
# インスタンスをデプロイします。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

resource "alicloud_alikafka_consumer_group" "default" {
  consumer_id = var.group_name
  instance_id = alicloud_alikafka_instance.default.id
}

data "alicloud_alikafka_consumer_groups" "consumer_groups_ds" {
  instance_id = alicloud_alikafka_instance.default.id
  depends_on  = [alicloud_alikafka_consumer_group.default]
}

    関連情報

    • ApsaraMQ for Kafka コンソールで、または API オペレーションを呼び出すことによって、コンシューマーグループを管理することもできます。 詳細については、「手順 3: リソースを作成する」および「CreateConsumerGroup」をご参照ください。

    • alicloud_alikafka_consumer_group リソースによって提供される他の引数の詳細については、「alicloud_alikafka_consumer_group」をご参照ください。