Elastic Compute Service:Terraform リファレンス

Terraform の基本機能

Terraform は、IT インフラストラクチャの自動化とオーケストレーションを実現するツールです。コードを使用して IT リソースを管理および保守できます。詳細については、「Terraformとは」 をご参照ください。

• Terraform のコマンドラインインターフェイス (CLI) を使用すると、設定ファイルを Alibaba Cloud またはその他のサポートされているクラウドに簡単にデプロイし、そのバージョンを管理できます。仮想マシン、ストレージアカウント、ネットワークインターフェイスなどのインフラストラクチャを、クラウド リソース トポロジを記述する設定ファイルで定義できます。

• Terraform はプロバイダーを通じて新しいインフラストラクチャをサポートしており、シンプルなテンプレート言語を使用して、Alibaba Cloud 上のクラウドインフラストラクチャを簡単に定義、プレビュー、デプロイできます。

• Terraform を使用して、複数の Alibaba Cloud サービスのリソースを作成、変更、削除できます。

Alibaba Cloud と Terraform の統合に関する詳細については、「Alibaba Cloud Provider」 をご参照ください。

Terraform のインストール

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

export PATH=$PATH:$(go env GOPATH)/bin

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Terraform の認証

アクセス認証情報を環境変数に保存することで、Terraform を認証できます。 Terraform コマンドを実行すると、設定テンプレートで認証情報が明示的に宣言されていない場合、Terraform はこれらの変数から認証情報を取得しようとします。以下のセクションでは、環境変数を設定する方法について説明します。

# AccessKey ID
$ export ALICLOUD_ACCESS_KEY="<yourAccessKeyID>"
# AccessKey シークレット
$ export ALICLOUD_SECRET_KEY="<yourAccessKeySecret>"
# STS 認証情報を使用する場合は、ALICLOUD_SECURITY_TOKEN を設定する必要があります。
$ export ALICLOUD_SECURITY_TOKEN="<yourSTSToken>"

環境変数を設定した後は、プロバイダーブロックで認証情報を宣言する必要はありません。リージョンのみを宣言できます。

provider "alicloud" {
  region = "cn-hangzhou"
}

リージョンは、ALICLOUD_REGION 環境変数を使用して設定することもできます。リージョンが明示的に宣言されておらず、この環境変数も設定されていない場合、デフォルト値は cn-beijing です。

サポートされるリソース

Terraform による ECS リソースの作成と管理

このセクションでは、Terraform を使用して Elastic Compute Service (ECS) リソースを作成および管理する例を紹介します。

1. 作業ディレクトリを作成します。このディレクトリに、main.tf という名前の設定ファイルを作成します。次のコードで、ECS インスタンスと、必要な VPC、セキュリティグループ、vSwitch リソースを作成します。コードを main.tf ファイルにコピーします。

   # Alibaba Cloud リージョンを指定するため、変数 "region" を定義します。デフォルト値は "cn-beijing" です。
   variable "region"{
     default = "cn-beijing"
   }
   
   # "region" 変数で定義されたリージョンを使用するよう、Alibaba Cloud プロバイダーを設定します。
   provider "alicloud"{
     region = var.region
   }
   
   # ECS インスタンスタイプを指定するため、文字列変数 "instance_type" を定義します。デフォルト値は "ecs.e-c1m1.large" です。
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # データソースを使用してアベイラビリティーゾーン情報をクエリします。指定されたインスタンスタイプ、リソース作成タイプ (vSwitch など)、ディスクカテゴリで結果をフィルタリングします。
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # VPC の CIDR ブロックを指定するため、変数 "vpc_cidr_block" を定義します。デフォルト値は "172.16.0.0/16" です。
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # vSwitch の CIDR ブロックを指定するため、変数 "vsw_cidr_block" を定義します。デフォルト値は "172.16.0.0/24" です。
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # 一部のリソース名の一意性を確保するため、10000 から 99999 までのランダムな整数を生成します。
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # "vpc-test" という名前の VPC を作成し、ランダムな整数を使用して名前が一意になるようにします。
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # セキュリティグループを作成し、一意性を確保するために名前にランダムな整数を含め、上記で作成した VPC に関連付けます。
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # すべてのインバウンド TCP トラフィックを許可するセキュリティグループルールを作成し、以前に作成したセキュリティグループに関連付けます。
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # vSwitch を作成し、一意性を確保するために名前にランダムな整数を含め、VPC とアベイラビリティーゾーンに関連付けます。
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # ECS インスタンスを作成します。アベイラビリティーゾーン、セキュリティグループ、インスタンスタイプなどの複数のパラメータを設定します。ランダムな整数を使用してインスタンス名が一意になるようにします。
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # 要件に合わせてパスワードを変更してください。
   }

2. 次のコマンドを実行して、Terraform ランタイム環境を初期化します。

   terraform init

   Terraform が正常に初期化されると、次の出力が表示されます。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 次のコマンドを実行して、設定を適用します。

   terraform apply

   実行中に、プロンプトが表示されたら yes を入力し、[Enter] キーを押します。コマンドが完了するまで待ちます。次の出力が表示された場合、コードは正常に実行されています。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. 結果の確認

terraform show

リファレンス

• その他のチュートリアルについては、「Terraform チュートリアル」をご参照ください。

• 一般的な Terraform コマンドの詳細については、「一般的なコマンド」をご参照ください。

• Terraform は ROS でマネージドサービスとして利用できます。 ROS コンソール で Terraform テンプレートをデプロイできます。詳細については、「Terraform スタックを作成する」をご参照ください。