PolarDB：錯誤處理

預定義異常

PolarDB PostgreSQL版（相容Oracle）既支援原生PostgreSQL的所有預定義異常，如division_by_zero。同時也支援相容Oracle文法中的常見預定義異常，如zero_divide。在SQL中既可以拋出這些異常，也可以捕獲這些異常。

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
END;

-- PostgreSQL 風格
BEGIN
    RAISE division_by_zero;
END;

-- Oracle 風格
BEGIN
    RAISE zero_divide;
END;

-- PostgreSQL 風格
DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN division_by_zero THEN
        DBMS_OUTPUT.PUT_LINE('division by zero');
END;

-- Oracle 風格
DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN zero_divide THEN
        DBMS_OUTPUT.PUT_LINE('zero divide');
END;

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('division by zero');
END;

非預定義異常

在Oracle文法中，存在大量的錯誤碼，其中只有少數錯誤碼被定義為系統預定義異常。例如，錯誤碼100對應於no_data_found異常，可以通過顯式拋出RAISE no_data_found來引發該異常，並通過WHEN no_data_found進行異常捕獲。

對於大量的非預定義異常，它們僅具備錯誤碼而沒有名稱，如何拋出和捕獲這些異常呢？為瞭解決這一問題，Oracle引入了異常變數。PolarDB PostgreSQL版（相容Oracle）同樣支援該特性：

1. 首先在DECLARE中聲明異常變數，給定一個變數名，例如my_exception EXCEPTION;。

2. 通過PRAGMA EXCEPTION_INIT 語句為該變數綁定一個 SQLCODE，例如PRAGMA EXCEPTION_INIT(my_exception, -1476);。

   重要

   錯誤碼存在範圍限制，需為100（表示no_data_found異常）或在[-1000000, 0)範圍內，且只有[-65535, 0)這個範圍能夠綁定到Oracle的合法SQLCODE，其他範圍的錯誤碼沒有實際意義。

3. 在 EXCEPTION 段中可以用WHEN my_exception或WHEN OTHERS捕獲該異常。

樣本

DECLARE
    result INT;
    my_exception EXCEPTION;
    PRAGMA EXCEPTION_INIT(my_exception, -66666);
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN my_exception THEN
        DBMS_OUTPUT.PUT_LINE('zero divide');
END;

自訂異常（RAISE_APPLICATION_ERROR）

預定義異常和非預定義異常的錯誤碼都屬於Oracle預留的錯誤碼範圍，通常為[-65535, 0)範圍的負數。除此以外，Oracle還提供了一個自訂異常錯誤碼區間[-20000, -20999]，通過RAISE_APPLICATION_ERROR函數即可拋出自訂的錯誤碼和錯誤訊息。

樣本

DECLARE
    salary NUMBER := 4000;
BEGIN
    -- 校正商務規則，不符合條件時觸發錯誤
    IF salary < 5000 THEN
        RAISE_APPLICATION_ERROR(-20001, 'Salary is below the allowed minimum.');
    END IF;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('SQLCODE: ' || SQLCODE);
        DBMS_OUTPUT.PUT_LINE('Custom Error: ' || SQLERRM);
END;

錯誤碼與錯誤資訊

在EXCEPTION段中通過WHEN子句捕獲到異常以後，如果希望擷取異常的各項相關資訊，可以通過如下方法：

• SQLSTATE：原生PostgreSQL的錯誤碼，由五個字元的字串組成，前兩位表示類別（如語法錯誤、串連異常等），後三位表示具體錯誤子類。

• SQLCODE：相容Oracle文法中的錯誤碼，分為三類：

  • 100：表示no_data_found異常，查詢語句無返回結果。

  • [-65535, 0)範圍的負數：PolarDB PostgreSQL版（相容Oracle）叢集已相容Oracle文法中的各類錯誤情境。

  • -99999：表示非法值，PolarDB PostgreSQL版（相容Oracle）叢集暫不支援當前情境。

• SQLERRM：錯誤資訊，用於描述異常的詳細情況。

DECLARE
    result INT;
BEGIN
    result := 1 / 0;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('SQLCODE: ' || SQLCODE);
        DBMS_OUTPUT.PUT_LINE('SQLSTATE: ' || SQLSTATE);
        DBMS_OUTPUT.PUT_LINE('SQLERRM: ' || SQLERRM);
END;

SQLCODE: -1476
SQLSTATE: 22012
SQLERRM: division by zero