Edge Security Acceleration：使用Terraform配置等候室

安裝Terraform並配置許可權

涉及的資源

• 建立網站：alicloud_esa_site

• 建立等候室：alicloud_esa_waiting_room

• 查詢ESA執行個體：alicloud_esa_sites

配置等候室

1. 建立一個名為 main.tf 的設定檔，然後將以下代碼複製到設定檔中，用於配置等候室。

   # 1. 查詢企業版 ESA 執行個體
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # 篩選企業版執行個體
   }
   
   # 2. 建立網站
   resource "alicloud_esa_site" "resource_Site_example" {
     site_name   = "{{DOMAIN}}"  # 替換為實際網域名稱，如 example.com
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # 海外加速
     access_type = "NS"         # NS 接入方式
   }
   
   # 3. 建立等候室
   resource "alicloud_esa_waiting_room" "default" {
     site_id                        = alicloud_esa_site.resource_Site_example.id
     waiting_room_name              = "waitingroom_example"  # 等候室名稱
     description                    = "example"
     status                         = "off"  # 建立後預設關閉，需手動開啟
     waiting_room_type              = "default"
   
     # 排隊策略配置
     queuing_method                 = "fifo"  # 先進先出排隊演算法
     session_duration               = "5"    # 會話時間長度（分鐘）
     total_active_users             = "300"  # 最大並發使用者數
     new_users_per_minute           = "200"  # 每分鐘允許存取人數
   
     # 匹配規則：觸發排隊的條件
     host_name_and_path {
       domain    = "sub_domain.com"         # 主網域名稱
       path      = "/example"                # 路徑匹配
       subdomain = "example_sub_domain.com."  # 子網域名稱
     }
   
     # 頁面顯示配置
     language                       = "zhcn"  # 排隊頁面語言：簡體中文
     custom_page_html               = ""      # 空表示使用預設排隊頁面
     queuing_status_code            = "200"   # 排隊時返回的HTTP狀態代碼
     cookie_name                    = "__aliwaitingroom_example"  # Cookie名稱
   
     # 進階選項
     queue_all_enable               = "off"  # 是否全員排隊
     disable_session_renewal_enable = "off"  # 是否禁用會話續期
     json_response_enable           = "off"  # 是否返回JSON響應
   }

   說明

   請根據實際情況修改代碼中的預留位置：將 DOMAIN 替換為您的實際網域名稱，將 host_name_and_path 中的網域名稱和路徑替換為實際觸發排隊的條件。關鍵參數說明請參見本文末尾的相關參考章節。

2. 進入設定檔所在目錄，執行如下命令，初始化Terraform環境。

   terraform init

3. 執行如下命令，驗證Terraform文法與配置。

   terraform validate

4. 執行如下命令，預覽執行結果。

   terraform plan

5. 執行如下命令，執行Terraform指令碼。

   terraform apply

6. 依據提示輸入yes確認執行即可。

驗證結果

terraform show

相關參考

本文程式碼範例中關鍵參數的說明如下：

更多參數說明,請參見alicloud_esa_waiting_room。

不同套餐的支援情況