使用Terraform從備份恢複RDS PostgreSQL執行個體-雲資料庫 RDS-阿里雲

本文介紹如何使用Terraform恢複執行個體。

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

前提條件

已建立RDS PostgreSQL執行個體，詳情請參見建立RDS PostgreSQL執行個體。
執行個體狀態為運行中，您可以通過如下兩種方式查看：
- 參見查詢執行個體詳情查看參數status，如果取值為Runing則表示執行個體狀態為運行中。
- 前往RDS管理主控台，切換到目標地區，找到指定執行個體後，查看執行個體狀態。
由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

通過RAM授權，RAM使用者可以有效地管理其雲資源存取權限，適應多使用者協同工作的需求，並且能夠按需為使用者指派最小許可權，避免許可權過大導致的安全性漏洞。具體操作方式請參見為RAM使用者授權。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

使用的資源

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

alicloud_vpc：建立Virtual Private Cloud。
alicloud_vswitch：建立專用網路交換器。
alicloud_db_instance：建立RDS PostgreSQL執行個體。
alicloud_rds_clone_db_instance：按時間點恢複執行個體。

按時間點恢複執行個體

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下代碼複製到main.tf中。

建立前置資源。

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# 建立備份
resource "alicloud_rds_backup" "instance" {
  db_instance_id    = alicloud_db_instance.instance.id
  remove_from_state = true
}

# 查詢備份
data "alicloud_rds_backups" "example" {
  db_instance_id = alicloud_db_instance.instance.id
  depends_on     = [alicloud_rds_backup.instance]
}

在main.tf檔案中增加resource "alicloud_rds_clone_db_instance" "clone_time" {}配置項，具體配置如下。

# 按時間點恢複執行個體
resource "alicloud_rds_clone_db_instance" "clone_time" {
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_description  = "terraform-test-clone"
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 類比擷取查詢結果中backup_end_time的參數取值。
  restore_time             = data.alicloud_rds_backups.example.backups.0.backup_end_time
  db_instance_storage      = "50"
}

說明

restore_time參數配置的取值擷取方法：

在terraform.tf檔案中增加data "alicloud_rds_backups" "example" { db_instance_id = alicloud_db_instance.instance.id}配置項查詢備份。
使用terraform apply執行查詢。
使用terraform show查詢備份資訊，擷取查詢結果中backup_end_time的參數取值。

具體操作，請參見通過Terraform管理RDS PostgreSQL備份。

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_rds_clone_db_instance.example: Creating...
alicloud_rds_clone_db_instance.example: Still creating... [10s elapsed]
...
alicloud_rds_clone_db_instance.example: Still creating... [24m11s elapsed]
alicloud_rds_clone_db_instance.example: Creation complete after 24m34s [id=pgm-****]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

驗證結果。

執行terraform show命令

您可以使用以下命令查看執行個體恢複情況。

terraform show

...
# alicloud_rds_clone_db_instance.example:
resource "alicloud_rds_clone_db_instance" "example" {
    category                 = "HighAvailability"
    connection_string        = "pgm-****.pg.rds.aliyuncs.com"
    db_instance_class        = "pg.n2.2c.2m"
    db_instance_storage      = 50
    db_instance_storage_type = "cloud_essd"
    deletion_protection      = false
    engine                   = "PostgreSQL"
    engine_version           = "13.0"
    ha_mode                  = "RPO"
    id                       = "pgm-****"
    instance_network_type    = "VPC"
    maintain_time            = "18:00Z-22:00Z"
    payment_type             = "PayAsYouGo"
    port                     = "5432"
    private_ip_address       = "192.168.XX.XX"
    restore_time             = "2022-09-29T04:32:59Z"
    security_ips             = [
        "0.0.0.0/0",
    ]
    source_db_instance_id    = "pgm-****"
    sync_mode                = "Async"
    tcp_connection_type      = "LONG"
    vswitch_id               = "vsw-****"
    zone_id                  = "cn-hangzhou-j"
}

登入RDS管理主控台

登入RDS管理主控台查看執行個體恢複情況。恢複執行個體

按備份組恢複執行個體

在main.tf檔案中增加resource "alicloud_rds_clone_db_instance" "clone_id" {}配置項，具體配置如下。
```
...
resource "alicloud_rds_clone_db_instance" "clone_id" {
  db_instance_description  = "terraform-test-clone-1"
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 類比擷取查詢結果中backup_id的參數取值。
  backup_id                = data.alicloud_rds_backups.example.backups.0.backup_id
  db_instance_storage      = "50"
}         
```
說明
backup_id參數配置的取值擷取方法：
- 在terraform.tf檔案中增加data "alicloud_rds_backups" "querybackups" {db_instance_id = alicloud_db_instance.instance.id}配置項查詢備份。
- 使用terraform apply執行查詢。
- 使用terraform show查詢備份資訊，擷取查詢結果中backup_id的參數取值。
具體操作，請參見通過Terraform管理RDS PostgreSQL備份。

執行以下命令。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_rds_clone_db_instance.example: Creating...
alicloud_rds_clone_db_instance.example: Still creating... [10s elapsed]
...
alicloud_rds_clone_db_instance.example: Still creating... [19m31s elapsed]
alicloud_rds_clone_db_instance.example: Creation complete after 19m39s [id=pgm-bp1sox718o31j940]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

驗證結果。

執行terraform show命令

您可以使用以下命令查看執行個體恢複情況。

terraform show

...
# alicloud_rds_clone_db_instance.example:
resource "alicloud_rds_clone_db_instance" "example" {
    backup_id                = "1499356764"
    category                 = "HighAvailability"
    connection_string        = "pgm-****.pg.rds.aliyuncs.com"
    db_instance_class        = "pg.n2.2c.2m"
    db_instance_storage      = 50
    db_instance_storage_type = "cloud_essd"
    deletion_protection      = false
    engine                   = "PostgreSQL"
    engine_version           = "13.0"
    ha_mode                  = "RPO"
    id                       = "pgm-****"
    instance_network_type    = "VPC"
    maintain_time            = "18:00Z-22:00Z"
    payment_type             = "PayAsYouGo"
    port                     = "5432"
    private_ip_address       = "192.168.XX.XX"
    security_ips             = [
        "0.0.0.0/0",
    ]
    source_db_instance_id    = "pgm-****"
    sync_mode                = "Async"
    tcp_connection_type      = "LONG"
    vswitch_id               = "vsw-****"
    zone_id                  = "cn-hangzhou-j"
}

登入RDS管理主控台

登入RDS管理主控台查看執行個體恢複情況。按備份組恢複

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-heyuan"
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# 建立備份
resource "alicloud_rds_backup" "instance" {
  db_instance_id    = alicloud_db_instance.instance.id
  remove_from_state = true
}

# 查詢備份
data "alicloud_rds_backups" "example" {
  db_instance_id = alicloud_db_instance.instance.id
  depends_on     = [alicloud_rds_backup.instance]
}

# 按時間點恢複執行個體
resource "alicloud_rds_clone_db_instance" "clone_time" {
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_description  = "terraform-test-clone"
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 類比擷取查詢結果中backup_end_time的參數取值。
  restore_time             = data.alicloud_rds_backups.example.backups.0.backup_end_time
  db_instance_storage      = "50"
}

# 按備份組恢複執行個體
resource "alicloud_rds_clone_db_instance" "clone_id" {
  db_instance_description  = "terraform-test-clone-1"
  source_db_instance_id    = alicloud_db_instance.instance.id
  db_instance_storage_type = "cloud_essd"
  payment_type             = "PayAsYouGo"
  # 類比擷取查詢結果中backup_id的參數取值。
  backup_id                = data.alicloud_rds_backups.example.backups.0.backup_id
  db_instance_storage      = "50"
}

如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。

ApsaraDB RDS：通過Terraform恢複RDS PostgreSQL執行個體

前提條件

使用的資源

按時間點恢複執行個體

執行terraform show命令

登入RDS管理主控台

按備份組恢複執行個體

執行terraform show命令

登入RDS管理主控台

清理資源

完整樣本

範例程式碼

相關文檔