边缘安全加速：使用Terraform配置等候室

安装Terraform并配置权限

涉及的资源

• 创建站点：alicloud_esa_site

• 创建等候室：alicloud_esa_waiting_room

• 查询ESA实例：alicloud_esa_sites

配置等候室

1. 创建一个名为 main.tf 的配置文件，然后将以下代码复制到配置文件中，用于配置等候室。

   # 1. 查询企业版 ESA 实例
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # 筛选企业版实例
   }
   
   # 2. 创建站点
   resource "alicloud_esa_site" "resource_Site_example" {
     site_name   = "{{DOMAIN}}"  # 替换为实际域名，如 example.com
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # 海外加速
     access_type = "NS"         # NS 接入方式
   }
   
   # 3. 创建等候室
   resource "alicloud_esa_waiting_room" "default" {
     site_id                        = alicloud_esa_site.resource_Site_example.id
     waiting_room_name              = "waitingroom_example"  # 等候室名称
     description                    = "example"
     status                         = "off"  # 创建后默认关闭，需手动开启
     waiting_room_type              = "default"
   
     # 排队策略配置
     queuing_method                 = "fifo"  # 先进先出排队算法
     session_duration               = "5"    # 会话时长（分钟）
     total_active_users             = "300"  # 最大并发用户数
     new_users_per_minute           = "200"  # 每分钟放行人数
   
     # 匹配规则：触发排队的条件
     host_name_and_path {
       domain    = "sub_domain.com"         # 主域名
       path      = "/example"                # 路径匹配
       subdomain = "example_sub_domain.com."  # 子域名
     }
   
     # 页面显示配置
     language                       = "zhcn"  # 排队页面语言：简体中文
     custom_page_html               = ""      # 空表示使用默认排队页面
     queuing_status_code            = "200"   # 排队时返回的HTTP状态码
     cookie_name                    = "__aliwaitingroom_example"  # Cookie名称
   
     # 高级选项
     queue_all_enable               = "off"  # 是否全员排队
     disable_session_renewal_enable = "off"  # 是否禁用会话续期
     json_response_enable           = "off"  # 是否返回JSON响应
   }

   说明

   请根据实际情况修改代码中的占位符：将 DOMAIN 替换为您的实际域名，将 host_name_and_path 中的域名和路径替换为实际触发排队的条件。关键参数说明请参见本文末尾的相关参考章节。

2. 进入配置文件所在目录，执行如下命令，初始化Terraform环境。

   terraform init

3. 执行如下命令，验证Terraform语法与配置。

   terraform validate

4. 执行如下命令，预览执行结果。

   terraform plan

5. 执行如下命令，执行Terraform脚本。

   terraform apply

6. 依据提示输入yes确认执行即可。

验证结果

terraform show

相关参考

本文代码示例中关键参数的说明如下：

更多参数说明,请参见alicloud_esa_waiting_room。

不同套餐的支持情况