Edge Security Acceleration:Configure a waiting room with Terraform

Install Terraform and configure permissions

Resources

• Create a site: alicloud_esa_site

• Create a waiting room: alicloud_esa_waiting_room

• Query ESA instances: alicloud_esa_sites

Procedure

1. To configure the waiting room, create a file named main.tf and add the following code:

   # 1. Query for Enterprise ESA instances
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # Filter for Enterprise instances
   }
   
   # 2. Create a site
   resource "alicloud_esa_site" "resource_Site_example" {
     site_name   = "{{DOMAIN}}"  # Replace with your domain name, such as example.com
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # Overseas acceleration
     access_type = "NS"         # NS access mode
   }
   
   # 3. Create a waiting room
   resource "alicloud_esa_waiting_room" "default" {
     site_id                        = alicloud_esa_site.resource_Site_example.id
     waiting_room_name              = "waitingroom_example"  # Waiting room name
     description                    = "example"
     status                         = "off"  # Disabled by default. Must be enabled manually.
     waiting_room_type              = "default"
   
     # Queuing policy configuration
     queuing_method                 = "fifo"  # FIFO queuing method
     session_duration               = "5"    # Session duration (minutes)
     total_active_users             = "300"  # Maximum concurrent users
     new_users_per_minute           = "200"  # Number of new users admitted per minute
   
     # Matching rule: Conditions that trigger queuing
     host_name_and_path {
       domain    = "sub_domain.com"         # Hostname to match
       path      = "/example"                # Path to match
       subdomain = "example_sub_domain.com."  # Subdomain to match
     }
   
     # Page display configuration
     language                       = "zhcn"  # Queuing page language: Simplified Chinese
     custom_page_html               = ""      # An empty value uses the default queuing page
     queuing_status_code            = "200"   # HTTP status code returned during queuing
     cookie_name                    = "__aliwaitingroom_example"  # Cookie name
   
     # Advanced options
     queue_all_enable               = "off"  # Specifies whether to queue all users
     disable_session_renewal_enable = "off"  # Specifies whether to disable session renewal
     json_response_enable           = "off"  # Specifies whether to return a JSON response
   }

   Note

   Replace the placeholders in the code with your actual values. Replace DOMAIN with your domain name, and update the domain and path in the host_name_and_path block to match your queuing conditions. For a description of the parameters, see the References section.

2. Navigate to the directory that contains the configuration files. Then, run the following command to initialize the Terraform environment.

   terraform init

   

3. Run the following command to validate the syntax and configuration of the Terraform files.

   terraform validate

   If the output is similar to the following figure, the validation is successful.

   

4. Run the following command to preview the changes that will be applied.

   terraform plan

5. Run the following command to execute the Terraform script.

   terraform apply

6. When prompted, enter yes to confirm the operation.

Verify the results

terraform show

References

The following table describes the key parameters used in the code example.

For more details on the parameters, see alicloud_esa_waiting_room.

Availability