Elastic Compute Service:Terraform reference

Terraform'un temel özellikleri

Terraform, BT altyapısı otomasyonu ve düzenleme aracıdır. BT kaynaklarını kodla yönetmenize ve bakımını yapmanıza olanak tanır. Daha fazla bilgi için bkz. Terraform Nedir?.

• Terraform komut satırı arayüzü (CLI), yapılandırma dosyalarını Alibaba Cloud veya desteklenen diğer cloud ortamlarına dağıtmak ve sürümlerini yönetmek için basit bir yol sağlar. Bulut kaynak topolojinizi açıklayan yapılandırma dosyalarında sanal makineler, depolama hesapları ve ağ arabirimleri gibi altyapınızı tanımlayabilirsiniz.

• Terraform, sağlayıcılar aracılığıyla yeni altyapıları destekler. Bu sayede basit bir şablon dili kullanarak Alibaba Cloud üzerinde cloud altyapısını kolayca tanımlayabilir, ön izleyebilir ve dağıtabilirsiniz.

• Terraform'u birden çok Alibaba Cloud hizmetinin kaynaklarını oluşturmak, değiştirmek ve silmek için kullanabilirsiniz.

Alibaba Cloud ve Terraform entegrasyonu hakkında daha fazla bilgi için bkz. Alibaba Cloud Sağlayıcısı.

Terraform'u yükleme

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Terraform'u kimlik doğrulama

Erişim kimlik bilgilerini ortam değişkenlerinde saklayarak Terraform'u kimlik doğrulayabilirsiniz. Bir Terraform komutu çalıştırdığınızda, bu değişkenler yapılandırma şablonunda açıkça bildirilmemişse Terraform kimlik bilgilerini bu değişkenlerden almaya çalışır. Aşağıdaki bölümlerde ortam değişkenlerinin nasıl ayarlanacağı açıklanmaktadır.

# AccessKey ID
$ export ALICLOUD_ACCESS_KEY="<your AccessKey ID>"
# AccessKey secret
$ export ALICLOUD_SECRET_KEY="<your AccessKey secret>"
# If you use STS credentials, you must configure security_token.
$ export ALICLOUD_SECURITY_TOKEN="<your access token>"

Ortam değişkenlerini ayarladıktan sonra provider bloğunda kimlik bilgilerini bildirmeniz gerekmez. Yalnızca bölgeyi bildirebilirsiniz.

provider "alicloud" {
  region = "cn-hangzhou"
}

Bölgeyi ALICLOUD_REGION ortam değişkenini kullanarak da yapılandırabilirsiniz. Bölge açıkça bildirilmez ve bu ortam değişkeni ayarlanmazsa varsayılan değer cn-beijing olur.

Desteklenen kaynaklar

Terraform'u kullanarak ECS kaynaklarını oluşturma ve yönetme

Bu bölümde Terraform ile ECS kaynaklarının nasıl oluşturulup yönetileceğine ilişkin bir örnek sunulmaktadır.

1. Bir çalışma dizini oluşturun. Dizin içinde main.tf adlı bir yapılandırma dosyası oluşturun. Aşağıdaki kod bir ECS örneği ve bunun için gereken VPC, güvenlik grubu ve vSwitch kaynaklarını oluşturur. Kodu main.tf dosyasına kopyalayın.

   # Define a variable "region" with the default value "cn-beijing" to specify the Alibaba Cloud region.
   variable "region"{
     default = "cn-beijing"
   }
   
   # Configure the Alibaba Cloud provider to use the region defined in the "region" variable.
   provider "alicloud"{
     region = var.region
   }
   
   # Define a string variable "instance_type" with the default value "ecs.e-c1m1.large" to specify the ECS instance type.
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # Use a data source to query zone information. Filter the results by the specified instance type, resource creation type (such as VSwitch), and disk category.
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # Define a variable "vpc_cidr_block" with the default value "172.16.0.0/16" to specify the CIDR block for the VPC.
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # Define a variable "vsw_cidr_block" with the default value "172.16.0.0/24" to specify the CIDR block for the vSwitch.
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # Generate a random integer between 10000 and 99999 to ensure the uniqueness of some resource names.
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # Create a VPC named "vpc-test" and use the random integer to ensure the name is unique.
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # Create a security group, include the random integer in the name to ensure uniqueness, and associate it with the VPC created above.
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # The field name here was replaced.
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # Create a security group rule to allow all inbound TCP traffic and associate it with the previously created security group.
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # Modified here, nic_type is changed to 'intranet'.
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # Create a vSwitch, include the random integer in the name to ensure uniqueness, and associate it with the VPC and zone.
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # Create an ECS instance. Set multiple parameters such as the zone, security group, and instance type. Use the random integer to ensure the instance name is unique.
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # Modify the password based on your requirements.
   }

2. Terraform çalışma zamanı ortamını başlatmak için aşağıdaki komutu çalıştırın.

   terraform init

   Aşağıdaki çıktı, Terraform'un başarıyla başlatıldığını gösterir.

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. Kodu yürütmek için aşağıdaki komutu çalıştırın.

   terraform apply

   Yürütme sırasında istendiğinde yes girin ve Enter tuşuna basın. Komutun tamamlanmasını bekleyin. Aşağıdaki çıktı görünürse kod başarıyla yürütülmüş demektir.

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. Sonuçları doğrulayın

terraform show

Referanslar

• Daha fazla öğretici için bkz. Terraform Öğreticileri.

• Yaygın Terraform komutları hakkında daha fazla bilgi için bkz. Yaygın Komutlar.

• Terraform, ROS'ta yönetilen bir hizmet olarak kullanılabilir. ROS konsolunda Terraform şablonlarını dağıtabilirsiniz. Daha fazla bilgi için bkz. Terraform yığını oluşturma.