Container Service for Kubernetes:Terraform を使用したアプリケーションのバックアップと復元

即時バックアップタスクの作成

1. csdr.tf に次の内容を追加し、プレースホルダーを置き換えます。

   ACK クラスターで Velero をご利用の場合、技術サポートについては DingTalk グループ 35532895 にご参加ください。

   パラメータ	必須	説明
   csdr.alibabacloud.com/backuplocations	はい	バックアップボールトのアノテーション。BackupLocation の設定と完全に一致する必要があります。
   name	はい	即時バックアップタスクの名前。
   includedNamespaces	はい	バックアップする名前空間。
   includedResources	いいえ	含めるリソースタイプ。includedResources または excludedResources のいずれか 1 つのみを指定します。両方が空の場合、すべてのリソースタイプがバックアップされます。
   excludedResources	いいえ	除外するリソースタイプ。includedResources を参照してください。
   matchLabels	いいえ	バックアップするリソースのラベル。
   includeClusterResources	いいえ	クラスター スコープのリソースを制御します。true：すべてのクラスター スコープのリソース。false または未設定：指定された名前空間によって参照されるリソースのみ。ACK コンソールでのデフォルト：false。
   defaultPvBackup	いいえ	true：アプリケーションとボリュームをバックアップします。false：アプリケーションのみをバックアップします。
   storageLocation	はい	バックアップボールト (BackupLocation) の名前。
   ttl	はい	バックアップの有効期間。形式：720h0m0s。有効範囲：24h0m0s～1572864h0m0s。有効期限が切れたバックアップは復元できません。

   resource "kubernetes_manifest" "applicationbackup-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "ApplicationBackup"
       metadata = {
         name      = "<your-backup-task-name>"
         namespace = "csdr"
         annotations = {
           # バックアップボールトの設定と完全に一致する必要があります
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         includedNamespaces = ["default", "default1"]  # バックアップする名前空間
   
         # includedResources または excludedResources のいずれか 1 つのみを指定します。
         # 両方が空の場合、すべてのリソースタイプがバックアップされます。
         includedResources = ["statefulset"]
         excludedResources = ["excludedResources"]
   
         labelSelector = {
           matchLabels = {
             "app" = "mysql-sts"  # オプション: これらのラベルを持つリソースのみをバックアップします
           }
         }
   
         pvBackup = {
           defaultPvBackup = "false"  # "true": アプリケーションとボリュームをバックアップ、"false": アプリケーションのみ
         }
   
         storageLocation = "<your-backup-vault-name>"  # BackupLocation 名と一致する必要があります
   
         ttl = "720h0m0s"  # バックアップの有効期間。形式：720h0m0s
                           # 有効範囲：24h0m0s ～ 1572864h0m0s
                           # 有効期限が切れたバックアップは復元できません
   
         # includeClusterResources は、クラスター スコープのリソースを含めるかどうかを制御します：
         # "true"  — すべてのクラスター スコープのリソース (StorageClass、CRD、webhook など) を含めます
         # "false" — 指定された名前空間によって参照されるクラスター スコープのリソースのみを含めます
         #           (たとえば、Pod がクラスターロールを持つサービスアカウントを使用している場合、
         #            そのクラスターロールは自動的に含まれます)
         # 未設定  — 名前空間フィルタリングが使用される場合、"false" と同じ動作
         includeClusterResources = "false"
       }
     }
   
     # バックアップの完了を待機するには、コメントを解除します (スクリプト化されたワークフローに推奨)。
     # バックアップ時間は、アプリケーション数とボリュームデータサイズによって異なります。
     #wait {
     #  fields = {
     #    "status.phase" = "Completed"
     #  }
     #}
     #timeouts {
     #  create = "60m"
     #}
   }

2. 変更内容をプレビューします。

   terraform plan

3. 即時バックアップタスクを作成します。

   terraform apply

   出力を展開して表示

   kubernetes_manifest.applicationbackup-demo: Creating...
   kubernetes_manifest.applicationbackup-demo: Creation complete after 1s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

スケジュールバックアップタスクの作成

1. csdr.tf に次の内容を追加し、プレースホルダーを置き換えます。

   設定ファイルを展開して表示

   resource "kubernetes_manifest" "backupschedule-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "BackupSchedule"
       metadata = {
         name      = "<your-schedule-name>"
         namespace = "csdr"
         annotations = {
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         # バックアップスケジュールの cron 式 (サーバーのタイムゾーン)。
         # 形式：分 時 日 月 曜日
         # 例："1 4 * * *" は毎日 04:01 に実行されます。
         schedule = "1 4 * * *"
   
         template = {
           includedNamespaces = ["default", "default1"]
           includedResources  = ["statefulset"]
           excludedResources  = ["excludedResources"]
           labelSelector = {
             matchLabels = {
               "app" = "mysql-sts"
             }
           }
           pvBackup = {
             defaultPvBackup = "false"  # BackupSchedule では必須
           }
           storageLocation         = "<your-backup-vault-name>"
           ttl                     = "720h0m0s"
           includeClusterResources = "false"
         }
       }
     }
   
     wait {
       fields = {
         "status.phase" = "Enabled"
       }
     }
   
     timeouts {
       create = "10m"
     }
   }

   パラメータ	必須	説明
   csdr.alibabacloud.com/backuplocations	はい	バックアップボールトのアノテーション。BackupLocation の設定と完全に一致する必要があります。
   name	はい	スケジュールバックアップタスクの名前。
   schedule	はい	cron 式としてのバックアップ頻度。形式：分 時 日 月 曜日。例："1 4 * * *" は毎日 04:01 に実行されます。
   includedNamespaces	はい	バックアップする名前空間。
   includedResources	いいえ	含めるリソースタイプ。includedResources または excludedResources のいずれか 1 つのみを指定します。両方が空の場合、すべてのリソースタイプがバックアップされます。
   excludedResources	いいえ	除外するリソースタイプ。includedResources の注記を参照してください。
   matchLabels	いいえ	バックアップするリソースのラベル。
   includeClusterResources	いいえ	クラスター スコープのリソースを制御します。true：すべてのクラスター スコープのリソース。false または未設定：指定された名前空間によって参照されるリソースのみ。
   defaultPvBackup	はい	true：アプリケーションとボリュームをバックアップします。false：アプリケーションのみをバックアップします。
   storageLocation	はい	バックアップボールト (BackupLocation) の名前。
   ttl	はい	バックアップの有効期間。形式：720h0m0s。有効範囲：24h0m0s～1572864h0m0s。

2. 変更内容をプレビューします。

   terraform plan

3. スケジュールバックアップタスクを作成します。

   terraform apply

   出力を展開して表示

   kubernetes_manifest.backupschedule-demo: Creating...
   kubernetes_manifest.backupschedule-demo: Creation complete after 1s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

スケジュールバックアップタスクの管理

スケジュールによって作成されたバックアップの検索

特定のスケジュールから作成されたバックアップを一覧表示します。

data "kubernetes_resources" "list-applicationbackup" {
  api_version    = "csdr.alibabacloud.com/v1beta1"
  kind           = "ApplicationBackup"
  namespace      = "csdr"
  label_selector = "csdr/schedule-name=<your-schedule-name>"
}

output "applicationbackup-name" {
  value = data.kubernetes_resources.list-applicationbackup.objects
}

スケジュールバックアップタスクの変更

スケジュール頻度などのパラメータを変更するには、次の手順を実行します。

1. spec.paused を "true" に設定してスケジュールを一時停止し、その後パラメータを更新します。例：

   設定ファイルを展開して表示

   resource "kubernetes_manifest" "backupschedule-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "BackupSchedule"
       metadata = {
         name      = "<your-schedule-name>"
         namespace = "csdr"
         annotations = {
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         paused   = "true"        # 変更する前にスケジュールを一時停止します
         schedule = "0 5 * * *"   # 更新されたバックアップ頻度
         template = {
           includedNamespaces      = ["default", "default1"]
           includedResources       = ["statefulset"]
           excludedResources       = ["excludedResources"]
           labelSelector = {
             matchLabels = {
               "app" = "mysql-sts"
             }
           }
           pvBackup = {
             defaultPvBackup = "false"
           }
           storageLocation         = "<your-backup-vault-name>"
           ttl                     = "720h0m0s"
           includeClusterResources = "false"
         }
       }
     }
     wait {
       fields = {
         "status.phase" = "Paused"  # さらに変更を適用する前に、スケジュールが一時停止されていることを確認します
       }
     }
     timeouts {
       create = "10m"
     }
   }

2. 変更内容をプレビューします。

   terraform plan

3. 更新された設定を適用します。

   terraform apply

   出力例：

   kubernetes_manifest.backupschedule-demo: Modifying...
   kubernetes_manifest.backupschedule-demo: Modifications complete after 1s
   
   Apply complete! Resources: 0 added, 1 changed, 0 destroyed.

データ保護 (PvBackup)

backupType を PvBackup に設定すると、ボリュームデータのみをバックアップします。pvcList を指定して特定の PVC をバックアップするか、storageClassList を指定して特定のストレージクラスのボリュームをバックアップします。両方を設定した場合、storageClassList は無視されます。どちらも設定しない場合、含まれる名前空間内のすべてのボリュームがバックアップされます。

スケジュールバックアップタスクの削除

terraform destroy を実行して、BackupSchedule を削除し、スケジュールを停止します。

バックアップタスクまたは復元タスクの削除

DeleteRequest CR を使用して、バックアップタスクまたは復元タスクと関連するクラウドリソースを安全に削除します。

バックアップタスクを削除しても、既存のバックアップには影響しません。復元タスクを削除しても、復元されたデータには影響しません。

1. csdr.tf に次の内容を追加します。

   パラメータ	必須	説明
   name	はい	削除リクエストの名前。形式：バックアップタスクを削除する場合は <ApplicationBackup-name>-dbr、復元タスクを削除する場合は <ApplicationRestore-name>-dbr。
   deleteObjectName	はい	削除するリソースの名前。
   deleteObjectType	はい	"Backup"：ApplicationBackup CR と関連リソースを削除します。"Restore"：ApplicationRestore CR と関連リソースを削除します。

   resource "kubernetes_manifest" "deleterequest-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "DeleteRequest"
       metadata = {
         name      = "<object-name>-dbr"  # 形式：<ApplicationBackup-or-ApplicationRestore-name>-dbr
         namespace = "csdr"
       }
       spec = {
         deleteObjectName = "<object-name>"   # 削除するバックアップタスクまたは復元タスクの名前
         deleteObjectType = "Backup"          # "Backup": ApplicationBackup と関連リソースを削除します
                                              # "Restore": ApplicationRestore と関連リソースを削除します
       }
     }
   }

2. 変更内容をプレビューします。

   terraform plan

3. 削除を適用します。

   terraform apply

   出力を展開して表示

   kubernetes_manifest.deleterequest-demo: Creating...
   kubernetes_manifest.deleterequest-demo: Creation complete after 0s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

   ターゲットリソースを削除した後、システムは DeleteRequest CR も削除します。