Virtual Private Cloud:VPC sharing

1. Enable sharing

This section only describes how to share a vSwitch with other accounts. See sharing resources within a resource directory for more.

1. Log on to the owner account and go to the Resource Sharing - Resources I Share page in the Resource Management console. In the upper-left corner of the top menu bar, select the region where the resource to be shared is located, and click Create Resource Share. On the page that appears:

   Step 1: Enter a Resource Share Name, and select the vSwitch to be shared.

   Step 2: The AliyunRSDefaultPermissionVSwitch permission is selected by default.

   Step 3: For Principal Scope, select All Accounts. For Method, select Add Manually. Enter the Alibaba Cloud account ID of the participants, and click Add.

   Step 4: Verify the information, and click OK.

2. Log on to the participant account and accept the sharing invitation:

   1. Go to the Resource Sharing - Resources Shared to Me page.

   2. In the upper-left corner of the top menu bar, select the region where the shared resource is located, and click Accept in the Status column of the target resource share.

   3. After accepting, the participant can access the shared vSwitch, and any new shared resources added to this resource share will be automatically accepted.

Step 2: Create cloud resources in a shared vSwitch

Log on to the principal account:

1. Go to the vSwitch page in the VPC console. Select the region of the shared vSwitch in the top menu bar, and you'll see the shared vSwitch (marked as "from sharing").

   

2. To create ECS, RDS, and SLB instances, click Add Cloud Service in the Actions column of the target shared vSwitch.

3. For other resource types that can be created in shared vSwitches, select the shared vSwitch when you create them.

Step 1: Enable sharing

• Method 1: Share with any account

  1. Call CreateResourceShare with the owner credentials to create a resource share. Make sure to set the AllowExternalTargets parameter to True.

  2. Use the participant credentials to call ListResourceShareInvitations to query the invitations, and call AcceptResourceShareInvitation to accept the invitation.

• Method 2: Share within a resource directory

  1. Call EnableSharingWithResourceDirectory with the owner credential to enable resource directory sharing.

  2. Call CreateResourceShare with the participant credentials to create a resource share. Make sure to set the AllowExternalTargets parameter to False.

Step 2: Create cloud resources

Log on to the principal account.

1. Call DescribeVSwitches to get the list of vSwitches.

2. In the vSwitch list, filter out shared vSwitches (where the ShareType field is Sharing).

3. Call the creation operation of the resource (such as RunInstances for ECS) to create cloud resources based on the shared vSwitch.

Step 1: Enable sharing

The vSwitch owner creates a resource share:

Currently, Terraform does not support sharing vSwitches with any account. It only supports sharing within a resource directory. Before you perform operations, make sure the vSwitch owner has enabled resource sharing.

Resources: alicloud_resource_manager_resource_share, alicloud_resource_manager_shared_resource, alicloud_resource_manager_shared_target

# Specify the region.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Specify the name of the resource share.
resource "alicloud_resource_manager_resource_share" "example_unit" {
  resource_share_name = "example_unit_name"
}

# Specify the shared vSwitch.
resource "alicloud_resource_manager_shared_resource" "example_vsw" {
  resource_share_id = alicloud_resource_manager_resource_share.example_unit.id
  resource_id       = "vsw-bp1omg98fixldnwcxxxxx" # Replace the value with the ID of the shared vSwitch.
  resource_type     = "VSwitch"                   # The resource type is VSwitch. 
}

# Specify the principal of the shared vSwitch.
resource "alicloud_resource_manager_shared_target" "example_target" {
  resource_share_id = alicloud_resource_manager_resource_share.example_unit.id
  target_id         = "10xxxxxxxxxxxxxx" # Replace the value with the UID of the vSwitch principal.
}

Step 2: Create cloud resources in a shared vSwitch

The following example shows how a vSwitch participant creates an ECS instance in a shared vSwitch:

Resources: alicloud_security_group, alicloud_instance

Data sources: alicloud_vswitches

# Specify the region.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Specify the shared vSwitch.
variable "vsw_id" {
  default = "vsw-bp1omg98fixldnwcxxxxx" # Replace the value with the ID of the shared vSwitch.
}

# Obtain information about the target shared vSwitch.
data "alicloud_vswitches" "example_vsw" {
  ids = [var.vsw_id]  
}

# Create a security group.
resource "alicloud_security_group" "example_sg" {
  security_group_name = "example_sg_name"
  vpc_id              = data.alicloud_vswitches.example_vsw.vswitches[0].vpc_id
}

# Create an ECS instance.
resource "alicloud_instance" "example_ecs" {
  instance_name        = "example_ecs_name"
  instance_type        = "ecs.e-c1m1.large"
  security_groups      = [alicloud_security_group.example_sg.id]
  vswitch_id           = var.vsw_id
  image_id             = "aliyun_3_x64_20G_alibase_20250117.vhd"
  system_disk_category = "cloud_essd"
}

View shared vSwitches and participants

The vSwitch owner views resource shares, shared resources, and participants:

Datasources: alicloud_resource_manager_resource_shares, alicloud_resource_manager_shared_resources, alicloud_resource_manager_shared_targets

# Specify the region.
provider "alicloud" {
  region = "cn-hangzhou"
}

# The list of resource shares.
data "alicloud_resource_manager_resource_shares" "example_units" {
  resource_share_owner = "Self" # View the resource shares that you have shared with other accounts.
}
# Output the list.
output "first_resource_manager_resource_share_id" {
  value = data.alicloud_resource_manager_resource_shares.example_units.shares
}

# The list of shared resources.
data "alicloud_resource_manager_shared_resources" "example_resources" {
}
# Output the list.
output "first_resource_manager_shared_resource_id" {
  value = data.alicloud_resource_manager_shared_resources.example_resources.resources
}

# The list of principals of the shared resources.
data "alicloud_resource_manager_shared_targets" "example_targets" {
}
# Output the list.
output "first_resource_manager_shared_target_id" {
  value = data.alicloud_resource_manager_shared_targets.example_targets.targets
}

Add or delete a shared vSwitch

A vSwitch owner can add or delete alicloud_resource_manager_shared_resource in the .tf file to add or delete a shared vSwitch.

Add or delete a principal for a shared vSwitch

A vSwitch owner can add or delete alicloud_resource_manager_shared_target in the .tf file to add or delete a principal for a shared vSwitch.