Virtual Private Cloud:DHCP オプションセットと DNS ホスト名

コンソール

VPC コンソール - DHCP オプションセット ページに移動し、[DHCP オプションセットの作成] をクリックします。[ドメイン名] および [DNS サーバーの IP アドレス] のパラメーターを設定します。

リージョン内の VPC で初めて DNS ホスト名を有効化すると、デフォルト DHCP オプションセットが自動的に作成され、その VPC に関連付けられます。デフォルト DHCP オプションセットは変更できません。

API

CreateDhcpOptionsSet を呼び出して DHCP オプションセットを作成します。

Terraform

# VPC のリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# DHCP オプションセットを作成します。
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                 # ドメイン名を指定します。
  domain_name_servers   = "100.100.2.136,100.100.2.138" # DNS サーバーの IP アドレスを指定します。
}

リソース： alicloud_vpc_dhcp_options_set

コンソール

VPC と DHCP オプションセットの関連付けは、以下の 2 か所から管理できます：

• VPC の詳細ページの [DHCP オプションセット] セクションで、関連付けの作成、変更、または削除を行います。

• DHCP オプションセットの詳細ページ、または [操作] 列で、[VPC の関連付け] を選択します。

関連付けが変更されると、新しい ECS インスタンスは自動的に更新された構成を使用します。既存の ECS インスタンスについては、DHCP プロセスを再起動して変更を適用します：

sudo dhclient -r eth0 && sudo dhclient eth0

関連付けが解除された場合、Alibaba Cloud は DHCP 経由で ECS インスタンスにデフォルト DNS サーバーを構成します。既存のインスタンスで新しい構成を確実に適用し、サービスへの影響を最小限に抑えるためには、インスタンスまたはそのネットワークサービスを再起動します。

VPC で 共有 VPC 機能が有効になっている場合、DHCP オプションセットは共有 VPC 内の ECS インスタンスにも適用されます。

API

• AttachDhcpOptionsSetToVpc — DHCP オプションセットを VPC にアタッチします

• DetachDhcpOptionsSetFromVpc — DHCP オプションセットを VPC からデタッチします

• ReplaceVpcDhcpOptionsSet — VPC に関連付けられた DHCP オプションセットを変更します

Terraform

# DHCP オプションセットを VPC に関連付けます。
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vbg******"                                       # 関連付ける VPC の ID を指定します。
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # 関連付ける DHCP オプションセットの ID を指定します。
}

リソース：alicloud_vpc_dhcp_options_set_attachment

コンソール

DHCP オプションセットの詳細ページ、または [操作] 列で、[編集] をクリックします。

API

UpdateDhcpOptionsSetAttribute を呼び出して構成を変更します。

コンソール

1. プライベートゾーン に移動し、[ゾーンの追加] をクリックします。カスタムドメイン名を構成し、[有効範囲] を対象 VPC に設定します。ゾーンの詳細ページで、[ECS ホスト名] タブに移動し、[ECS ホスト名の追加] をクリックします。システムは、選択されたリージョン内の ECS インスタンスのホスト名および IP アドレスに対応する DNS レコードを自動的に追加します。

   ホスト名が変更された場合、DNS レコードは自動的に更新されません。[自動同期] を有効化すると、システムが毎分 DNS レコードを追加および同期します。カスタムドメインプレフィックスを追加するには、[DNS レコード] タブに移動し、[ホストレコード] を追加します。

2. VPC コンソール - DHCP オプションセット ページに移動し、[DHCP オプションセットの作成] をクリックします。[ドメイン名] をプライベートゾーンのドメイン名に設定します。

3. 新しい DHCP オプションセットの [操作] 列で、[VPC の関連付け] を選択します。DNS レコードが設定された ECS インスタンスは、関連付けられた VPC 内の他のインスタンスからホスト名またはホストレコードでアクセス可能になります。

API

1. AddZone を呼び出してプライベートゾーンを追加します。

2. DNS レコードの追加 API を呼び出すか、UpdateSyncEcsHostTask を呼び出してホスト名の同期を構成します。

3. CreateDhcpOptionsSet を呼び出して DHCP オプションセットを作成します。

4. AttachDhcpOptionsSetToVpc を呼び出して DHCP オプションセットを VPC に関連付けます。

Terraform

ECS ホスト名レコードの自動追加はサポートされていません。カスタム DNS レコードを 1 つずつ追加してください。

# 対象 VPC のリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# プライベートゾーンを構成します。
resource "alicloud_pvtz_zone" "test_pvtz_zone" {
  zone_name = "example.com"
}

# ドメイン名の有効範囲を設定します。
resource "alicloud_pvtz_zone_attachment" "test_pvtz_zone_attachment" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  vpc_ids = ["vpc-8vba******"] # ドメイン名が有効になる VPC の ID を指定します。
}

# DNS レコードを追加します。
resource "alicloud_pvtz_zone_record" "test_pvtz_zone_record" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  rr      = "abc"         # ホストレコードを指定します。
  type    = "A"           # DNS レコードのタイプを指定します。
  value   = "192.168.0.4" # DNS レコードの値を指定します。
}

# DHCP オプションセットを作成します。
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                 # ドメイン名を指定します。
  domain_name_servers   = "100.100.2.136,100.100.2.138" # Alibaba Cloud のデフォルト DNS サーバーの IP アドレスを指定します。
}

# DHCP オプションセットを VPC に関連付けます。
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vba******"                                       # 関連付ける VPC の ID を指定します。
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # 関連付ける DHCP オプションセットの ID を指定します。
}

リソース：alicloud_pvtz_zone、alicloud_pvtz_zone_attachment、alicloud_pvtz_zone_record、alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment

コンソール

1. VPC コンソール - DHCP オプションセット ページに移動し、[DHCP オプションセットの作成] をクリックします。[ドメイン名] をカスタムドメイン名に設定し、[カスタムサーバーの IP] をクリックして、セルフマネージド DNS サーバーの IP アドレスをリストの先頭に配置します。

2. [操作] 列で、[VPC の関連付け] を選択します。DNS レコードが構成された ECS インスタンスは、関連付けられた VPC 内の他のインスタンスからホスト名でアクセス可能になります。

API

1. CreateDhcpOptionsSet を呼び出して、ドメイン名およびセルフマネージド DNS サーバーの IP アドレスを含むカスタム DHCP オプションセットを作成します。

2. AttachDhcpOptionsSetToVpc を呼び出して、DHCP オプションセットを VPC に関連付けます。

Terraform

# VPC のリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# セルフマネージド DNS サーバーを含む DHCP オプションセットを作成します。
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                              # ドメイン名を指定します。
  domain_name_servers   = "192.168.0.10,100.100.2.136,100.100.2.138" # セルフマネージド DNS サーバーの IP を先頭に配置します。
}

# DHCP オプションセットを VPC に関連付けます。
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vbg******"                                       # 関連付ける VPC の ID を指定します。
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # 関連付ける DHCP オプションセットの ID を指定します。
}

リソース：alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment