Container Service for Kubernetes:Terraform を使用した ACK 専用クラスターの作成

作業ディレクトリを作成し、次の内容で main.tf ファイルを作成します。

provider "alicloud" {
  region = var.region_id
}

variable "region_id" {
  type    = string
  default = "cn-hangzhou"
}

variable "zone_ids" {
  type    = list(string)
  default = ["cn-hangzhou-i","cn-hangzhou-j","cn-hangzhou-k"]
}

# リソース名またはラベルを指定します。
variable "name" {
  default = "tf-example"
}

# 既存の VPC の ID を指定します。この変数を空白のままにすると、新しい VPC が作成されます。
variable "vpc_id" {
  description = "Existing vpc id used to create several vswitches and other resources."
  default     = ""
}

# 新しい VPC の CIDR ブロックを指定します。この変数は、vpc_id 変数を空白のままにした場合に有効になります。
variable "vpc_cidr" {
  description = "The cidr block used to launch a new vpc when 'vpc_id' is not specified."
  default     = "10.0.0.0/8"
}

# 既存の vSwitch の ID を指定します。
variable "vswitch_ids" {
  description = "List of existing vswitch id."
  type        = list(string)
  default     = []
}

# vswitch_ids が指定されていない場合は、vSwitch を作成するために 3 つの CIDR ブロックを指定する必要があります。CIDR ブロックは互いに重複させることはできません。
variable "vswitch_cidrs" {
  description = "List of cidr blocks used to create several new vswitches when 'vswitch_ids' is not specified."
  type        = list(string)
  default     = ["10.1.0.0/16", "10.2.0.0/16", "10.3.0.0/16"]
}

# Terway 構成を指定します。
variable "terway_vswitch_ids" {
  description = "List of existing vswitch ids for terway."
  type        = list(string)
  default     = []
}

# terway_vswitch_ids が空の場合に、Terway vSwitch を作成するための CIDR ブロックを指定します。
variable "terway_vswitch_cidrs" {
  description = "List of cidr blocks used to create several new vswitches when 'terway_vswitch_cidrs' is not specified."
  type        = list(string)
  default     = ["10.4.0.0/16", "10.5.0.0/16", "10.6.0.0/16"]
}

# ACK クラスターにインストールするコンポーネントを指定します。インストールする各コンポーネントの名前と構成を指定する必要があります。
variable "cluster_addons" {
  type = list(object({
    name   = string
    config = string
  }))

  default = [
    {
      "name"   = "terway-eniip",
      "config" = "",
    },
    {
      "name"   = "csi-plugin",
      "config" = "",
    },
    {
      "name"   = "csi-provisioner",
      "config" = "",
    },
    {
      "name"   = "logtail-ds",
      "config" = "{\"IngressDashboardEnabled\":\"true\"}",
    },
    {
      "name"   = "nginx-ingress-controller",
      "config" = "{\"IngressSlbNetworkType\":\"internet\"}",
    },
    {
      "name"   = "arms-prometheus",
      "config" = "",
    },
    {
      "name"   = "ack-node-problem-detector",
      "config" = "{\"sls_project_name\":\"\"}",
    }
  ]
}

locals {
  all_zone_ids = [for zones in data.alicloud_enhanced_nat_available_zones.enhanced.zones : zones.zone_id]
  common_zone_ids = setintersection(toset(var.zone_ids),toset(local.all_zone_ids))

  # 各ゾーンで利用可能なインスタンスタイプを取得します。
  instance_types_per_az = { for az, types in data.alicloud_instance_types.default : az => [for t in types.instance_types : t.id] }

  # 指定されたすべてのゾーンのインスタンスタイプのリストを取得します。
  all_instance_types_in_zones = [for zone in local.common_zone_ids : local.instance_types_per_az[zone]]

  # 各リストをコレクションに変換します。
  sets = [for s in local.all_instance_types_in_zones : toset(s)]

  # すべてのゾーンに共通するインスタンスタイプを計算します。
  common_instance_types = [for element in local.sets[0]: element if length([for set in local.sets: set if contains(set, element)]) == length(local.sets)]
}

# 拡張 NAT ゲートウェイをサポートするゾーンをクエリします。
data "alicloud_enhanced_nat_available_zones" "enhanced" {
}

# vpc_id 変数を指定しない場合、この Terraform リソースは VPC を作成します。VPC の CIDR ブロックは vpc_cidr 変数で指定されます。
resource "alicloud_vpc" "vpc" {
  count      = var.vpc_id == "" ?  1 : 0
  cidr_block = var.vpc_cidr
}

# vswitch_ids 変数を指定しない場合、新しい vSwitch が vswitch_cidrs に基づいて作成されます。
resource "alicloud_vswitch" "vswitches" {
  count      = length(var.vswitch_ids) > 0 ?  0 : length(var.vswitch_cidrs)
  vpc_id     = var.vpc_id == "" ?  join("", alicloud_vpc.vpc.*.id) : var.vpc_id
  cidr_block = element(var.vswitch_cidrs, count.index)
  zone_id    = tolist(local.common_zone_ids)[count.index]
}

# terway_vswitch_ids 変数を指定しない場合、Terway で使用される vSwitch が vswitch_cidrs パラメータに基づいて作成されます。
resource "alicloud_vswitch" "terway_vswitches" {
  count      = length(var.terway_vswitch_ids) > 0 ?  0 : length(var.terway_vswitch_cidrs)
  vpc_id     = var.vpc_id == "" ?  join("", alicloud_vpc.vpc.*.id) : var.vpc_id
  cidr_block = element(var.terway_vswitch_cidrs, count.index)
  zone_id    = tolist(local.common_zone_ids)[count.index]
}

# RAM ユーザーが管理するリソースグループをクエリします。
data "alicloud_resource_manager_resource_groups" "default" {
  status = "OK"
}

# ECS インスタンスタイプをクエリします。
data "alicloud_instance_types" "default" {
  for_each            = toset(local.common_zone_ids )
  availability_zone   = each.key
  cpu_core_count      = 8
  memory_size         = 16
  kubernetes_node_role = "Master"
  system_disk_category = "cloud_essd"
}

# ACK 専用クラスターを作成し、コントロールプレーン vSwitch、Pod vSwitch、インスタンスタイプ、ディスク、ノードへのログオンに使用するパスワード、および Service CIDR ブロックを構成します。
resource "alicloud_cs_kubernetes" "default" {
  master_vswitch_ids    = length(var.vswitch_ids) > 0 ?  split(",", join(",", var.vswitch_ids)) : length(var.vswitch_cidrs) < 1 ?  [] : split(",", join(",", alicloud_vswitch.vswitches.*.id))
  pod_vswitch_ids       = length(var.terway_vswitch_ids) > 0 ?  split(",", join(",", var.terway_vswitch_ids)) : length(var.terway_vswitch_cidrs) < 1 ?  [] : split(",", join(",", alicloud_vswitch.terway_vswitches.*.id)) # Terway をネットワークコンポーネントとして使用する場合の Pod vSwitch の CIDR ブロック。
  master_instance_types = [local.common_instance_types[0],local.common_instance_types[0],local.common_instance_types[0]] # コントロールプレーンのインスタンスタイプ。
  master_disk_category  = "cloud_essd"            # コントロールプレーンのシステムディスクタイプ。
  password              = "Yourpassword1234"     # SSH ログオンに使用するパスワード。
  service_cidr          = "172.18.0.0/16"        # Service CIDR ブロック。
  load_balancer_spec    = "slb.s1.small"         # Server Load Balancer (SLB) インスタンスタイプ。
  install_cloud_monitor = "true"                 # CloudMonitor の有効化。
  resource_group_id     = data.alicloud_resource_manager_resource_groups.default.groups.0.id # クラスターが所属するリソースグループの ID。リソースグループはリソースの分離に使用されます。
  deletion_protection   = "false"                # 削除保護により、コンソールまたは API 操作によるクラスターの誤削除を防止できます。
  timezone              = "Asia/Shanghai"        # クラスターのタイムゾーン。
  os_type               = "Linux"                # ノード OS のタイプ。
  platform              = "AliyunLinux3"         # OS ディストリビューション。
  cluster_domain        = "cluster.local"        # クラスタードメイン名。
  proxy_mode            = "ipvs"                 # kube-proxy モード。
  custom_san            = "www.terraform.io"     # クラスターの API サーバー証明書のサブジェクトの別名 (SAN)。
  new_nat_gateway       = "true"                 # NAT ゲートウェイを作成します。
  dynamic "addons" {
    for_each = var.cluster_addons
    content {
      name   = lookup(addons.value, "name", var.cluster_addons)
      config = lookup(addons.value, "config", var.cluster_addons)
    }
  }
}