Virtual Private Cloud:VPC dan vSwitch

Konsol

API

Berbeda dengan di konsol, pemanggilan operasi CreateVpc hanya membuat VPC kosong. Anda juga harus memanggil operasi CreateVSwitch untuk membuat vSwitch.

• Panggil CreateVpc lalu CreateVSwitch untuk membuat VPC dan vSwitch.

• Panggil DeleteVSwitch lalu DeleteVpc untuk menghapus vSwitch dan VPC.

  1. Sebelum menghapus vSwitch, pastikan vSwitch tersebut tidak dibagikan, tidak terikat ke tabel rute kustom atau ACL jaringan, dan semua resource cloud di dalamnya telah dilepas.

  2. Sebelum menghapus VPC, pastikan semua resource di dalamnya telah dilepas dan koneksi ke layanan jaringan lainnya, seperti CEN, telah dihapus.

Terraform

Resource: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Tentukan wilayah tempat Anda ingin membuat VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Gunakan data source untuk secara otomatis mengambil daftar zona tempat Anda dapat membuat vSwitch.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Mencari zona tempat vSwitch dapat dibuat di VPC.
  # available_instance_type = "ecs.g7.large"  # Mencari zona tempat instance ECS dapat dibuat di VPC.
  # available_resource_creation = "slb"  # Mencari zona tempat instance SLB dapat dibuat di VPC.
}

# Buat VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # Tentukan blok CIDR. 
}

# Buat vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # Tentukan blok CIDR. 
  vpc_id       = alicloud_vpc.example_vpc.id                       # Tentukan ID VPC tempat vSwitch berada. 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # Tentukan zona tempat vSwitch berada.
}

Konsol

API

Berbeda dengan di konsol, IPv6 Gateway tidak dibuat secara otomatis saat Anda mengaktifkan IPv6 untuk VPC dan vSwitch melalui API. Anda harus memanggil CreateIpv6Gateway untuk membuatnya sendiri.

• Saat membuat VPC dan vSwitch, atur parameter EnableIPv6 di CreateVpc dan CreateVSwitch untuk mengaktifkan atau menonaktifkan IPv6. Saat membuat VPC, tentukan parameter Ipv6IpamPoolId dan Ipv6CidrMask untuk mengalokasikan blok CIDR IPv6 dari kolam IPAM IPv6 tertentu ke VPC.

• Untuk VPC dan vSwitch yang sudah ada, ubah parameter EnableIPv6 dari ModifyVpcAttribute dan ModifyVSwitchAttribute untuk mengaktifkan atau menonaktifkan IPv6. Untuk menetapkan blok CIDR IPv6 ke VPC dari kolam alamat IPv6 tertentu, panggil AssociateVpcCidrBlock.

Terraform

Terraform saat ini hanya mendukung blok CIDR IPv6 yang dialokasikan oleh sistem. Alokasi dari kolam IPAM tidak didukung.

Resource: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Tentukan wilayah tempat Anda ingin membuat VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Gunakan data source untuk secara otomatis mengambil daftar zona tempat Anda dapat membuat vSwitch.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Mencari zona tempat vSwitch dapat dibuat di VPC.
  # available_instance_type = "ecs.g7.large"  # Mencari zona tempat instance ECS dapat dibuat di VPC.
  # available_resource_creation = "slb"  # Mencari zona tempat instance SLB dapat dibuat di VPC.
}

# Buat VPC dual-stack. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # Aktifkan IPv6. Atur nilainya ke false untuk menonaktifkan IPv6.
  ipv6_isp    = "BGP" # Tentukan jenis blok CIDR IPv6.
}

# Buat vSwitch dual-stack. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # Aktifkan IPv6. Atur nilainya ke false untuk menonaktifkan IPv6.
  ipv6_cidr_block_mask = 1    # Tentukan 8 bit terakhir dari blok CIDR IPv6 untuk vSwitch. 
} 

Konsol

API

• Panggil CreateVSwitchCidrReservation untuk membuat blok CIDR yang dicadangkan.

• Panggil GetVSwitchCidrReservationUsage untuk melihat alamat IP yang digunakan.

• Panggil DeleteVSwitchCidrReservation untuk menghapus blok CIDR yang dicadangkan.

Terraform

Resource: alicloud_vpc_vswitch_cidr_reservation

# Tentukan wilayah tempat resource berada.
provider "alicloud" {
  region = "cn-hangzhou" # Wilayah tempat resource berada.
}

# Tentukan ID vSwitch.
variable "vsw_id" {
  default = "vsw-xxx" # Ganti dengan ID aktual vSwitch Anda.
}

# Buat blok CIDR yang dicadangkan.
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # Tentukan blok CIDR yang dicadangkan. 
}

Konsol

Sebelum membuat VPC, pastikan Anda telah membuat instans IPAM dan kolam IPAM di Konsol IPAM.

1. Buka halaman Create VPC di Konsol VPC.

2. Untuk mengalokasikan blok CIDR IPv4, pilih Allocated by IPAM, pilih kolam IPAM, lalu konfigurasi masker. Sistem secara otomatis mengalokasikan blok CIDR pertama yang tersedia sesuai panjang masker yang ditentukan. Anda juga dapat menyesuaikan blok CIDR IPv4 dalam rentang yang telah disediakan oleh kolam.

3. Untuk mengaktifkan IPv6, pilih Allocated by IPAM, pilih kolam IPAM IPv6, lalu konfigurasi masker atau tentukan blok CIDR.

API

• Jika Anda memiliki kolam IPAM yang sudah ada:

  • Alokasikan blok CIDR IPv4: Anda dapat memanggil CreateVpc dan meneruskan parameter Ipv4IpamPoolId untuk menentukan kolam IPAM dan parameter Ipv4CidrMask untuk menentukan masker. Blok CIDR kemudian dialokasikan dari kolam IPAM dan digunakan sebagai blok CIDR IPv4 untuk VPC baru. Atau, Anda dapat meneruskan parameter CidrBlock untuk menentukan blok CIDR VPC alih-alih mengalokasikan blok CIDR secara otomatis dengan menentukan masker.

  • Alokasikan blok CIDR IPv6: Jika Anda meneruskan kedua parameter Ipv6IpamPoolId dan Ipv6CidrMask, blok CIDR IPv6 dialokasikan ke VPC dari kolam IPAM IPv6 yang ditentukan.

• Jika Anda belum membuat kolam IPAM, panggil API berikut secara berurutan untuk membuatnya, lalu buat VPC seperti dijelaskan di atas.

  1. OpenVpcIpamService - Aktifkan fitur IPAM

  2. CreateIpam - Buat instans IPAM

  3. CreateIpamPool - Buat kolam IPAM

  4. AddIpamPoolCidr - Sediakan blok CIDR untuk kolam IPAM

Terraform

Terraform saat ini hanya mendukung alokasi blok CIDR IPv4 dari kolam IPAM. Alokasi blok CIDR IPv6 tidak didukung.

Resource: vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# Tentukan wilayah tempat Anda ingin membuat instans IPAM, kolam IPAM, dan VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Buat instans IPAM.
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Tentukan wilayah operasional instans IPAM.
}

# Buat kolam IPAM.
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Tentukan cakupan kolam IPAM.
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Tentukan wilayah kolam IPAM.
  ip_version     = "IPv4"                                     # Tentukan versi IP kolam IPAM.
}

# Alokasikan CIDR ke kolam IPAM.
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Tentukan CIDR.
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Tentukan ID kolam IPAM.
}

# Buat VPC.
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Tentukan ID kolam IPAM.
  ipv4_cidr_mask    = 24                                                 # Masker jaringan IPv4.
}