使用Terraform修改RDS PostgreSQL執行個體參數並查詢參數修改日誌-Terraform-阿里雲

本文介紹如何使用Terraform修改參數以及查詢參數修改日誌。

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

前提條件

已建立RDS PostgreSQL執行個體，詳情請參見建立RDS PostgreSQL執行個體。
執行個體狀態為運行中，您可以通過如下兩種方式查看：
- 參見查詢執行個體詳情查看參數status，如果取值為Running則表示執行個體狀態為運行中。
- 前往RDS管理主控台，切換到目標地區，找到指定執行個體後，查看執行個體狀態。
由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

通過RAM授權，RAM使用者可以有效地管理其雲資源存取權限，適應多使用者協同工作的需求，並且能夠按需為使用者指派最小許可權，避免許可權過大導致的安全性漏洞。具體操作方式請參見為RAM使用者授權。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

使用的資源

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

alicloud_vpc：建立Virtual Private Cloud。
alicloud_vswitch：建立專用網路交換器。
alicloud_db_instance：建立RDS PostgreSQL執行個體。

修改參數

說明

部分參數修改後會立即重啟執行個體，詳情請參見控制台上可修改參數頁面中的是否重啟列。重啟執行個體會造成串連中斷，重啟前請做好業務安排，謹慎操作。

本文以修改參數authentication_timeout的取值為120為例。

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下代碼複製到main.tf中。

建立前置資源。

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體（預設版本為rds_postgres_1300_20240229）
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

在main.tf檔案的resource "alicloud_db_instance" "instance" {}中增加parameters配置項，具體配置如下。

...
resource "alicloud_db_instance" "instance" {
...
parameters {
    name  = "authentication_timeout"
    value = "120"  
   }       
}

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_db_instance.instance: Modifying... [id=pgm-****]
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 10s elapsed]
...
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 3m10s elapsed]
alicloud_db_instance.instance: Modifications complete after 3m10s [id=pgm-****]

Apply complete! Resources: 0 added, 1 changed, 0 destroyed.

驗證結果。

執行terraform show命令

您可以使用以下命令查看參數修改情況。

terraform show

# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    acl                            = null
    auto_upgrade_minor_version     = "Auto"
    ca_type                        = null
    category                       = "HighAvailability"
    client_ca_cert                 = (sensitive value)
    client_ca_enabled              = 0
    client_cert_revocation_list    = null
    client_crl_enabled             = 0
    connection_string              = "pgm-f8z03v853neh87k8.pg.rds.aliyuncs.com"
    connection_string_prefix       = "pgm-f8z03v853neh87k8"
    create_time                    = "2024-10-31T02:29:36Z"
    db_instance_ip_array_attribute = null
    db_instance_ip_array_name      = null
    db_instance_storage_type       = "cloud_essd"
    db_instance_type               = "Primary"
    db_param_group_id              = null
    db_time_zone                   = "Asia/Shanghai"
    deletion_protection            = false
    engine                         = "PostgreSQL"
    engine_version                 = "13.0"
    force_restart                  = false
    ha_config                      = "Auto"
    id                             = "pgm-f8z03v853neh87k8"
    instance_charge_type           = "Postpaid"
    instance_name                  = null
    instance_storage               = 30
    instance_type                  = "pg.n2.2c.2m"
    maintain_time                  = "18:00Z-22:00Z"
    manual_ha_time                 = null
    monitoring_period              = 300
    node_id                        = "32990438"
    period                         = 0
    port                           = "5432"
    private_ip_address             = "172.16.206.226"
    replication_acl                = null
    resource_group_id              = "rg-acfmykd63gtpfpa"
    security_group_ids             = []
    security_ip_mode               = "normal"
    security_ip_type               = null
    security_ips                   = [
        "127.0.0.1",
    ]
    server_cert                    = (sensitive value)
    server_key                     = null
    sql_collector_config_value     = 30
    sql_collector_status           = "Disabled"
    ssl_action                     = "Close"
    ssl_connection_string          = null
    ssl_status                     = null
    status                         = "Running"
    storage_auto_scale             = null
    storage_threshold              = 0
    storage_upper_bound            = 0
    target_minor_version           = "rds_postgres_1300_20240830"
    tcp_connection_type            = "LONG"
    tde_status                     = "Disabled"
    vpc_id                         = "vpc-f8zvtuuan0tjyas7muymk"
    vswitch_id                     = "vsw-f8zjvdbtv24927fmvrydl"
    whitelist_network_type         = null
    zone_id                        = "cn-heyuan-a"

    parameters {
        name  = "authentication_timeout"
        value = "120"
    }
}

登入RDS管理主控台

登入RDS管理主控台查看參數修改情況。修改參數

查詢參數修改日誌

在上述main.tf檔案中增加data "alicloud_rds_modify_parameter_logs" "querylogs"配置項，具體配置如下：

...
resource "time_static" "example" {}

data "alicloud_rds_modify_parameter_logs" "querylogs" {
  db_instance_id = alicloud_db_instance.instance.id
  start_time     = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "-12h"))
  end_time       = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "12h"))
}

執行以下命令。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_db_instance.instance: Refreshing state... [id=pgm-****]
data.alicloud_rds_modify_parameter_logs.querylogs: Reading...
alicloud_db_backup_policy.instance: Refreshing state... [id=pgm-****]
data.alicloud_rds_modify_parameter_logs.querylogs: Read complete after 0s [id=6335****]

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are needed.

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

驗證結果。

執行terraform show命令

您可以使用以下命令查看參數修改日誌。

terraform show

# data.alicloud_rds_modify_parameter_logs.querylogs:
data "alicloud_rds_modify_parameter_logs" "querylogs" {
    db_instance_id = "pgm-f8z03v853neh87k8"
    end_time       = "2024-10-31T23:59Z"
    id             = "6722ee94"
    logs           = [
        {
            modify_time         = "1730342339000"
            new_parameter_value = "120"
            old_parameter_value = "60"
            parameter_name      = "authentication_timeout"
            status              = "Applied"
        },
    ]
    start_time     = "2024-10-31T00:00Z"
}

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-heyuan"
}

variable "zone_id" {
  default = "cn-heyuan-a"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  # 修改參數,修改完參數後需再次運行terraform apply
  parameters {
    name  = "authentication_timeout"
    value = "120"
  }
}
# 擷取目前時間
resource "time_static" "example" {}

# 查詢參數修改日誌
data "alicloud_rds_modify_parameter_logs" "querylogs" {
  db_instance_id = alicloud_db_instance.instance.id
  start_time     = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "-12h"))
  end_time       = formatdate("YYYY-MM-DD'T'hh:mm'Z'", timeadd(time_static.example.rfc3339, "12h"))
}

如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。

Terraform：通過Terraform管理RDS PostgreSQL執行個體參數

前提條件

使用的資源

修改參數

執行terraform show命令

登入RDS管理主控台

查詢參數修改日誌

執行terraform show命令

清理資源

完整樣本

範例程式碼

相關文檔