Edge Security Acceleration:Configure a waiting room with Terraform

Instalar o Terraform e configurar permissões

Recursos

• Criar um site: alicloud_esa_site

• Criar uma sala de espera: alicloud_esa_waiting_room

• Consultar instâncias do ESA: alicloud_esa_sites

Procedimento

1. Para configurar a sala de espera, crie um arquivo chamado main.tf e adicione o seguinte código:

   # 1. Query for Enterprise ESA instances
   data "alicloud_esa_sites" "default" {
     plan_subscribe_type = "enterpriseplan"  # Filter for Enterprise instances
   }
   
   # 2. Create a site
   resource "alicloud_esa_site" "resource_Site_example" {
     site_name   = "{{DOMAIN}}"  # Replace with your domain name, such as example.com
     instance_id = data.alicloud_esa_sites.default.sites.0.instance_id
     coverage    = "overseas"  # Overseas acceleration
     access_type = "NS"         # NS access mode
   }
   
   # 3. Create a waiting room
   resource "alicloud_esa_waiting_room" "default" {
     site_id                        = alicloud_esa_site.resource_Site_example.id
     waiting_room_name              = "waitingroom_example"  # Waiting room name
     description                    = "example"
     status                         = "off"  # Disabled by default. Must be enabled manually.
     waiting_room_type              = "default"
   
     # Queuing policy configuration
     queuing_method                 = "fifo"  # FIFO queuing method
     session_duration               = "5"    # Session duration (minutes)
     total_active_users             = "300"  # Maximum concurrent users
     new_users_per_minute           = "200"  # Number of new users admitted per minute
   
     # Matching rule: Conditions that trigger queuing
     host_name_and_path {
       domain    = "sub_domain.com"         # Hostname to match
       path      = "/example"                # Path to match
       subdomain = "example_sub_domain.com."  # Subdomain to match
     }
   
     # Page display configuration
     language                       = "zhcn"  # Queuing page language: Simplified Chinese
     custom_page_html               = ""      # An empty value uses the default queuing page
     queuing_status_code            = "200"   # HTTP status code returned during queuing
     cookie_name                    = "__aliwaitingroom_example"  # Cookie name
   
     # Advanced options
     queue_all_enable               = "off"  # Specifies whether to queue all users
     disable_session_renewal_enable = "off"  # Specifies whether to disable session renewal
     json_response_enable           = "off"  # Specifies whether to return a JSON response
   }

   Nota

   Substitua os espaços reservados no código pelos seus valores reais. Troque DOMAIN pelo seu nome de domínio e atualize o domínio e o caminho no bloco host_name_and_path para corresponder às suas condições de fila. Consulte a seção Referências para ver a descrição dos parâmetros.

2. Acesse o diretório que contém seus arquivos de configuração e execute o comando a seguir para inicializar o ambiente do Terraform.

   terraform init

3. Execute o comando abaixo para validar a sintaxe e a configuração do Terraform.

   terraform validate

4. Execute o seguinte comando para visualizar o plano de execução.

   terraform plan

5. Aplique a configuração executando este comando:

   terraform apply

6. Quando solicitado, insira yes para confirmar e aplicar as alterações.

Verifique os resultados

terraform show

Referências

A tabela a seguir descreve os principais parâmetros usados no exemplo de código.

Para mais detalhes sobre os parâmetros, consulte alicloud_esa_waiting_room.