Koneksi jaringan private antara VPC di akun dan wilayah berbeda - Koneksi peering VPC - Virtual private cloud

Secara default, virtual private clouds (VPC) terisolasi satu sama lain. Koneksi peering VPC menghubungkan dua VPC yang Blok CIDR-nya tidak tumpang tindih, memungkinkan resource di kedua VPC berkomunikasi menggunakan alamat IP pribadi. Koneksi peering VPC dapat dibuat antara VPC dalam akun yang sama maupun berbeda, baik dalam wilayah yang sama maupun berbeda.

Untuk menghubungkan beberapa VPC, gunakan peering VPC atau Cloud Enterprise Network (CEN). Untuk kasus penggunaan dan pertimbangan trade-off-nya, lihat Hubungkan VPC.

Cara kerja

Koneksi peering VPC melibatkan peminta dan penerima. Ikuti proses berikut untuk membuat koneksi peering:

VPC peminta menginisiasi permintaan koneksi.
- Akun yang sama: Jika VPC penerima berada dalam akun yang sama, sistem akan secara otomatis menerima dan mengaktifkan koneksi tersebut.
- Cross-account: Jika VPC penerima berada dalam akun lain, pemiliknya harus secara manual menerima permintaan tersebut.
Kedua VPC mengonfigurasi rute
Pemilik setiap VPC secara manual menambahkan entri rute yang mengarah ke Blok CIDR VPC pasangannya (peer VPC).

Pertimbangan

Tidak ada routing transitif
Peering VPC bersifat non-transitif. Jika VPC A di-peer dengan VPC B dan VPC C, maka VPC B dan VPC C tidak dapat berkomunikasi melalui VPC A. Untuk mengizinkan lalu lintas antara VPC B dan VPC C, Anda harus membuat koneksi peering VPC secara langsung di antara keduanya.
Konfigurasikan rute di kedua VPC
Rute tidak dikonfigurasi secara otomatis. Untuk mengaktifkan konektivitas, Anda harus secara manual menambahkan entri rute yang mengarah ke Blok CIDR peer VPC di kedua VPC, baik peminta maupun penerima.
Perbarui kontrol keamanan
Membuat koneksi tidak secara otomatis mengganti kontrol keamanan. Anda harus memperbarui grup keamanan, ACL jaringan, dan daftar izin tingkat layanan—misalnya untuk ApsaraDB RDS—untuk mengizinkan lalu lintas masuk dari VPC pasangan.
Aktifkan CDT untuk koneksi cross-region
Untuk koneksi cross-region, pengguna baru harus mengaktifkan Cloud Data Transfer (CDT) di kedua akun, baik peminta maupun penerima.
Batasi peering pada website yang sama
Peering VPC hanya berlaku untuk akun-akun di website Alibaba Cloud yang sama. Anda tidak dapat membuat koneksi peering antara akun di website Tiongkok (aliyun.com) dan akun di website Internasional (alibabacloud.com).
Izin VPC bersama
Dalam VPC bersama, izin (buat, ubah, hapus) dicadangkan untuk pemilik resource. Pengguna resource (principal) tidak dapat melakukan operasi tersebut.

Buat koneksi peering VPC

Konsol

Buat koneksi peering VPC:
1. Buka halaman VPC - VPC Peering Connection. Di bilah navigasi atas, pilih wilayah tempat VPC berada, lalu klik Create VPC Peering Connection.
2. Pilih tipe akun penerima.
  - Same-Account: Koneksi diterima dan diaktifkan secara otomatis. Klik Add route to peer VPC CIDR untuk secara otomatis mengonfigurasi rute yang mengarah ke peer VPC.
  - Cross-Account: Pemilik akun penerima harus login, temukan permintaan di wilayah yang sama, lalu klik Allow di kolom Actions.
    Penerima dapat Deny atau Delete permintaan tersebut. Untuk informasi lebih lanjut, lihat Lifecycle.
3. Untuk koneksi Inter-Region, Anda harus mengonfigurasi Link Type dan Accepter Region.
  Platinum dan Gold menyediakan tingkat kualitas transfer data yang berbeda dan harga penagihan-nya bervariasi.
  - Platinum (ketersediaan 99,995%): Terbaik untuk aplikasi yang sensitif terhadap jitter seperti panggilan suara, konferensi video, dan gaming real-time.
  - Gold (ketersediaan 99,95%): Cocok untuk tugas yang toleran terhadap latensi seperti transfer file dan sinkronisasi data.
  Bandwidth dan tipe tautan dapat diubah nanti dengan mengklik Edit di halaman detail instans.
Konfigurasikan rute: Komunikasi memerlukan rute eksplisit di kedua VPC.
- VPC peminta: Klik Configure route di kolom Requester VPC. Pilih tabel rute peminta yang terkait dengan vSwitch, lalu atur Destination CIDR Block ke Blok CIDR VPC penerima.
- VPC penerima: Klik Configure route di kolom Accepter. Pilih tabel rute peminta yang terkait dengan vSwitch, lalu atur Destination CIDR Block ke CIDR VPC penerima.
Untuk IPv6, pastikan Anda juga menambahkan rute untuk Blok CIDR IPv6 peer.
Verifikasi konektivitas:
Metode A: Reachability analyzer (Direkomendasikan). Tidak ada paket data nyata yang dikirim dan layanan Anda tidak terpengaruh.
1. Di kolom Diagnose koneksi peering, pilih Diagnose > Reachability Analyzer.
2. Konfigurasikan sumber dan tujuan, lalu tentukan protokol dan port untuk mensimulasikan lalu lintas bisnis Anda dan memverifikasi konektivitas.
3. Sistem memeriksa rute, grup keamanan, dan ACL jaringan tanpa memengaruhi lalu lintas langsung.
4. Jika berhasil, klik reverse path analytics untuk memverifikasi lalu lintas dua arah.
Metode B: Uji ping
Login ke instans ECS di VPC peminta dan jalankan ping <Private IP of Peer ECS>.

Penghapusan: Salah satu VPC dapat menghapus koneksi tersebut.

Peringatan: Tindakan ini tidak dapat dikembalikan dan segera menghentikan akses jaringan pribadi.

API

Buat koneksi peering

Panggil CreateVpcPeerConnection untuk membuat koneksi peering VPC.
Jika kedua VPC berada di akun berbeda, pemilik akun penerima harus memanggil AcceptVpcPeerConnection untuk menerima koneksi peering VPC tersebut.
Penerima dapat memanggil RejectVpcPeerConnection untuk menolak koneksi peering VPC tersebut.
Pemilik kedua VPC harus memanggil GetVpcPeerConnectionAttribute untuk menanyakan Blok CIDR kedua VPC.
Pemilik kedua VPC harus memanggil CreateRouteEntry untuk membuat rute yang mengarah ke koneksi peering.

Ubah koneksi peering cross-region

Panggil ModifyVpcPeerConnection untuk mengubah bandwidth atau tipe tautan koneksi peering VPC cross-region.

Hapus koneksi peering

Panggil DeleteRouteEntry untuk menghapus rute yang mengarah ke koneksi peering.
Panggil DeleteVpcPeerConnection untuk menghapus koneksi peering VPC.

Reachability Analyzer

Panggil operasi API berikut secara berurutan untuk menggunakan Reachability Analyzer guna memeriksa konektivitas.

Terraform

Koneksi peering akun yang sama

Resource: alicloud_vpc_peer_connection, alicloud_route_entry

Data Sources: alicloud_account

# Akun tempat VPC berada
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "ap-southeast-1" # Wilayah tempat VPC peminta berada.
}

provider "alicloud" {
  alias  = "accepting"
  region = "eu-west-1" # Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Konfigurasikan parameter ini sesuai wilayah VPC penerima.
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-t4ns******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-d7ot******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # ID VPC peminta
  accepting_ali_uid    = data.alicloud_account.default.id # ID akun penerima   
  accepting_region_id  = "eu-west-1"                     # Wilayah tempat VPC penerima berada
  accepting_vpc_id     = var.accepting_vpc_id             # ID VPC penerima
  bandwidth            = 1024                             # Bandwidth dalam Mbit/s. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"                           # Tipe tautan. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
}

# Konfigurasikan rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-t4nl******"            # Tabel rute yang terikat ke vSwitch tempat instans peminta berada
  destination_cidrblock = "172.16.0.0/12"             # Blok CIDR VPC penerima
  nexthop_type          = "VpcPeer"                   # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-d7od******"            # Tabel rute yang terikat ke vSwitch tempat instans penerima berada
  destination_cidrblock = "10.0.0.0/8"                # Blok CIDR VPC peminta
  nexthop_type          = "VpcPeer"                   # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Koneksi peering cross-account

Resource: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "ap-southeast-1" # Wilayah VPC peminta 
}

# Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Anda perlu mengonfigurasinya sesuai wilayah VPC penerima.
variable "accepting_region" {
  default = "eu-west-1"
}

# Akun penerima
variable "accepting_uid" {
  default = "1234******"
}

# ID AccessKey akun penerima
variable "access_key_id" {
  description = "ID AccessKey untuk mengoperasikan infrastruktur Anda"
}
# Rahasia AccessKey akun penerima
variable "access_key_secret" {
  description = "Rahasia AccessKey untuk mengoperasikan infrastruktur Anda"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-t4ns******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-d7ot******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # ID VPC peminta
  accepting_ali_uid    = var.accepting_uid    # ID akun penerima   
  accepting_region_id  = var.accepting_region # Wilayah penerima
  accepting_vpc_id     = var.accepting_vpc_id # ID VPC penerima
  bandwidth            = 1024                 # Bandwidth dalam Mbit/s. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"               # Tipe tautan. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
}

# Penerima menerima permintaan koneksi peering
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-t4nl******" # Tabel rute yang terikat ke vSwitch tempat instans peminta berada
  destination_cidrblock = "192.168.0.0/24" # Blok CIDR VPC penerima
  nexthop_type          = "VpcPeer"        # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-d7od******" # Tabel rute yang terikat ke vSwitch tempat instans penerima berada
  destination_cidrblock = "172.16.0.0/12"  # Blok CIDR VPC peminta
  nexthop_type          = "VpcPeer"        # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Pemecahan Masalah

Mulailah dengan menggunakan Reachability Analyzer untuk memverifikasi konektivitas jaringan.

Periksa status koneksi
- Pastikan status koneksi peering adalah Activated.
- Tindakan: Jika statusnya Accepting, pemilik VPC penerima harus login dan mengklik Accept.
Periksa tumpang tindih CIDR
- Pastikan Blok CIDR VPC peminta dan penerima tidak tumpang tindih.
  - Akar masalah: Jika CIDR tumpang tindih, lalu lintas yang ditujukan ke VPC pasangan akan lebih memilih mencocokkan rute sistem lokal dan tetap berada di dalam VPC lokal. Rute sistem lokal selalu didahulukan daripada rute peering kustom.
  - Blok CIDR VPC tumpang tindih, tetapi Blok CIDR vSwitch tidak. Migrasi VPC direkomendasikan.
    Anda dapat mengonfigurasi rute ke vSwitch pasangan, tetapi koneksi mungkin tidak stabil. Kami sangat menyarankan untuk memindahkan layanan ke VPC dengan Blok CIDR yang tidak tumpang tindih dan membuat ulang koneksi peering.
    Blok CIDR vSwitch tumpang tindih. Migrasi ke VPC yang tidak tumpang tindih bersifat wajib.
- Verifikasi kepatuhan RFC 1918: Periksa apakah Anda menggunakan rentang IP non-standar, seperti 30.0.0.0/16, bukan ruang alamat pribadi standar RFC 1918 .
  - Akar masalah: VPC memperlakukan alamat IP di luar RFC 1918 sebagai Blok CIDR publik. Jika VPC Anda dapat mengakses Internet melalui NAT Gateway atau EIP, lalu lintas yang ditujukan ke pasangan akan diarahkan ke Internet, bukan melalui koneksi peering.
  - Tindakan: Buat IPv4 Gateway untuk mengganti perilaku default ini dan mengarahkan lalu lintas ke VPC tujuan.
- Periksa konflik jaringan lokal: Verifikasi bahwa pengaturan jaringan Docker lokal, seperti alamat IP bridge Docker, tidak bertentangan dengan Blok CIDR VPC pasangan.
Validasi rute di kedua VPC
- Konfirmasi bahwa entri rute ada di kedua VPC, baik peminta maupun penerima. Routing tidak dikonfigurasi secara otomatis.
- Jangan hanya memeriksa tabel rute sistem default. Verifikasi bahwa entri rute ditambahkan ke tabel rute yang terkait dengan vSwitch instans Anda.
Verifikasi aturan kontrol akses
- Tingkat instans (grup keamanan): Verifikasi bahwa aturan inbound dan outbound grup keamanan ECS mengizinkan lalu lintas dari IP pasangan.
- Tingkat vSwitch (ACL jaringan): Verifikasi bahwa aturan inbound dan outbound ACL jaringan yang terkait dengan vSwitch mengizinkan lalu lintas dari IP pasangan.
- Tingkat aplikasi (daftar putih): Untuk layanan PaaS seperti ApsaraDB RDS atau Redis, verifikasi bahwa Blok CIDR VPC pasangan telah ditambahkan ke daftar izin.

Contoh

Hubungkan tiga VPC

Saat mengonfigurasi rute untuk peering VPC, Anda dapat memilih antara dua strategi routing:

Akses penuh: Atur tujuan ke Blok CIDR VPC pasangan dan izinkan semua instans di kedua VPC berkomunikasi sepenuhnya.
Akses granular: Atur tujuan ke Blok CIDR vSwitch atau alamat IP instans tertentu. Ini meningkatkan keamanan dengan membatasi cakupan, tetapi memerlukan pembaruan rute manual setiap kali resource baru membutuhkan akses.

Contoh:

VPC1 (Granular): Dikonfigurasi dengan rute spesifik yang hanya mengarah ke vSwitch 3 di VPC2 dan ECS04 di VPC3. VPC1 dibatasi hanya mengakses resource tersebut.
VPC2 & VPC3 (Penuh): Dikonfigurasi dengan rute yang mengarah ke seluruh Blok CIDR VPC pasangan. Mereka mengizinkan komunikasi penuh dengan VPC pasangan yang diotorisasi.

Hubungkan beberapa VPC ke VPC pusat (Hub-and-spoke)

VPC spoke dapat mengakses layanan di VPC pusat (hub), tetapi tidak dapat berkomunikasi satu sama lain.

Kasus penggunaan umum:

Isolasi departemen: VPC departemen, misalnya HR dan keuangan, tetap terisolasi satu sama lain tetapi berbagi akses ke VPC pusat yang menghosting resource bersama seperti logging dan autentikasi.
Isolasi multi-penyewa: VPC pelanggan terhubung ke VPC penyedia SaaS pusat. Setiap pelanggan terisolasi dari pelanggan lain tetapi dapat mengakses layanan bersama yang dihosting oleh penyedia.

Pemantauan dan O&M

Cakupan yang didukung: Metrik hanya tersedia untuk koneksi peering inter-region.

Notifikasi peringatan: Gunakan CloudMonitor untuk membuat aturan peringatan berbasis ambang batas. Pantau status koneksi secara real-time dan deteksi segera kemacetan jaringan atau kegagalan.

Metrik pemantauan

Metrik	Deskripsi
Inbound Traffic in a Cycle	Trafik yang dikirim dari VPC peminta ke VPC penerima dalam satu periode statistik.
Outbound Traffic in a Cycle	Trafik yang dikirim dari VPC penerima ke VPC peminta dalam satu periode statistik.
Inbound Bandwidth	Bandwidth inbound dari VPC peminta ke VPC penerima.
Outbound Bandwidth	Bandwidth outbound dari VPC penerima ke VPC peminta.
Outbound Packets Dropped Due to Throttling	Laju paket data yang dibuang karena pembatasan bandwidth outbound pada koneksi peering.

Konsol

Lihat metrik

Buka halaman VPC - VPC Peering Connection. Di bilah navigasi atas, pilih wilayah tempat VPC berada.
Klik ikon di kolom Monitoring koneksi peering VPC inter-region yang dituju. Lihat data real-time untuk metrik utama seperti penggunaan bandwidth dan kehilangan paket.

Konfigurasikan peringatan (CloudMonitor)

Buka halaman , lalu klik Create Alert Rule.
Konfigurasikan ambang batas untuk setiap level peringatan. Saat metrik mencapai ambang batasnya, notifikasi akan dikirim secara otomatis ke Alert Contact Group.
Untuk melihat riwayat peringatan sebelumnya, klik Alert History.
Untuk Modify, Disable, atau Delete aturan, gunakan opsi di kolom Actions.

API

Panggil PutResourceMetricRules untuk menetapkan beberapa aturan peringatan berbasis ambang batas untuk metrik tertentu dari koneksi peering VPC. Untuk informasi lebih lanjut, lihat Metrik CloudMonitor untuk koneksi peering.
Panggil EnableMetricRules untuk mengaktifkan satu atau beberapa aturan peringatan.
Panggil DisableMetricRules untuk menonaktifkan aturan peringatan.
Panggil DeleteMetricRules untuk menghapus satu atau beberapa aturan peringatan.

Terraform

Konfigurasikan aturan peringatan berbasis ambang batas. Untuk informasi lebih lanjut, lihat Metrik CloudMonitor untuk koneksi peering.

Resource: alicloud_cms_alarm_contact, alicloud_cms_alarm_contact_group, alicloud_cms_alarm

# ID instans koneksi peering yang akan dipantau
variable "vpc_peer_id" {
  default = "pcc-28cv******"
}

# Buat kontak peringatan
resource "alicloud_cms_alarm_contact" "example_cms_alarm_contact" {
  alarm_contact_name = "example_cms_alarm_contact_name"
  describe           = "example_vpc_peer_alarm"
  channels_mail      = "xxx@xxx.com" # Ganti dengan alamat email Anda.
  lifecycle {
    ignore_changes = [channels_mail]
  }
}

# Buat kelompok kontak peringatan
resource "alicloud_cms_alarm_contact_group" "example_cms_alarm_contact_group" {
  alarm_contact_group_name = "example_cms_alarm_contact_group"
  contacts                 = [alicloud_cms_alarm_contact.example_cms_alarm_contact.id] # Kontak peringatan
}

# Buat aturan peringatan
resource "alicloud_cms_alarm" "example_cms_alarm" {
  name               = "example_cms_alarm_name"
  project            = "acs_vpcpeer" # Namespace data layanan cloud
  metric             = "IntranetRX"  # Nama metrik
  period             = 60            # Periode statistik
  contact_groups     = [alicloud_cms_alarm_contact_group.example_cms_alarm_contact_group.alarm_contact_group_name]
  effective_interval = "06:00-20:00" # Periode efektif
  metric_dimensions  = <<EOF
  [
    {
      "instanceId": "${var.vpc_peer_id}"
    }
  ]
  EOF
  escalations_critical {            # Peringatan level Info
    statistics          = "Sum"     # Metode statistik untuk peringatan
    comparison_operator = ">="      # Operator perbandingan untuk ambang batas
    threshold           = 104857600 # Ambang batas
    times               = 2         # Jumlah percobaan ulang untuk peringatan
  }
}

Penagihan

Jenis koneksi & biaya
- Intra-region: Gratis. Berlaku terlepas dari apakah VPC berada dalam akun yang sama atau berbeda.
- Inter-region: Berbayar. Biaya transfer data dikenakan untuk lalu lintas keluar dan ditagih melalui CDT.
Aturan penagihan
- Harga satuan: Bervariasi berdasarkan wilayah asal/tujuan dan tipe tautan.
- Siklus penagihan: Per jam.
- Perubahan tier: Jika Anda mengganti tipe tautan dalam satu jam penagihan, seluruh jam tersebut akan ditagih dengan tarif tier yang lebih tinggi.
Contoh penagihan
Koneksi Gold antara VPC1 (Akun A, Singapura) dan VPC2 (Akun B, London Inggris) dengan tarif USD 0,08/GB:
- Akun A membayar: USD 0,08/GB × 200 GB = USD 16
- Akun B membayar: USD 0,08/GB × 100 GB = USD 8

FAQ

T: Apakah koneksi peering lintas batas didukung?

J: Ya. Koneksi VPC Peering mendukung kedua skenario konektivitas tersebut:

Non-lintas batas: Menghubungkan dua wilayah di Tiongkok daratan, atau dua wilayah di luar Tiongkok daratan.
Lintas batas: Menghubungkan wilayah di Tiongkok daratan dengan wilayah di luar Tiongkok daratan. Pastikan akun Anda telah menyelesaikan verifikasi identitas bisnis.

T: Mengapa saya tidak bisa memilih VPC target saat membuat koneksi peering?

J: Pastikan wilayah dan akun yang dipilih sesuai dengan lokasi dan pemilik VPC target.

Peminta: Wilayah dan akun yang sedang Anda gunakan berfungsi sebagai Peminta.
Penerima: Wilayah dan akun penerima ditentukan selama konfigurasi. VPC target hanya akan muncul jika pengaturan ini benar.

T: Mengapa instans ECS saya yang menjalankan Docker tidak dapat terhubung ke VPC pasangan?

J: Jika routing dan grup keamanan sudah dikonfigurasi dengan benar, kemungkinan besar masalahnya adalah konflik CIDR antara jaringan bridge Docker (docker0 default) dan Blok CIDR VPC pasangan.

Diagnosis masalah:
Jalankan ip addr di instans ECS untuk memeriksa alamat IP antarmuka Docker. Jika tumpang tindih dengan Blok CIDR VPC pasangan, lalu lintas akan diarahkan secara lokal, bukan ke VPC pasangan.
Solusi: Ubah CIDR bridge Docker
Peringatan: Prosedur ini memerlukan restart layanan Docker, yang akan mengganggu semua kontainer yang sedang berjalan. Lakukan operasi ini selama jendela pemeliharaan dan pastikan Blok CIDR baru tidak bertentangan dengan aplikasi yang ada.
1. Hentikan Docker: sudo systemctl stop docker.
2. Edit file konfigurasi Docker: Buka file konfigurasi, biasanya /etc/docker/daemon.json atau /etc/docker/daemon.conf. Anda dapat menggunakan editor seperti vim, sudo vim /etc/docker/daemon.json.
3. Perbarui alamat IP bridge: Tambahkan atau ubah parameter bip ke Blok CIDR yang tidak bertentangan.
```
{
    "bip":"new Docker CIDR block"
}
```
4. Restart dan verifikasi: sudo systemctl start docker.

Informasi lebih lanjut

Siklus hidup

Saat diinisiasi, koneksi peering VPC melewati tahapan berikut:

Akun yang sama: Sistem secara otomatis menginisiasi, menerima, dan mengaktifkan koneksi secara instan.

Deskripsi status

Status	Deskripsi	Tindakan yang diperlukan
Creating	Permintaan koneksi diinisiasi oleh peminta.	Tunggu hingga proses selesai.
Accepting	Permintaan dikirim dan menunggu penerimaan (hanya untuk cross-account).	Penerima harus menerima dalam waktu 7 hari.
Updating	Penerima menerima permintaan; koneksi sedang dibuat.	Tunggu hingga status berubah menjadi activated.
Activated	Koneksi telah dibuat dan tersedia.	Konfigurasikan rute di kedua VPC untuk mengaktifkan lalu lintas.
Rejected	Penerima menolak permintaan.	Hapus instans tersebut. Buat permintaan baru jika diperlukan.
Expired	Permintaan kedaluwarsa karena tidak ada respons dalam 7 hari.	Hapus instans yang kedaluwarsa dan buat permintaan baru.
Deleting	Koneksi sedang dihentikan.	Tunggu hingga penghapusan selesai.
Deleted	Koneksi dihapus secara permanen.	Tidak ada.

Wilayah yang didukung

Area	Wilayah yang mendukung koneksi peering VPC
Asia-Pasifik - Tiongkok	Tiongkok (Hangzhou), Tiongkok (Shanghai), Tiongkok (Nanjing - Local Region - Decommissioning), Tiongkok (Qingdao), Tiongkok (Beijing), Tiongkok (Zhangjiakou), Tiongkok (Hohhot), Tiongkok (Ulanqab), Tiongkok (Shenzhen), Tiongkok (Heyuan), Tiongkok (Guangzhou), Tiongkok (Chengdu), Tiongkok (Hong Kong), Tiongkok (Wuhan - Local Region), Tiongkok (Fuzhou - Local Region - Decommissioning)
Asia-Pasifik - Lainnya	Jepang (Tokyo), Korea Selatan (Seoul), Singapura, Malaysia (Kuala Lumpur), Indonesia (Jakarta), Filipina (Manila), Thailand (Bangkok)
Eropa dan Amerika	Jerman (Frankfurt), Inggris (London), AS (Silicon Valley), AS (Virginia)
Timur Tengah	UEA (Dubai), SAU (Riyadh - Partner Region)

Kuota

Nama kuota	Deskripsi	Kuota default	Tingkatkan kuota
vpc_quota_cross_region_peer_num_per_vpc	Jumlah koneksi peering VPC inter-region yang dapat dimiliki oleh satu VPC.	20	Buka halaman Manajemen Kuota atau Quota Center untuk mengajukan peningkatan kuota.
vpc_quota_intra_region_peer_num_per_vpc	Jumlah koneksi peering VPC intra-region yang dapat dimiliki oleh satu VPC.	10
vpc_quota_peer_num	Jumlah koneksi peering VPC yang dapat dibuat oleh satu Akun Alibaba Cloud di suatu wilayah.	20
vpc_quota_peer_cross_border_bandwidth	Bandwidth maksimum lintas batas.	1.024 Mbps
vpc_quota_peer_cross_region_bandwidth	Bandwidth maksimum lintas wilayah.	1.024 Mbps