Virtual Private Cloud:IPv4 ゲートウェイ

コンソール

1. VPC コンソールの IPv4 ゲートウェイページに移動します。VPC が展開されているリージョンを選択し、IPv4 ゲートウェイの作成 をクリックします。

2. IPv4 ゲートウェイの作成: インターネットアクセスを一元化する VPC を選択します。

3. IPv4 ゲートウェイの有効化：パブリック vSwitch に関連付けられたルートテーブルを選択します。システムが自動的に、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを追加します。これにより、パブリック vSwitch 内でパブリック IP アドレスが割り当てられたリソースがインターネットにアクセスできるようになります。ルートテーブルにすでに宛先 CIDR ブロックが 0.0.0.0/0 のルートが存在する場合は、有効化しない をクリックします。その後、ルートのネクストホップを IPv4 ゲートウェイに変更し、ゲートウェイを有効化します。有効化後、IPv4 ゲートウェイが VPC のインターネットアクセスを一元的に制御します。

   • ECS インスタンスが、インターネット NAT ゲートウェイにアタッチされたパブリック IP アドレスを使用してインターネットにアクセスする場合、ECS インスタンスとインターネット NAT ゲートウェイは異なる vSwitch にデプロイする必要があります。NAT ゲートウェイの vSwitch のルートテーブルには、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートが含まれている必要があります。ECS インスタンスの vSwitch のルートテーブルには、パブリック vSwitch の NAT ゲートウェイを指すルートが含まれている必要があります。

   • ECS インスタンスが固定パブリック IP アドレスまたはアタッチ済みの EIP を使用してインターネットにアクセスする場合、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを追加します。

API

• CreateIpv4Gateway を呼び出して IPv4 ゲートウェイを作成します。

• EnableVpcIpv4Gateway を呼び出して IPv4 ゲートウェイを有効化します。RouteTableList をパブリック vSwitch に関連付けられたルートテーブルに設定します。このパラメーターを指定しない場合は、CreateRouteEntry を呼び出して、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを追加します。

Terraform

コンソールとは異なり、システムは IPv4 ゲートウェイの有効化時に、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを自動的に追加しません。ルートは手動で設定する必要があります。

リソース：alicloud_vpc、alicloud_vswitch、alicloud_vpc_ipv4_gateway、alicloud_route_table、alicloud_route_table_attachment、alicloud_vpc_route_entry、alicloud_instance、alicloud_security_group、alicloud_security_group_rule、alicloud_eip_address、alicloud_eip_association、alicloud_nat_gateway、alicloud_snat_entry

データソース：alicloud_zones

# IPv4 ゲートウェイを作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースに基づき、vSwitch を作成可能なゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC 内でリソースを作成可能なゾーンを照会します。
}

# VPC を作成します。
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # CIDR ブロックを指定します。
}

# vSwitch の構成を定義します。
locals {
  vswitches = {
    vsw1 = {
      name       = "example_vsw1_name"
      cidr_block = "10.0.0.0/24"
      zone_index = 0
    }
    vsw2 = {
      name       = "example_vsw2_name"
      cidr_block = "10.0.1.0/24"
      zone_index = 1
    }
    vsw3 = {
      name       = "example_vsw3_name"
      cidr_block = "10.0.2.0/24"
      zone_index = 0
    }
    vsw4 = {
      name       = "example_vsw4_name"
      cidr_block = "10.0.3.0/24"
      zone_index = 0
    }
  }

  # ルートテーブルの構成を定義します。
  route_tables = {
    rt1 = {
      name        = "example_rt1_name"
      vswitch_key = "vsw1"
    }
    rt2 = {
      name        = "example_rt2_name"
      vswitch_key = "vsw2"
    }
    rt3 = {
      name        = "example_rt3_name"
      vswitch_key = "vsw3"
    }
    rt4 = {
      name        = "example_rt4_name"
      vswitch_key = "vsw4"
    }
  }

  # インスタンスの構成を定義します。
  instances = {
    instance1 = {
      name        = "example_instance1_name"
      vswitch_key = "vsw1"
    }
    instance2 = {
      name        = "example_instance2_name"
      vswitch_key = "vsw3"
    }
    instance3 = {
      name        = "example_instance3_name"
      vswitch_key = "vsw4"
    }
  }

  # EIP の構成を定義します。
  eips = {
    eip1 = {
      name = "example_eip1_name"
    }
    eip2 = {
      name = "example_eip2_name"
    }
  }

  # SNAT エントリの構成を定義します。
  snat_entries = {
    snat1 = {
      instance_key = "instance2"
    }
    snat2 = {
      instance_key = "instance3"
    }
  }
}

# 複数の vSwitch を作成します。
resource "alicloud_vswitch" "example_vsw" {
  for_each = local.vswitches

  vswitch_name = each.value.name
  cidr_block   = each.value.cidr_block
  vpc_id       = alicloud_vpc.example_vpc.id
  zone_id      = data.alicloud_zones.available_zones.zones[each.value.zone_index].id
}

# 複数のカスタムルートテーブルを作成します。
resource "alicloud_route_table" "example_route_table" {
  for_each = local.route_tables

  route_table_name = each.value.name
  vpc_id           = alicloud_vpc.example_vpc.id
}

# ルートテーブルを vSwitch に関連付けます。
resource "alicloud_route_table_attachment" "example_route_table_attachment" {
  for_each = local.route_tables

  vswitch_id     = alicloud_vswitch.example_vsw[each.value.vswitch_key].id
  route_table_id = alicloud_route_table.example_route_table[each.key].id
}

# インスタンスタイプを指定します。
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# イメージ ID を指定します。
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "example_security_group" {
  security_group_name = "example_security_group_name"
  vpc_id              = alicloud_vpc.example_vpc.id
}

# セキュリティグループルールを作成します。必要に応じてプロトコルおよびポート番号を変更してください。
resource "alicloud_security_group_rule" "allow_Internet" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group.id
  cidr_ip           = "0.0.0.0/0"
}

# 複数のサーバーを作成します。
resource "alicloud_instance" "example_instance" {
  for_each = local.instances

  instance_name        = each.value.name
  vswitch_id           = alicloud_vswitch.example_vsw[each.value.vswitch_key].id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group.id]
  instance_charge_type = "PostPaid"           # 課金方法を従量課金に設定します。
  spot_strategy        = "SpotWithPriceLimit" # 最大価格を指定できるスポットインスタンスとしてインスタンスを設定します。
}

# 複数の EIP を作成します。
resource "alicloud_eip_address" "example_eip" {
  for_each = local.eips

  address_name = each.value.name
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# ECS インスタンスに EIP を関連付けます。
resource "alicloud_eip_association" "example_eip_ecs_association" {
  allocation_id = alicloud_eip_address.example_eip["eip1"].id
  instance_type = "EcsInstance"
  instance_id   = alicloud_instance.example_instance["instance1"].id
}

# インターネット NAT ゲートウェイを作成します。
resource "alicloud_nat_gateway" "example_natgw" {
  nat_gateway_name = "example_natgw_name"
  vpc_id           = alicloud_vpc.example_vpc.id
  vswitch_id       = alicloud_vswitch.example_vsw["vsw2"].id
  nat_type         = "Enhanced"
  eip_bind_mode    = "NAT" # EIP 関連付けモードを指定します。値は NAT である必要があります。
  payment_type     = "PayAsYouGo"
}

# EIP をインターネット NAT ゲートウェイに関連付けます。
resource "alicloud_eip_association" "example_eip_natgw_association" {
  allocation_id = alicloud_eip_address.example_eip["eip2"].id
  instance_type = "NAT"
  instance_id   = alicloud_nat_gateway.example_natgw.id
}

# NAT ゲートウェイを指すルートを追加します。
resource "alicloud_route_entry" "example_rt3_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt3"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "NatGateway"
  nexthop_id            = alicloud_nat_gateway.example_natgw.id
}

# NAT ゲートウェイを指すルートを追加します。
resource "alicloud_route_entry" "example_rt4_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt4"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "NatGateway"
  nexthop_id            = alicloud_nat_gateway.example_natgw.id
}

# SNAT エントリを作成します。
resource "alicloud_snat_entry" "example_snat_entry" {
  for_each = local.snat_entries

  snat_table_id = alicloud_nat_gateway.example_natgw.snat_table_ids
  source_cidr   = alicloud_instance.example_instance[each.value.instance_key].primary_ip_address
  snat_ip       = alicloud_eip_address.example_eip["eip2"].ip_address
}

# IPv4 ゲートウェイを作成します。
resource "alicloud_vpc_ipv4_gateway" "example_ipv4gw" {
  ipv4_gateway_name = "example_ipv4gw_name"
  vpc_id            = alicloud_vpc.example_vpc.id
  enabled           = true
}

# IPv4 ゲートウェイを指すルートを追加します。
resource "alicloud_route_entry" "example_rt1_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt1"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

# IPv4 ゲートウェイを指すルートを追加します。
resource "alicloud_route_entry" "example_rt2_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt2"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

コンソール

1. VPC コンソールの IPv4 ゲートウェイページに移動します。VPC が展開されているリージョンを選択し、IPv4 ゲートウェイの作成 をクリックします。

2. IPv4 ゲートウェイの作成: 非標準のプライベート CIDR ブロックにアクセスする必要がある VPC を選択します。

3. IPv4 ゲートウェイの有効化：非標準のプライベート CIDR ブロックにアクセスする必要がある vSwitch に関連付けられたルートテーブルを選択します。システムが自動的に、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを追加します。これにより、vSwitch 内のリソースが、より具体的なルートに基づいて非標準のプライベート CIDR ブロックにアクセスできるようになります。

   • 添付されたルートテーブルに宛先 CIDR ブロックが 0.0.0.0/0 のルートが含まれていないことを確認してください。含まれている場合は、有効化しない をクリックし、ルートを削除してから、再度ルートテーブルを有効化してください。

   • 有効化後、IPv4 ゲートウェイがインターネット向けトラフィックを一元的に制御し、すべてのトラフィックがルートテーブルに基づいて転送されます。

API

• CreateIpv4Gateway を呼び出して IPv4 ゲートウェイを作成します。

• EnableVpcIpv4Gateway を呼び出して IPv4 ゲートウェイを有効化します。RouteTableList をパブリック vSwitch に関連付けられたルートテーブルに設定します。このパラメーターを指定しない場合は、CreateRouteEntry を呼び出して、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートを追加します。

Terraform

コンソールとは異なり、IPv4 ゲートウェイを有効化しても、IPv4 ゲートウェイを指す 0.0.0.0/0 ルートは自動的に追加されません。ルートは手動で設定する必要があります。

リソース：alicloud_vpc、alicloud_vswitch、alicloud_vpc_ipv4_gateway、alicloud_route_table、alicloud_route_table_attachment、alicloud_vpc_route_entry、alicloud_instance、alicloud_security_group、alicloud_security_group_rule、alicloud_eip_address、alicloud_eip_association、alicloud_vpc_peer_connection

データソース：alicloud_zones

この例では、ピアリング接続内の VPC は同一アカウントに属しています。クロスアカウントピアリング接続を作成する場合、ピアアカウントが VPC ピアリング接続要求を受諾できるよう、alicloud_vpc_peer_connection_accepter も作成する必要があります。

# IPv4 ゲートウェイを作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースに基づき、vSwitch を作成可能なゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC 内でリソースを作成可能なゾーンを照会します。
}

# インスタンスタイプを指定します。
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# イメージ ID を指定します。
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# VPC を作成します。
resource "alicloud_vpc" "example_vpc1" {
  vpc_name   = "example_vpc1_name"
  cidr_block = "10.0.0.0/16" # CIDR ブロックを指定します。
}

# VPC を作成します。
resource "alicloud_vpc" "example_vpc2" {
  vpc_name   = "example_vpc2_name"
  cidr_block = "30.0.0.0/16" # CIDR ブロックを指定します。
}

# vSwitch を作成します。
resource "alicloud_vswitch" "example_vsw1" {
  vswitch_name = "example_vsw1_name"
  cidr_block   = "10.0.1.0/24"
  vpc_id       = alicloud_vpc.example_vpc1.id
  zone_id      = data.alicloud_zones.available_zones.zones.0.id
}

# vSwitch を作成します。
resource "alicloud_vswitch" "example_vsw2" {
  vswitch_name = "example_vsw2_name"
  cidr_block   = "30.0.1.0/24"
  vpc_id       = alicloud_vpc.example_vpc2.id
  zone_id      = data.alicloud_zones.available_zones.zones.1.id
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "example_security_group1" {
  security_group_name = "example_security_group1_name"
  vpc_id              = alicloud_vpc.example_vpc1.id
}

# セキュリティグループルールを作成します。必要に応じてプロトコルおよびポート番号を変更してください。
resource "alicloud_security_group_rule" "allow_Internet1" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group1.id
  cidr_ip           = "0.0.0.0/0"
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "example_security_group2" {
  security_group_name = "example_security_group2_name"
  vpc_id              = alicloud_vpc.example_vpc2.id
}

# セキュリティグループルールを作成します。必要に応じてプロトコルおよびポート番号を変更してください。
resource "alicloud_security_group_rule" "allow_Internet2" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group2.id
  cidr_ip           = "0.0.0.0/0"
}

# ECS インスタンスを作成します。
resource "alicloud_instance" "example_instance1" {
  instance_name        = "example_instance1_name"
  vswitch_id           = alicloud_vswitch.example_vsw1.id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group1.id]
  instance_charge_type = "PostPaid"
  spot_strategy        = "SpotWithPriceLimit"
}

# EIP を作成します。
resource "alicloud_eip_address" "example_eip" {
  address_name = "example_eip_name"
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# ECS インスタンスに EIP を関連付けます。
resource "alicloud_eip_association" "example_eip_ecs_association" {
  allocation_id = alicloud_eip_address.example_eip.id
  instance_type = "EcsInstance"
  instance_id   = alicloud_instance.example_instance1.id
}

# ECS インスタンスを作成します。
resource "alicloud_instance" "example_instance2" {
  instance_name        = "example_instance2_name"
  vswitch_id           = alicloud_vswitch.example_vsw2.id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group2.id]
  instance_charge_type = "PostPaid"
  spot_strategy        = "SpotWithPriceLimit"
}

# カスタムルートテーブルを作成します。
resource "alicloud_route_table" "example_route_table1" {
  route_table_name = "example_route_table1_name"
  vpc_id           = alicloud_vpc.example_vpc1.id
}

# ルートテーブルを vSwitch に関連付けます。
resource "alicloud_route_table_attachment" "example_route_table_attachment1" {
  vswitch_id     = alicloud_vswitch.example_vsw1.id
  route_table_id = alicloud_route_table.example_route_table1.id
}

# カスタムルートテーブルを作成します。
resource "alicloud_route_table" "example_route_table2" {
  route_table_name = "example_route_table2_name"
  vpc_id           = alicloud_vpc.example_vpc2.id
}

# ルートテーブルを vSwitch に関連付けます。
resource "alicloud_route_table_attachment" "example_route_table_attachment2" {
  vswitch_id     = alicloud_vswitch.example_vsw2.id
  route_table_id = alicloud_route_table.example_route_table2.id
}

# VPC ピアリング接続を作成します。
resource "alicloud_vpc_peer_connection" "example_vpc_peer" {
  peer_connection_name = "example_vpc_peer_name"
  vpc_id               = alicloud_vpc.example_vpc1.id
  accepting_ali_uid    = "1234****" # ピア VPC が属するアカウントの ID。この例では、同一アカウントの VPC ピアリング接続を作成しています。クロスアカウントピアリング接続を作成する場合、ピアアカウントが VPC ピアリング接続要求を受諾できるよう、alicloud_vpc_peer_connection_accepter を作成する必要があります。
  accepting_region_id  = "cn-hangzhou"
  accepting_vpc_id     = alicloud_vpc.example_vpc2.id
}

# ピアリング接続のためのルートを設定します。
resource "alicloud_route_entry" "example_peer_route1" {
  route_table_id        = alicloud_route_table.example_route_table1.id
  destination_cidrblock = "30.0.0.0/16"
  nexthop_type          = "VpcPeer"
  nexthop_id            = alicloud_vpc_peer_connection.example_vpc_peer.id
}

# ピアリング接続のためのルートを設定します。
resource "alicloud_route_entry" "example_peer_route2" {
  route_table_id        = alicloud_route_table.example_route_table2.id
  destination_cidrblock = "10.0.0.0/16"
  nexthop_type          = "VpcPeer"
  nexthop_id            = alicloud_vpc_peer_connection.example_vpc_peer.id
}

# IPv4 ゲートウェイを作成します。
resource "alicloud_vpc_ipv4_gateway" "example_ipv4gw" {
  ipv4_gateway_name = "example_ipv4gw_name"
  vpc_id            = alicloud_vpc.example_vpc1.id
  enabled           = true
}

# IPv4 ゲートウェイを指すルートを追加します。
resource "alicloud_route_entry" "example_igw_route" {
  route_table_id        = alicloud_route_table.example_route_table1.id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

コンソール

API

• AssociateRouteTableWithGateway を呼び出して gateway route table をアタッチします。

• DissociateRouteTableFromGateway を呼び出して gateway route table をデタッチします。

Terraform

リソース：alicloud_vpc_gateway_route_table_attachment

# IPv4 ゲートウェイが展開されているリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# IPv4 ゲートウェイの ID を指定します。
variable "ipv4_gateway_id" {
  default = "ipv4gw-hp3v******" # 値を実際の IPv4 ゲートウェイ ID に置き換えてください。
}

# gateway route table の ID を指定します。
variable "route_table_id" {
  default = "vtb-hp3w******" # 値を実際の gateway route table ID に置き換えてください。
}

# gateway route table をアタッチします。
resource "alicloud_vpc_gateway_route_table_attachment" "example_attachment" {
  ipv4_gateway_id = var.ipv4_gateway_id
  route_table_id  = var.route_table_id
}