全部產品
Search

搜尋本產品

    ApsaraDB RDS：通過Terraform管理RDS PostgreSQL備份

    文件中心

    ApsaraDB RDS：通過Terraform管理RDS PostgreSQL備份

    更新時間：Mar 13, 2025

    本文介紹如何使用Terraform建立備份、查看備份、修改備份設定以及刪除備份。

    說明

    本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

    前提條件

    • 已建立RDS PostgreSQL執行個體，詳情請參見建立RDS PostgreSQL執行個體。

    • 執行個體狀態為運行中，您可以通過如下兩種方式查看：

      • 參見查詢執行個體詳情查看參數status，如果取值為Running則表示執行個體狀態為運行中。

      • 前往RDS管理主控台，切換到目標地區，找到指定執行個體後，查看執行個體狀態。

    • 由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

    • 通過RAM授權，RAM使用者可以有效地管理其雲資源存取權限，適應多使用者協同工作的需求，並且能夠按需為使用者指派最小許可權，避免許可權過大導致的安全性漏洞。具體操作方式請參見為RAM使用者授權。

      {
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

    • 準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。

      • 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。

      • Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。

      • 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

    使用的資源

    說明

    本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

    建立備份

    1. 建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下代碼複製到main.tf中。

      • 建立前置資源。

        variable "region" {
  default = "cn-shenzhen"
}

variable "zone_id" {
  default = "cn-shenzhen-c"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

      • 在main.tf檔案中增加resource "alicloud_rds_backup" "instance" {}配置項，具體配置如下。

        ...
resource "alicloud_rds_backup" "instance" {
  db_instance_id = alicloud_db_instance.instance.id
  remove_from_state = true
}

    2. 執行以下命令，初始化Terraform運行環境。

      terraform init

      返回如下資訊，表示Terraform初始化成功。

      Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

    3. 建立執行計畫，並預覽變更。

      terraform plan

    4. 執行以下命令，建立資源。

      terraform apply

      在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

      alicloud_rds_backup.instance: Creating...
alicloud_rds_backup.instance: Still creating... [10s elapsed]
alicloud_rds_backup.instance: Still creating... [20s elapsed]
...
alicloud_rds_backup.instance: Still creating... [4m30s elapsed]
alicloud_rds_backup.instance: Creation complete after 4m33s [id=pgm-****]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

    5. 驗證結果。

      執行terraform show命令

      您可以使用以下命令查看建立的備份。

      terraform show
      ...
# alicloud_rds_backup.instance:
resource "alicloud_rds_backup" "instance" {
    backup_id         = "149xxxxxx"
    backup_method     = "Snapshot"
    backup_type       = "FullBackup"
    db_instance_id    = "pgm-****"
    id                = "pgm-****:****"
    remove_from_state = true
    store_status      = "Enabled"
}

      登入RDS管理主控台

      登入RDS管理主控台查看建立的備份。備份

    查看備份

    1. 在main.tf檔案中增加data "alicloud_rds_backups" "querybackups" {}配置項，具體配置如下。

      ...
data "alicloud_rds_backups" "querybackups" {
  db_instance_id = alicloud_db_instance.instance.id
}

    2. 執行以下命令。

      terraform apply

      在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

      alicloud_db_instance.instance: Refreshing state... [id=pgm-****]
alicloud_rds_backup.instance: Refreshing state... [id=pgm-****:14985****]
data.alicloud_rds_backups.querybackups: Reading...
data.alicloud_rds_backups.querybackups: Read complete after 0s [id=52064****]

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are
needed.

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

    3. 驗證結果。

      執行terraform show命令

      您可以使用以下命令查看備份清單。

      terraform show
      # data.alicloud_rds_backups.querybackups:
data "alicloud_rds_backups" "querybackups" {
    backups        = [
        {
            backup_download_url          = ""
            backup_end_time              = "2022-09-29T04:10:15Z"
            backup_id                    = "1498535549"
            backup_initiator             = "User"
            backup_intranet_download_url = ""
            backup_method                = "Snapshot"
            backup_mode                  = "Manual"
            backup_size                  = "53687091200"
            backup_start_time            = "2022-09-29T04:08:34Z"
            backup_status                = "Success"
            backup_type                  = "FullBackup"
            consistent_time              = "1664424514"
            copy_only_backup             = ""
            db_instance_id               = "pgm-****"
            encryption                   = jsonencode({})
            host_instance_id             = "22839235"
            id                           = "pgm-****:1498535549"
            is_avail                     = 1
            meta_status                  = ""
            storage_class                = "0"
            store_status                 = "Enabled"
        },
        {
            backup_download_url          = ""
            backup_end_time              = "2022-09-29T02:55:24Z"
            backup_id                    = "1498486764"
            backup_initiator             = "User"
            backup_intranet_download_url = ""
            backup_method                = "Snapshot"
            backup_mode                  = "Manual"
            backup_size                  = "53687091200"
            backup_start_time            = "2022-09-29T02:50:24Z"
            backup_status                = "Success"
            backup_type                  = "FullBackup"
            consistent_time              = "0"
            copy_only_backup             = ""
            db_instance_id               = "pgm-****"
            encryption                   = jsonencode({})
            host_instance_id             = "22839234"
            id                           = "pgm-****:1498486764"
            is_avail                     = 1
            meta_status                  = ""
            storage_class                = "0"
            store_status                 = "Enabled"
        },
    ]
    db_instance_id = "pgm-****"
    id             = "520646901"
    ids            = [
        "pgm-****:1498535549",
        "pgm-****:1498486764",
    ]
}

    修改備份設值

    1. 在main.tf檔案中增加resource "alicloud_db_backup_policy" "instance" {}配置項，具體配置如下。

      ...
resource "alicloud_db_backup_policy" "instance" {
  instance_id = alicloud_db_instance.instance.id
  preferred_backup_time = "00:00Z-01:00Z"
}

    2. 執行以下命令。

      terraform apply

      在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

      alicloud_db_backup_policy.instance: Creating...
alicloud_db_backup_policy.instance: Creation complete after 2s [id=pgm-****]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

    3. 驗證結果。

      執行terraform show命令

      您可以使用以下命令查看備份設定。

      terraform show
      # alicloud_db_backup_policy.instance:
resource "alicloud_db_backup_policy" "instance" {
    archive_backup_keep_count       = 1
    archive_backup_keep_policy      = "ByMonth"
    archive_backup_retention_period = 0
    backup_period                   = [
        "Friday",
        "Monday",
        "Saturday",
        "Sunday",
        "Thursday",
        "Tuesday",
        "Wednesday",
    ]
    backup_retention_period         = 7
    backup_time                     = "00:00Z-01:00Z"
    compress_type                   = "1"
    enable_backup_log               = true
    high_space_usage_protection     = "Enable"
    id                              = "pgm-****"
    instance_id                     = "pgm-****"
    local_log_retention_hours       = 0
    local_log_retention_space       = 30
    log_backup                      = true
    log_backup_retention_period     = 7
    log_retention_period            = 7
    preferred_backup_period         = [
        "Friday",
        "Monday",
        "Saturday",
        "Sunday",
        "Thursday",
        "Tuesday",
        "Wednesday",
    ]
    preferred_backup_time           = "00:00Z-01:00Z"
    released_keep_policy            = "None"
    retention_period                = 7
}
...

      登入RDS管理主控台

      登入RDS管理主控台查看SQL審計狀態。備份設定

    刪除備份

    1. 在上述main.tf檔案中刪除resource "alicloud_rds_backup" "instance" {}配置項的內容。例如，刪除如下資訊。

      ...
resource "alicloud_rds_backup" "instance" {
  db_instance_id = alicloud_db_instance.instance.id
  remove_from_state = true
}

    2. 執行以下命令。

      terraform apply

      在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

      alicloud_rds_backup.instance: Destroying... [id=pgm-****:1498535549]
alicloud_rds_backup.instance: Destruction complete after 0s

Apply complete! Resources: 0 added, 0 changed, 1 destroyed.

    3. 驗證結果。

      執行terraform show命令

      您可以使用以下命令查看備份是否刪除。

      terraform show
      ...
# data.alicloud_rds_backups.querybackups:
data "alicloud_rds_backups" "querybackups" {
    backups        = []
    db_instance_id = "pgm-****"
    id             = "0"
    ids            = []
}

      登入RDS管理主控台

      登入RDS管理主控台刪除備份

    清理資源

    當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

    terraform destroy

    完整樣本

    說明

    當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

    範例程式碼

    variable "region" {
  default = "cn-shenzhen"
}

variable "zone_id" {
  default = "cn-shenzhen-c"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

variable "target_minor_version" {
  default = "rds_postgres_1300_20240830"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

resource "alicloud_security_group" "example" {
  name   = "terraform-example"
  vpc_id = alicloud_vpc.main.id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# 建立備份
resource "alicloud_rds_backup" "instance" {
  db_instance_id    = alicloud_db_instance.instance.id
  remove_from_state = true
}

# 修改備份設值
#resource "alicloud_db_backup_policy" "instance" {
#  instance_id           = alicloud_db_instance.instance.id
#  preferred_backup_time = "00:00Z-01:00Z"
#}

# 查看備份
#data "alicloud_rds_backups" "example" {
#  db_instance_id    = alicloud_db_instance.instance.id
#}

    如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。

    相關文檔

    • Terraform介紹，請參見Terraform產品介紹。

    • Resource Orchestration Service服務為Terraform提供了託管的能力，您可以建立Terraform類型的模板，定義RDS資源，配置資源參數和資源間的依賴關係。更多資訊，請參見建立Terraform類型模板。