Virtual Private Cloud:VPC と vSwitch

コンソール

API

コンソールとは異なり、CreateVpc API を呼び出すと、空の VPC のみが作成されます。vSwitch を作成するには、CreateVSwitch API も呼び出す必要があります。

• CreateVpc を呼び出してから CreateVSwitch を呼び出して、VPC と vSwitch を作成します。

• DeleteVSwitch を呼び出してから DeleteVpc を呼び出して、vSwitch と VPC を削除します。

  1. vSwitch を削除する前に、共有されておらず、カスタムルートテーブルまたはネットワーク ACL にバインドされておらず、vSwitch 内のすべてのクラウドリソースが解放されていることを確認してください。

  2. VPC を削除する前に、VPC 内のすべてのリソースが解放され、Cloud Enterprise Network (CEN) などの他のネットワークサービスへの接続が削除されていることを確認してください。

Terraform

リソース：alicloud_vpc、alicloud_vswitch

データソース：alicloud_zones

# VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースを使用して、vSwitch を作成できるゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC で vSwitch を作成できるゾーンをクエリします。
  # available_instance_type = "ecs.g7.large"  # VPC で ECS インスタンスを作成できるゾーンをクエリします。
  # available_resource_creation = "slb"  # VPC で Server Load Balancer (SLB) インスタンスを作成できるゾーンをクエリします。
}

# VPC を作成します。 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # CIDR ブロックを指定します。 
}

# vSwitch を作成します。 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # CIDR ブロックを指定します。 
  vpc_id       = alicloud_vpc.example_vpc.id                       # vSwitch が属する VPC の ID を指定します。 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # vSwitch が属するゾーンを指定します。
}

コンソール

API

コンソールとは異なり、API を呼び出して VPC と vSwitch で IPv6 を有効にしても、IPv6 ゲートウェイは自動的に作成されません。CreateIpv6Gateway を呼び出して、別途作成する必要があります。

• VPC と vSwitch を作成する際、CreateVpc と CreateVSwitch の EnableIPv6 パラメータを設定して、IPv6 を有効または無効にします。VPC を作成する際、Ipv6IpamPoolId と Ipv6CidrMask パラメータを指定して、指定された IPv6 IPAM プールから VPC に IPv6 CIDR ブロックを割り当てます。

• 既存の VPC と vSwitch の場合、ModifyVpcAttribute と ModifyVSwitchAttribute の EnableIPv6 パラメータを変更して、IPv6 を有効または無効にします。指定された IPv6 アドレスプールから VPC に IPv6 CIDR ブロックを割り当てるには、AssociateVpcCidrBlock を呼び出します。

Terraform

Terraform は現在、システムによって割り当てられた IPv6 CIDR ブロックのみをサポートしています。IPAM プールからの割り当てはサポートされていません。

リソース：alicloud_vpc、alicloud_vswitch

データソース：alicloud_zones

# VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースを使用して、vSwitch を作成できるゾーンのリストを自動的に取得します。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # VPC で vSwitch を作成できるゾーンをクエリします。
  # available_instance_type = "ecs.g7.large"  # VPC で ECS インスタンスを作成できるゾーンをクエリします。
  # available_resource_creation = "slb"  # VPC で SLB インスタンスを作成できるゾーンをクエリします。
}

# デュアルスタック VPC を作成します。 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # IPv6 を有効にします。無効にする場合は false に設定します。
  ipv6_isp    = "BGP" # IPv6 CIDR ブロックのタイプを指定します。
}

# デュアルスタック vSwitch を作成します。 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # IPv6 を有効にします。無効にする場合は false に設定します。
  ipv6_cidr_block_mask = 1    # vSwitch の IPv6 CIDR ブロックの最後の 8 ビットを指定します。 
} 

コンソール

API

• CreateVSwitchCidrReservation を呼び出して、予約済み CIDR ブロックを作成します。

• GetVSwitchCidrReservationUsage を呼び出して、使用中の IP アドレスを表示します。

• DeleteVSwitchCidrReservation を呼び出して、予約済み CIDR ブロックを削除します。

Terraform

リソース：alicloud_vpc_vswitch_cidr_reservation

# リソースが配置されているリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou" # リソースが存在するリージョン。
}

# vSwitch の ID を指定します。
variable "vsw_id" {
  default = "vsw-xxx" # 実際の vSwitch の ID に置き換えてください。
}

# 予約済み CIDR ブロックを作成します。
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 予約済み CIDR ブロックを指定します。 
}

コンソール

VPC を作成する前に、IPAM コンソールで IPAM インスタンスと IPAM プールを作成していることを確認してください。

1. VPC コンソールの VPC の作成 ページに移動します。

2. IPv4 CIDR ブロックを割り当てるには、IPAM で割り当て を選択し、IPAM プールを選択してマスクを設定します。システムは、指定されたマスク長に一致する最初に使用可能な CIDR ブロックを自動的に割り当てます。また、プールの事前にプロビジョニングされた範囲内で IPv4 CIDR ブロックを調整することもできます。

3. IPv6 を有効にするには、IPAM によって割り当てられた IPv6 ブロック を選択し、IPv6 IPAM プールを選択してから、マスクを設定するか、CIDR ブロックを指定します。

API

• 既存の IPAM プールがある場合：

  • IPv4 CIDR ブロックの割り当て：CreateVpc を呼び出し、Ipv4IpamPoolId パラメータを渡して IPAM プールを指定し、Ipv4CidrMask パラメータを渡してプレフィックス長を指定します。その後、IPAM プールから CIDR ブロックが割り当てられ、新しい VPC の IPv4 CIDR ブロックとして使用されます。または、プレフィックス長を指定して CIDR ブロックを自動的に割り当てる代わりに、CidrBlock パラメータを渡して VPC の CIDR ブロックを指定することもできます。

  • IPv6 CIDR ブロックの割り当て：Ipv6IpamPoolId と Ipv6CidrMask の両方を渡すと、指定された IPv6 IPAM プールから VPC に IPv6 CIDR ブロックが割り当てられます。

• IPAM プールを作成していない場合は、次の API を順番に呼び出してプールを作成してから、上記の手順に従って VPC を作成します。

  1. OpenVpcIpamService - IPAM 機能を有効にする

  2. CreateIpam - IPAM インスタンスを作成する

  3. CreateIpamPool - IPAM プールを作成する

  4. AddIpamPoolCidr - IPAM プールに CIDR ブロックをプロビジョニングする

Terraform

Terraform は現在、IPAM プールからの IPv4 CIDR ブロックの割り当てのみをサポートしています。IPv6 CIDR ブロックの割り当てはサポートされていません。

リソース：alicloud_vpc_ipam、alicloud_vpc_ipam_pool、alicloud_vpc_ipam_pool_cidr、alicloud_vpc

# IPAM インスタンス、IPAM プール、および VPC を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# IPAM インスタンスを作成します。
resource "alicloud_vpc_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # IPAM インスタンスの運用リージョンを指定します。
}

# IPAM プールを作成します。
resource "alicloud_vpc_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam.example_ipam.private_default_scope_id # IPAM プールのスコープを指定します。
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam.example_ipam.region_id # IPAM プールのリージョンを指定します。
  ip_version     = "IPv4"                                     # IPAM プールの IP バージョンを指定します。
}

# IPAM プールに CIDR を割り当てます。
resource "alicloud_vpc_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # CIDR を指定します。
  ipam_pool_id = alicloud_vpc_ipam_pool.example_parentIpamPool.id # IPAM プールの ID を指定します。
}

# VPC を作成します。
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_pool.example_parentIpamPool.id # IPAM プールの ID を指定します。
  ipv4_cidr_mask    = 24                                                 # IPv4 ネットワークのプレフィックス長。
}