使用Terraform管理RDS PostgreSQL資料庫-雲資料庫 RDS-阿里雲

本文介紹如何使用Terraform建立和刪除RDS PostgreSQL資料庫以及修改或添加資料庫備忘資訊。

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

前提條件

已建立RDS PostgreSQL執行個體，詳情請參見建立RDS PostgreSQL執行個體。
執行個體狀態為運行中，您可以通過如下兩種方式查看：
- 參見查詢執行個體詳情查看參數status，如果取值為Runing則表示執行個體狀態為運行中。
- 前往RDS管理主控台，切換到目標地區，找到指定執行個體後，查看執行個體狀態。
由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

通過RAM授權，RAM使用者可以有效地管理其雲資源存取權限，適應多使用者協同工作的需求，並且能夠按需為使用者指派最小許可權，避免許可權過大導致的安全性漏洞。具體操作方式請參見為RAM使用者授權。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

使用的資源

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

alicloud_db_database：建立資料庫。
alicloud_vpc：建立Virtual Private Cloud。
alicloud_vswitch：建立專用網路交換器。
alicloud_db_instance：建立RDS PostgreSQL執行個體。

建立資料庫

以建立名為tf_database_test的資料庫為例。

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下代碼複製到main.tf中。

建立前置資源。

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

在main.tf檔案中增加resource "alicloud_db_instance" "instance" {}配置項。

...
resource "alicloud_db_database" "db" {
  instance_id = alicloud_db_instance.instance.id
  name        = "tf_database_test"
}

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_db_database.db: Creating...
alicloud_db_database.db: Creation complete after 1s [id=pgm-****:tf_database_test]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

驗證結果。

執行terraform show命令

您可以使用以下命令查詢資料庫資訊：

terraform show

# alicloud_db_database.db:
resource "alicloud_db_database" "db" {
    character_set = "UTF8"
    id            = "pgm-****:tf_database_test"
    instance_id   = "pgm-****"
    name          = "tf_database_test"
}
# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    client_ca_enabled          = 0
    client_crl_enabled         = 0
    connection_string          = "pgm-****.pg.rds.aliyuncs.com"
    connection_string_prefix   = "pgm-****"
    db_instance_storage_type   = "cloud_essd"
    db_time_zone               = "Asia/Shanghai"
    deletion_protection        = false
    engine                     = "PostgreSQL"
    engine_version             = "13.0"
    force_restart              = false
    ha_config                  = "Auto"
    id                         = "pgm-****"
    instance_charge_type       = "Postpaid"
    instance_name              = "terraformtest"
    instance_storage           = 50
    instance_type              = "pg.n2.2c.2m"
    maintain_time              = "05:00Z-06:00Z"
    monitoring_period          = 300
    period                     = 0
    port                       = "5432"
    private_ip_address         = "172.16.XX.XX"
    resource_group_id          = "rg-****"
    security_group_ids         = []
    security_ip_mode           = "normal"
    security_ips               = [
        "127.0.0.1",
    ]
    sql_collector_config_value = 30
    sql_collector_status       = "Disabled"
    storage_auto_scale         = "Enable"
    storage_threshold          = 30
    storage_upper_bound        = 100
    target_minor_version       = "rds_postgres_1300_20220730"
    tcp_connection_type        = "SHORT"
    vpc_id                     = "vpc-****"
    vswitch_id                 = "vsw-****"
    zone_id                    = "cn-hangzhou-j"
}

登入RDS管理主控台

登入RDS管理主控台查看資料庫資訊。建立資料庫

修改或添加資料庫備忘

以添加tf_database_test資料庫的備忘資訊為terraform_test為例。

在上述main.tf檔案的resource "alicloud_db_database" "db"中，增加description配置項，具體配置如下。
```
...
resource "alicloud_db_database" "db" {
...
  description = "terraform_test"
}
```

運行terraform apply。

出現如下配置資訊後，確認配置資訊並輸入yes，開始添加配置。

alicloud_vpc.main: Refreshing state... [id=vpc-****]
alicloud_vswitch.main: Refreshing state... [id=vsw-****]
alicloud_db_instance.instance: Refreshing state... [id=pgm-****]
alicloud_db_database.db: Refreshing state... [id=pgm-****:tf_database_test]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the
following symbols:
-/+ destroy and then create replacement

Terraform will perform the following actions:

  # alicloud_db_database.db must be replaced
-/+ resource "alicloud_db_database" "db" {
      ~ character_set = "UTF8" -> "utf8" # forces replacement
      + description   = "terraform_test"
      ~ id            = "pgm-****:tf_database_test" -> (known after apply)
        name          = "tf_database_test"
        # (1 unchanged attribute hidden)
    }

Plan: 1 to add, 0 to change, 1 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve. 

  Enter a value:

出現類似如下日誌時，表示配置成功。

alicloud_db_database.db: Destroying... [id=pgm-****:tf_database_test]
alicloud_db_database.db: Destruction complete after 1s
alicloud_db_database.db: Creating...
alicloud_db_database.db: Creation complete after 1s [id=pgm-****:tf_database_test]

Apply complete! Resources: 1 added, 0 changed, 1 destroyed.

查看結果。

執行terraform show命令

您可以使用以下命令查看結果：

terraform show

# alicloud_db_database.db:
resource "alicloud_db_database" "db" {
    character_set = "UTF8"
    description   = "terraform_test"
    id            = "pgm-****:tf_database_test"
    instance_id   = "pgm-****"
    name          = "tf_database_test"
}
# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    client_ca_enabled          = 0
    client_crl_enabled         = 0
    connection_string          = "pgm-****.pg.rds.aliyuncs.com"
    connection_string_prefix   = "pgm-****"
    db_instance_storage_type   = "cloud_essd"
    db_time_zone               = "Asia/Shanghai"
    deletion_protection        = false
    engine                     = "PostgreSQL"
    engine_version             = "13.0"
    force_restart              = false
    ha_config                  = "Auto"
    id                         = "pgm-****"
    instance_charge_type       = "Postpaid"
    instance_name              = "terraformtest"
    instance_storage           = 50
    instance_type              = "pg.n2.2c.2m"
    maintain_time              = "05:00Z-06:00Z"
    monitoring_period          = 300
    period                     = 0
    port                       = "5432"
    private_ip_address         = "172.16.XX.XX"
    resource_group_id          = "rg-****"
    security_group_ids         = []
    security_ip_mode           = "normal"
    security_ips               = [
        "127.0.0.1",
    ]
    sql_collector_config_value = 30
    sql_collector_status       = "Disabled"
    storage_auto_scale         = "Enable"
    storage_threshold          = 30
    storage_upper_bound        = 100
    target_minor_version       = "rds_postgres_1300_20220730"
    tcp_connection_type        = "SHORT"
    vpc_id                     = "vpc-****"
    vswitch_id                 = "vsw-****"
    zone_id                    = "cn-hangzhou-j"
}

登入RDS管理主控台

登入RDS管理主控台查看結果。備忘資訊

刪除資料庫

以刪除名為tf_database_test的資料庫為例。

在上述main.tf檔案中，刪除resource "alicloud_db_database" "db"配置項的內容。例如，刪除如下資訊：

...
resource "alicloud_db_database" "db" {
  instance_id = alicloud_db_instance.instance.id
  name        = "tf_database_test"
  description = "terraform_test"
}

運行terraform apply。

出現如下配置資訊後，確認配置資訊並輸入yes，開始刪除。

alicloud_db_database.db: Refreshing state... [id=pgm-****:tf_database_test]
alicloud_vpc.main: Refreshing state... [id=vpc-****]
alicloud_vswitch.main: Refreshing state... [id=vsw-****]
alicloud_db_instance.instance: Refreshing state... [id=pgm-****]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the
following symbols:
  - destroy

Terraform will perform the following actions:

  # alicloud_db_database.db will be destroyed
  # (because alicloud_db_database.db is not in configuration)
  - resource "alicloud_db_database" "db" {
      - character_set = "UTF8" -> null
      - description   = "terraform_test" -> null
      - id            = "pgm-****:tf_database_test" -> null
      - instance_id   = "pgm-****" -> null
      - name          = "tf_database_test" -> null
    }

Plan: 0 to add, 0 to change, 1 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value:

出現類似如下日誌時，表示刪除成功。

alicloud_db_database.db: Destroying... [id=pgm-****:tf_database_test]
alicloud_db_database.db: Destruction complete after 1s

Apply complete! Resources: 0 added, 0 changed, 1 destroyed.

查看結果。

執行terraform show命令

您可以使用以下命令確認資料庫已刪除。

terraform show

# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    client_ca_enabled          = 0
    client_crl_enabled         = 0
    connection_string          = "pgm-****.pg.rds.aliyuncs.com"
    connection_string_prefix   = "pgm-****"
    db_instance_storage_type   = "cloud_essd"
    db_time_zone               = "Asia/Shanghai"
    deletion_protection        = false
    engine                     = "PostgreSQL"
    engine_version             = "13.0"
    force_restart              = false
    ha_config                  = "Auto"
    id                         = "pgm-****"
    instance_charge_type       = "Postpaid"
    instance_name              = "terraformtest"
    instance_storage           = 50
    instance_type              = "pg.n2.2c.2m"
    maintain_time              = "05:00Z-06:00Z"
    monitoring_period          = 300
    period                     = 0
    port                       = "5432"
    private_ip_address         = "172.16.XX.XX"
    resource_group_id          = "rg-****"
    security_group_ids         = []
    security_ip_mode           = "normal"
    security_ips               = [
        "127.0.0.1",
    ]
    sql_collector_config_value = 30
    sql_collector_status       = "Disabled"
    storage_auto_scale         = "Enable"
    storage_threshold          = 30
    storage_upper_bound        = 100
    target_minor_version       = "rds_postgres_1300_20220730"
    tcp_connection_type        = "SHORT"
    vpc_id                     = "vpc-****"
    vswitch_id                 = "vsw-****"
    zone_id                    = "cn-hangzhou-j"
}

登入RDS管理主控台

登入RDS管理主控台查看資料庫已刪除空資料庫

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

# 建立VPC
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立RDS PostgreSQL執行個體
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  # 如果不需要建立VPC和交換器，使用已有的VPC和交換器
  # vswitch_id       = "vsw-****"
  # 建立多個配置相同的RDS PostgreSQL執行個體，x為需要建立的執行個體數量
  #count = x
}

resource "alicloud_db_database" "db" {
  instance_id = alicloud_db_instance.instance.id
  name        = "tf_database_test"
  # 修改或添加資料庫備忘
  description = "terraform_test"
}

如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。