Virtual Private Cloud:VPCs and vSwitches

VPC ve vSwitch oluşturma

1. VPC konsolunda VPC Oluştur sayfasına gidin.

2. VPC'yi yapılandırın:

   1. Bölge: Bulut kaynaklarını oluşturmayı planladığınız bölgeyi seçin.

   2. IPv4 CIDR bloğu: Konsol tarafından önerilen bir CIDR bloğunu seçin veya özel bir tane girin. Birden fazla VPC bağlarken, çakışmaları önlemek için örtüşmeyen CIDR blokları kullanmanızı öneririz. CIDR bloğu çakışmalarını önlemek ve ağ ölçeklenebilirliğini sağlamak için IPAM kullanarak VPC oluşturmanızı öneririz.

      1. VPC'nin CIDR bloğu için, maske uzunluğu 16 ile 28 arasında olan RFC 1918 standardında belirtilen özel IPv4 adreslerini kullanmanızı öneririz. Örnekler: 10.0.0.0/16, 172.16.0.0/16 ve 192.168.0.0/16.

      2. VPC için IPv4 CIDR bloğu olarak 100.64.0.0/10, 224.0.0.0/4, 127.0.0.0/8 veya 169.254.0.0/16 kullanamazsınız.

3. vSwitch'i yapılandırın:

   1. Alan: Bulut kaynaklarını oluşturacağınız alanı seçin. Seçiminiz kaynak kullanılabilirliğine dayanmalıdır; çünkü bazı kaynaklar o alanda tükenmiş olabilir.

   2. IPv4 CIDR bloğu: Konsol tarafından sağlanan varsayılan CIDR bloğunu seçin veya ihtiyaca göre adres aralığını ayarlayın.

   3. Daha fazla vSwitch ekleyin: Uygulamalarınızı tek alan arızalarından korumak için farklı alanlarda birden fazla vSwitch oluşturmanızı öneririz. VPC'yi oluştururken vSwitch'ler oluşturabilir veya daha sonra VPC konsolundaki vSwitch'ler sayfasına giderek ekleyebilirsiniz.

VPC ve vSwitch silme

Hedef VPC veya vSwitch'in Actions sütununda veya ayrıntılar sayfasında Delete seçeneğini tıklayın. Sistem, yayımlanmamış bulut kaynakları veya ilişkili kaynaklar olup olmadığını kontrol eder. Bağımlılıklar varsa, VPC'yi veya vSwitch'i silebilmeniz için bunları serbest bırakmanız gerekir.

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Use a data source to automatically retrieve a list of zones where you can create vSwitches.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query for zones where vSwitches can be created in the VPC.
  # available_instance_type = "ecs.g7.large"  # Query for zones where ECS instances can be created in the VPC.
  # available_resource_creation = "slb"  # Query for zones where SLB instances can be created in the VPC.
}

# Create a VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # Specify the CIDR block. 
}

# Create a vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # Specify the CIDR block. 
  vpc_id       = alicloud_vpc.example_vpc.id                       # Specify the ID of the VPC to which the vSwitch belongs. 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # Specify the zone to which the vSwitch belongs.
}

IPv6'yı etkinleştirme

• Bir VPC ve vSwitch oluştururken IPv6'yı aşağıdaki yollardan biriyle etkinleştirebilirsiniz:

  • Allocated by system seçeneğini belirleyin ve ardından açılır listeden Assign BGP (Multi-ISP) seçeneğini seçin. Sistem otomatik olarak bir IPv6 Ağ Geçidi oluşturur ve bir IPv6 CIDR bloğu atar.

  • IP adreslerini merkezi olarak yönetmek için Allocated by IPAM seçeneğini belirleyin. Önceden hazırlanmış bir IPv6 CIDR bloğuna sahip bir IPAM havuzu seçin ve ardından havuzdan bir IPv6 CIDR bloğu tahsis etmek için bir maske yapılandırın veya bir CIDR bloğu belirtin.

• Mevcut bir VPC için, Enable IPv6 sütununda IPv6 CIDR seçeneğini tıklayın:

  • Allocated by system veya Allocated by IPAM seçeneğini belirleyin.

  • Sistem tahsisini seçerseniz, Automatically Enable IPv6 for All vSwitches onay kutusunu seçebilirsiniz. Bu onay kutusunu seçmezseniz veya IPAM ile tahsisi seçerseniz, hedef vSwitch'e gidip IPv6 CIDR sütununda Enable IPv6 seçeneğini tıklamanız gerekir.

IPv6'yı devre dışı bırakma

Hedef VPC veya vSwitch için IPv6 CIDR sütununda Disable IPv6 seçeneğini tıklayın. Bir VPC için IPv6'yı devre dışı bırakmak üzere, önce tüm vSwitch'leri için IPv6'yı devre dışı bırakmanız ve ilişkili IPv6 Ağ Geçidi'ni silmeniz gerekir.

Ayrılmış CIDR bloğu oluşturma

1. Hedef vSwitch'in Basic Information sayfasında, ayrılmış bir IPv4 veya IPv6 CIDR bloğu eklemek için Reserved CIDR Block sekmesini tıklayın. Bir CIDR bloğunu iki yoldan biriyle ekleyebilirsiniz:

   • Specify CIDR Block: Ayırmak istediğiniz adres bloğunu hassas bir şekilde kontrol edin.

   • Specify Mask Length: Sistem, kullanılabilir adres alanından otomatik olarak ayrılmış bir CIDR bloğu ayırır.

2. IPv6 için, vSwitch'te IPv6 etkin değilse Enable IPv6 seçeneğini tıklayın. Enable IPv6 iletişim kutusunda, vSwitch için IPv6 CIDR bloğunu yapılandırın.

   VPC için IPv6 etkin değilse, açılan Enable IPv6 iletişim kutusunda öncelikle IPv6 CIDR Block Type değerini varsayılan değer olan Assign BGP (Multi-ISP) olarak ayarlayın ve ardından vSwitch için IPv6 CIDR bloğunu yapılandırın.

Kullanılan IP adreslerini görüntüleme

Hedef vSwitch'in Reserved CIDR Block sekmesinde, IPv4 CIDR veya IPv6 CIDR sekmesini tıklayın. Hedef ayrılmış CIDR bloğunu bulun ve Actions sütununda View Used IP seçeneğini tıklayın. Kullanılan IP adreslerini ve karşılık gelen ENI'leri görüntüleyebilirsiniz.

Ayrılmış CIDR bloğunu silme

Ayrılmış bir CIDR bloğunu silmeden önce, içindeki hiçbir IP adresinin kullanılmadığından emin olun.

Hedef vSwitch'in Basic Information sayfasında, Reserved CIDR Block sekmesini tıklayın. IPv4 CIDR veya IPv6 CIDR sekmesinde, silmek istediğiniz ayrılmış CIDR bloğunu bulun ve Delete sütununda Actions seçeneğini tıklayın.

# Specify the region where the resource is located.
provider "alicloud" {
  region = "cn-hangzhou" # The region where the resource resides.
}

# Specify the ID of the vSwitch.
variable "vsw_id" {
  default = "vsw-xxx" # Replace with the actual ID of your vSwitch.
}

# Create a reserved CIDR block.
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # Specify the reserved CIDR block. 
}

# Specify the region where you want to create the IPAM instance, IPAM pool, and VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Create an IPAM instance.
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Specify the operating region of the IPAM instance.
}

# Create an IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Specify the scope of the IPAM pool.
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Specify the region of the IPAM pool.
  ip_version     = "IPv4"                                     # Specify the IP version of the IPAM pool.
}

# Allocate a CIDR to the IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Specify the CIDR.
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
}

# Create a VPC.
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
  ipv4_cidr_mask    = 24                                                 # The IPv4 network mask.
}