Virtual Private Cloud:DHCP オプションセットと DNS ホスト名

コンソール

1. Private DNS コンソールに移動し、Add Zone をクリックして、カスタムの[イントラネット権威ドメイン名 (Zone)]を設定し、[Effective Scope]を対象の VPC に設定します。

   対象のゾーン ID をクリックします。ECS Hostname タブで、Add ECS Hostname をクリックします。システムは、選択されたリージョン内の ECS ホスト名を IP にマッピングする DNS レコードを自動的に追加しますが、ホスト名の変更は自動的に同期されません。Automatic Synchronization Settings を有効にすると、システムが 1 分ごとに DNS レコードを自動的に追加および同期するようになります。カスタムドメインプレフィックスを使用するには、Settings タブに移動し、カスタムの[Hostname]を追加します。

2. VPC コンソール - DHCP オプションセットに移動し、创建DHCP选项集 をクリックして、[域名]を対応する組み込みの権威ドメイン名に設定します。

3. 対象の DHCP オプションセットの操作 列で、关联专有网络 を選択します。DNS レコードが設定された ECS インスタンスは、関連付けられた VPC 内の他のインスタンスからホスト名またはホストレコードでアクセスできるようになります。

API

Alibaba Cloud Private DNS を使用するには、次の API を順番に呼び出します。

Terraform

ECS ホスト名の DNS レコードの自動追加はサポートされていません。カスタム DNS レコードを個別に追加する必要があります。

リソース： alicloud_pvtz_zone、alicloud_pvtz_zone_attachment、alicloud_pvtz_zone_record、alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment

# 対象の VPC のリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou"
}

# 組み込みの権威ドメインを設定します
resource "alicloud_pvtz_zone" "test_pvtz_zone" {
  zone_name = "example.com"
}

# ドメイン名の範囲を設定します
resource "alicloud_pvtz_zone_attachment" "test_pvtz_zone_attachment" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  vpc_ids = ["vpc-8vba******"] # ドメインが有効になる VPC インスタンス ID を指定します
}

# DNS レコードを追加します
resource "alicloud_pvtz_zone_record" "test_pvtz_zone_record" {
  zone_id = alicloud_pvtz_zone.test_pvtz_zone.id
  rr      = "abc"         # ホストレコードを指定します
  type    = "A"           # DNS レコードタイプを指定します
  value   = "192.168.0.4" # DNS レコード値を指定します
}

# DHCP オプションセットを作成します
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                 # ドメイン名を指定します
  domain_name_servers   = "100.100.2.136,100.100.2.138" # Alibaba Cloud のデフォルト DNS サーバー IP を指定します
}

# DHCP オプションセットを VPC に関連付けます
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vba******"                                       # VPC インスタンス ID を指定します
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # DHCP オプションセットインスタンス ID を指定します
}

コンソール

1. VPC コンソール - DHCP オプションセットに移動し、创建DHCP选项集 をクリックして、[域名]をセルフマネージド DNS サービスで使用されるドメイン名に設定し、サーバ IP をカスタマイズ をクリックして、セルフマネージド DNS サーバー IP をリストの最初に配置します。

2. 対象の DHCP オプションセットの操作 列で、关联专有网络 を選択します。DNS レコードが設定された ECS インスタンスは、関連付けられた VPC 内の他のインスタンスからホスト名でアクセスできるようになります。

API

ドメイン名とセルフマネージド DNS サーバー IP を使用してカスタム DHCP オプションセットを作成し、それを VPC に関連付けるには、次の API を順番に呼び出します。

Terraform

リソース： alicloud_vpc_dhcp_options_set、alicloud_vpc_dhcp_options_set_attachment

# VPC のリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou"
}

# DHCP オプションセットを作成します
resource "alicloud_vpc_dhcp_options_set" "test_dhcp_options_set" {
  dhcp_options_set_name = "test_dhcp_options_set_name"
  domain_name           = "example.com"                              # ドメイン名を指定します
  domain_name_servers   = "192.168.0.10,192.168.0.11" # セルフマネージド DNS サーバー IP のみを指定します。単一障害点を回避するために、2 台のサーバーを推奨します
}

# DHCP オプションセットを VPC に関連付けます
resource "alicloud_vpc_dhcp_options_set_attachment" "test_attachment_vpc" {
  vpc_id              = "vpc-8vbg******"                                       # VPC インスタンス ID を指定します
  dhcp_options_set_id = alicloud_vpc_dhcp_options_set.test_dhcp_options_set.id # DHCP オプションセットインスタンス ID を指定します
}