Koneksi peering VPC - Virtual Private Cloud

Secara default, virtual private cloud (VPC) diisolasi satu sama lain. Koneksi peering VPC memungkinkan dua VPC, baik dalam wilayah atau akun yang sama maupun berbeda, terhubung melalui jaringan pribadi.

Cara kerjanya

Koneksi peering VPC menghubungkan dua VPC melalui jaringan pribadi, memungkinkan sumber daya di kedua VPC untuk saling mengakses menggunakan alamat IP pribadi. Ikuti langkah-langkah berikut:

Buat koneksi peering VPC: Jika VPC berada dalam akun yang sama, sistem secara otomatis menerima permintaan dan membuat koneksi. Jika VPC berada di akun yang berbeda, akun penerima harus menerima permintaan koneksi di halaman detail koneksi peering.
Konfigurasikan rute di kedua VPC: Untuk mengaktifkan akses sumber daya, Anda harus menambahkan rute yang menunjuk ke VPC peer.

Untuk menghubungkan banyak VPC dengan biaya rendah namun bandwidth tinggi, gunakan koneksi peering VPC bersama dengan CEN untuk membangun jaringan hibrid kompleks. Untuk perbedaan antara CEN dan koneksi peering VPC, lihat Hubungkan VPC.

Konfigurasikan koneksi peering

Konsol

Pemeriksaan awal:
1. Pastikan blok CIDR dari dua VPC tidak tumpang tindih. Jika mereka tumpang tindih, migrasikan layanan Anda ke VPC dengan blok CIDR yang tidak tumpang tindih.
2. Jika ini pertama kalinya Anda menggunakan koneksi peering VPC, pastikan CDT diaktifkan untuk akun yang memiliki VPC.
Buat koneksi peering:
1. Pergi ke halaman Konsol VPC - Koneksi Peering VPC di konsol VPC. Pilih wilayah tempat VPC berada dari bilah navigasi atas, lalu klik Create VPC Peering Connection.
2. Buat koneksi peering: Pilih akun penerima dan jenis wilayah.
  - Tipe akun penerima:
    - Same Account: Sistem secara otomatis menerima permintaan dan menetapkan koneksi.
    - Cross-Account: Menggunakan akun penerima, pergi ke halaman Konsol VPC - Koneksi Peering VPC. Di bilah navigasi atas, pilih wilayah tempat VPC berada. Di kolom Actions dari koneksi peering target, klik Accept.
      Penerima dapat Reject atau Delete permintaan koneksi. Untuk informasi lebih lanjut, lihat Status koneksi peering VPC.
  - Jika Anda menetapkan tipe wilayah penerima ke Inter-region, konfigurasikan Link Type dan Accepter Region.
    Platinum dan Gold memberikan tingkat kualitas transfer data yang berbeda dan sesuai dengan harga unit penagihan yang berbeda.
    - Platinum (99,995% komitmen ketersediaan): Untuk layanan yang sangat sensitif terhadap jitter dan latensi serta memerlukan kualitas koneksi tinggi, seperti perdagangan sekuritas, panggilan suara online, konferensi video, dan game real-time.
    - Gold (99,95% komitmen ketersediaan): Untuk layanan yang tidak sensitif terhadap kualitas koneksi, seperti sinkronisasi data dan transfer file.
Konfigurasikan rute:
Untuk menggunakan alamat IPv6, konfigurasikan rute yang menunjuk ke blok CIDR IPv6 dari VPC peer.
1. Gunakan akun VPC peminta:
  1. Di halaman Koneksi Peering VPC, temukan koneksi peering target dan lihat Accepter CIDR.
  2. Di kolom Requester VPC, klik Configure Route. Pilih Route Table yang terkait dengan vSwitch yang berisi sumber daya yang ingin Anda hubungkan. Setel Destination CIDR Block ke CIDR penerima.
2. Gunakan akun VPC penerima:
  1. Di halaman Koneksi Peering VPC, lihat Requester CIDR.
  2. Di kolom Accepter VPC, klik Configure Route. Pilih Route Table yang terkait dengan vSwitch yang berisi sumber daya yang ingin Anda hubungkan. Setel Destination CIDR Block ke CIDR peminta.
Verifikasi konektivitas:
- Analisis Jangkauan: Tidak ada paket nyata yang dikirim, sehingga tidak memengaruhi layanan Anda.
  1. Di kolom Diagnose untuk instans koneksi peering, pilih Diagnose > Reachability Analyzer. Sebagai alternatif, klik ID instans koneksi peering untuk pergi ke tab Reachability Analyzer.
  2. Konfigurasikan sumber dan tujuan. Tentukan protokol dan nomor port untuk mensimulasikan skenario nyata dan periksa konektivitas antara sumber dan tujuan.
  3. Sistem memeriksa konfigurasi rute, grup keamanan, dan ACL jaringan, serta memberikan hasil diagnosis.
  4. Jika jalur dapat dicapai dalam satu arah, klik Reverse Path Analysis dan konfigurasikan jalur balik untuk memeriksa konektivitas.
- Verifikasi manual: Di instance ECS di VPC peminta, jalankan perintah ping <alamat IP pribadi dari instance ECS peer>.

Setelah membuat koneksi peering antar-wilayah, Anda dapat mengklik ID instance dan kemudian klik Edit untuk memodifikasi Bandwidth (Mbit/s) dan Link Type dari koneksi peering antar-wilayah.

Kedua akun dapat menghapus koneksi peering VPC. Setelah penghapusan, akses pribadi terputus. Operasi ini tidak dapat dibatalkan. Pastikan bahwa hal itu tidak memengaruhi layanan Anda.

API

Buat koneksi peering

Panggil CreateVpcPeerConnection untuk membuat koneksi peering VPC.
Jika kedua VPC milik akun yang berbeda, gunakan akun penerima untuk memanggil AcceptVpcPeerConnection untuk menerima permintaan.
Penerima dapat memanggil RejectVpcPeerConnection untuk menolak permintaan koneksi.
Panggil GetVpcPeerConnectionAttribute menggunakan akun peminta atau penerima untuk mengambil blok CIDR dari VPC masing-masing.
Panggil CreateRouteEntry menggunakan akun peminta atau penerima untuk membuat rute yang menunjuk ke koneksi peering.

Modifikasi koneksi peering antar-wilayah

Panggil ModifyVpcPeerConnection untuk memodifikasi bandwidth atau jenis tautan dari koneksi peering VPC antar-wilayah.

Hapus koneksi peering

Panggil DeleteRouteEntry untuk menghapus rute yang menunjuk ke koneksi peering.
Panggil DeleteVpcPeerConnection untuk menghapus koneksi peering VPC.

Analisis Jangkauan

Panggil operasi API berikut secara berurutan untuk memeriksa konektivitas menggunakan Analisis Jangkauan.

Terraform

Koneksi peering akun yang sama

Sumber daya: alicloud_vpc_peer_connection, alicloud_route_entry

Sumber data: alicloud_account

# Akun tempat VPC berada
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # Wilayah tempat VPC peminta berada.
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Konfigurasikan berdasarkan wilayah VPC penerima.
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # ID VPC peminta
  accepting_ali_uid    = data.alicloud_account.default.id # ID akun penerima   
  accepting_region_id  = "cn-beijing"                     # Wilayah tempat VPC penerima berada
  accepting_vpc_id     = var.accepting_vpc_id             # ID VPC penerima
  bandwidth            = 1024                             # Bandwidth dalam Mbit/s. Anda hanya dapat mengonfigurasi parameter ini jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"                           # Jenis tautan. Anda hanya dapat mengonfigurasi parameter ini jika wilayah peminta dan penerima berbeda.
}

# Konfigurasikan rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # Tabel rute yang terikat pada vSwitch tempat instance peminta berada
  destination_cidrblock = "172.16.0.0/12"             # Blok CIDR dari VPC penerima
  nexthop_type          = "VpcPeer"                   # Hop berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # Tabel rute yang terikat pada vSwitch tempat instance penerima berada
  destination_cidrblock = "10.0.0.0/8"                # Blok CIDR dari VPC peminta
  nexthop_type          = "VpcPeer"                   # Hop berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Koneksi peering lintas akun

Sumber daya: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # Wilayah VPC peminta 
}

# Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Anda perlu mengonfigurasinya berdasarkan wilayah VPC penerima.
variable "accepting_region" {
  default = "cn-beijing"
}

# Akun penerima
variable "accepting_uid" {
  default = "1234******"
}

# ID AccessKey dari akun penerima
variable "access_key_id" {
  description = "ID AccessKey untuk mengoperasikan infrastruktur Anda"
}
# Rahasia AccessKey dari akun penerima
variable "access_key_secret" {
  description = "Rahasia AccessKey untuk mengoperasikan infrastruktur Anda"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # ID VPC peminta
  accepting_ali_uid    = var.accepting_uid    # ID akun penerima   
  accepting_region_id  = var.accepting_region # Wilayah penerima
  accepting_vpc_id     = var.accepting_vpc_id # ID VPC penerima
  bandwidth            = 1024                 # Bandwidth dalam Mbit/s. Anda hanya dapat mengonfigurasi parameter ini jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"               # Jenis tautan. Anda hanya dapat mengonfigurasi parameter ini jika wilayah peminta dan penerima berbeda.
}

# Penerima menerima permintaan koneksi peering
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # Tabel rute yang terikat pada vSwitch tempat instance peminta berada
  destination_cidrblock = "192.168.0.0/24" # Blok CIDR dari VPC penerima
  nexthop_type          = "VpcPeer"        # Hop berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasikan rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # Tabel rute yang terikat pada vSwitch tempat instance penerima berada
  destination_cidrblock = "172.16.0.0/12"  # Blok CIDR dari VPC peminta
  nexthop_type          = "VpcPeer"        # Hop berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Pemecahan masalah konektivitas jaringan

Daftar Periksa	Verifikasi	Solusi
Status koneksi peering	Periksa apakah Status dari koneksi peering adalah Activated.	Jika statusnya Accepting, hubungi akun penerima untuk menerima koneksi.
Blok CIDR	Periksa Requester CIDR dan Accepter CIDR: Periksa apakah terdapat tumpang tindih. Periksa apakah blok CIDR pribadi non-RFC 1918 digunakan.	Jika blok CIDR tumpang tindih, migrasikan layanan ke VPC dengan blok CIDR yang tidak tumpang tindih dan buat ulang koneksi peering. Jika blok CIDR pribadi non-RFC digunakan, aktifkan akses Internet menggunakan gateway IPv4 untuk memastikan lalu lintas mencapai VPC tujuan.
Rute	Di Route Entry List halaman detail koneksi peering, periksa hal-hal berikut: Apakah rute yang menunjuk ke VPC peer dikonfigurasikan untuk kedua VPC. Apakah blok CIDR tujuan disetel dengan benar ke blok CIDR VPC peer. Apakah rute ditambahkan ke tabel rute yang terkait dengan vSwitch tempat sumber daya berada.	Periksa dan modifikasi rute di kedua VPC.
Aturan akses	Apakah aturan masuk dan keluar dari grup keamanan ECS mengizinkan lalu lintas dari alamat IP peer. Apakah alamat IP peer ditambahkan ke daftar putih instance RDS. Apakah aturan masuk dan keluar dari ACL jaringan yang terkait dengan vSwitch mengizinkan lalu lintas dari alamat IP peer.	Pastikan bahwa grup keamanan, ACL jaringan, dan daftar putih RDS semuanya mengizinkan lalu lintas dari alamat IP peer.

Alasan kegagalan konektivitas karena konfigurasi blok CIDR

Blok CIDR tumpang tindih:
Jika blok CIDR dari dua VPC tumpang tindih dan Anda menetapkan tujuan ke blok CIDR VPC peer, lalu lintas akan cocok oleh rute sistem terlebih dahulu dan diteruskan dalam VPC sumber. Lalu lintas tidak dapat mencapai VPC peer.
1. Jika blok CIDR vSwitch tidak tumpang tindih, Anda dapat menetapkan tujuan ke blok CIDR vSwitch peer. Namun, pendekatan ini dapat menyebabkan masalah saat Anda membuat vSwitch baru karena blok CIDR mereka tidak boleh tumpang tindih dengan yang sudah ada. Kami merekomendasikan migrasi layanan ke VPC dengan blok CIDR yang tidak tumpang tindih dan membuat ulang koneksi peering.
2. Jika blok CIDR vSwitch tumpang tindih, Anda harus memigrasikan layanan ke VPC dengan blok CIDR yang tidak tumpang tindih dan membuat ulang koneksi peering. Ini karena Anda tidak dapat mengonfigurasi rute yang lebih spesifik daripada rute sistem.
Menggunakan blok CIDR pribadi non-RFC 1918:
VPC memperlakukan ruang alamat IP di luar RFC 1918 sebagai blok CIDR publik, seperti 30.0.0.0/16. Saat sumber daya dalam VPC memiliki akses Internet, lalu lintas diarahkan ke Internet terlebih dahulu dan tidak dapat mencapai VPC tujuan melalui koneksi peering. Untuk menyelesaikan ini, Anda harus menggunakan gateway IPv4 untuk mengaktifkan komunikasi pribadi melalui Internet untuk memastikan lalu lintas diarahkan dengan benar ke VPC tujuan.

Contoh

Menghubungkan tiga VPC

Saat mengonfigurasi rute untuk koneksi peering VPC:

Tetapkan blok CIDR tujuan ke blok CIDR VPC peer. Ini memungkinkan semua instance saling mengakses dan menyederhanakan manajemen.
Konfigurasikan rute yang lebih spesifik, dan tetapkan blok CIDR tujuan ke blok CIDR vSwitch atau alamat IP instance tertentu di VPC peer. Namun, jika instance baru memerlukan komunikasi, Anda harus memperbarui tabel rute secara manual.

Sebagai contoh, VPC1 dikonfigurasi dengan rute yang menunjuk ke blok CIDR vSwitch 3 di VPC2 dan ECS04 di VPC3. Oleh karena itu, sumber daya di VPC1 hanya dapat berkomunikasi dengan sumber daya di vSwitch 3 dan ECS04 melalui jaringan pribadi. VPC2 dan VPC3 dikonfigurasi dengan rute yang menunjuk ke blok CIDR VPC peer mereka. Ini memungkinkan interkoneksi penuh antara sumber daya mereka.

Menghubungkan beberapa VPC dan VPC pusat

Dalam skenario ini, VPC cabang dapat mengakses layanan yang diterapkan di VPC pusat, tetapi VPC cabang tidak dapat berkomunikasi satu sama lain. Skenario tipikal meliputi:

Isolasi multi-departemen: VPC untuk departemen bisnis yang berbeda tidak dapat berkomunikasi satu sama lain, tetapi mereka perlu mengakses layanan bersama di VPC pusat.
Isolasi multi-pengguna: Layanan diterapkan di VPC khusus dan disediakan untuk banyak pengguna. Setiap VPC pengguna dapat berkomunikasi dengan VPC layanan, tetapi VPC pengguna tidak dapat berkomunikasi satu sama lain.

Pemantauan dan Operasi & Pemeliharaan

Untuk koneksi peering antar-wilayah, Anda dapat melihat data pemantauan, seperti bandwidth lalu lintas dan tingkat kehilangan paket. Dengan memanfaatkan CloudMonitor, Anda dapat membuat aturan peringatan berbasis ambang batas untuk memantau status koneksi secara real-time. Ini membantu Anda mendeteksi dan menyelesaikan kemacetan jaringan atau gangguan dengan cepat.

Anda tidak dapat melihat metrik koneksi peering intra-wilayah.

Metrik

Metrik	Deskripsi
Inbound Traffic Within Cycle	Lalu lintas yang dikirim dari peminta ke penerima dalam periode statistik.
Outbound Traffic Within Cycle	Lalu lintas yang dikirim dari penerima ke peminta dalam periode statistik.
Inbound Bandwidth	Bandwidth masuk dari peminta ke penerima.
Outbound Bandwidth	Bandwidth keluar dari penerima ke peminta.
Packets Dropped Due To Throttling	Tingkat di mana paket data dibuang karena pembatasan bandwidth keluar untuk koneksi peering VPC.

Konsol

Pantau koneksi peering

Pergi ke halaman Konsol VPC - Koneksi Peering VPC di konsol VPC. Di bilah navigasi atas, pilih wilayah tempat VPC berada.
Klik ikon di kolom Monitoring dari koneksi peering VPC antar-wilayah target untuk melihat metrik seperti bandwidth dan tingkat kehilangan paket.

Peringatan CloudMonitor

Pergi ke halaman Aturan Peringatan di konsol CloudMonitor, dan klik Create Alert Rule.
Konfigurasikan ambang batas untuk setiap level peringatan dari metrik koneksi peering VPC. Saat metrik mencapai ambang batasnya, pemberitahuan peringatan dikirim ke Alert Contact Group yang ditentukan. Anda juga dapat melihat timeline peringatan dengan mengklik Alert History di kolom Actions dari aturan peringatan.
Anda dapat Modify, Disable, atau Delete aturan peringatan di kolom Actions.

API

Panggil PutResourceMetricRules untuk menetapkan beberapa aturan peringatan berbasis ambang batas untuk metrik koneksi peering VPC. Untuk informasi lebih lanjut, lihat Metrik CloudMonitor untuk koneksi peering.
Panggil EnableMetricRules untuk mengaktifkan satu atau lebih aturan peringatan.
Panggil DisableMetricRules untuk menonaktifkan aturan peringatan.
Panggil DeleteMetricRules untuk menghapus satu atau lebih aturan peringatan.

Terraform

Lihat Metrik CloudMonitor untuk koneksi peering untuk mengonfigurasi aturan peringatan berbasis ambang batas.

Sumber daya: alicloud_cms_alarm_contact, alicloud_cms_alarm_contact_group, alicloud_cms_alarm

# ID instance koneksi peering yang akan dipantau
variable "vpc_peer_id" {
  default = "pcc-28cv******"
}

# Buat kontak peringatan
resource "alicloud_cms_alarm_contact" "example_cms_alarm_contact" {
  alarm_contact_name = "example_cms_alarm_contact_name"
  describe           = "example_vpc_peer_alarm"
  channels_mail      = "xxx@xxx.com" # Ubah ke alamat email Anda.
  lifecycle {
    ignore_changes = [channels_mail]
  }
}

# Buat kelompok kontak peringatan
resource "alicloud_cms_alarm_contact_group" "example_cms_alarm_contact_group" {
  alarm_contact_group_name = "example_cms_alarm_contact_group"
  contacts                 = [alicloud_cms_alarm_contact.example_cms_alarm_contact.id] # Kontak peringatan
}

# Buat aturan peringatan
resource "alicloud_cms_alarm" "example_cms_alarm" {
  name               = "example_cms_alarm_name"
  project            = "acs_vpcpeer" # Namespace data layanan cloud
  metric             = "IntranetRX"  # Nama metrik
  period             = 60            # Periode statistik
  contact_groups     = [alicloud_cms_alarm_contact_group.example_cms_alarm_contact_group.alarm_contact_group_name]
  effective_interval = "06:00-20:00" # Periode efektif
  metric_dimensions  = <<EOF
  [
    {
      "instanceId": "${var.vpc_peer_id}"
    }
  ]
  EOF
  escalations_critical {            # Peringatan level Info
    statistics          = "Sum"     # Metode statistik untuk peringatan
    comparison_operator = ">="      # Operator perbandingan untuk ambang batas
    threshold           = 104857600 # Ambang batas
    times               = 2         # Jumlah percobaan ulang untuk peringatan
  }
}

FAQ

Apakah koneksi peering mendukung koneksi lintas batas?

Ya. Baik koneksi non-lintas batas maupun lintas batas didukung.

Non-lintas batas: Menghubungkan dua wilayah di daratan Tiongkok atau dua wilayah di luar daratan Tiongkok.
Lintas batas: Dari wilayah di daratan Tiongkok ke wilayah di luar daratan Tiongkok. Pergi ke Jalur Sewa Lintas Batas untuk mengajukan kualifikasi perusahaan. Jalur sewa lintas batas disediakan oleh China Unicom.

Berapa latensi jaringan koneksi peering?

Intra-region: Latensi rendah.
Antar-region: Karena data ditransfer antar wilayah, latensi bergantung pada jarak fisik dan kondisi jaringan antara kedua wilayah. Gunakan pemantauan jaringan cloud untuk melihat latensi rata-rata antar wilayah sebagai referensi dan pilih jenis tautan untuk bisnis Anda.

Mengapa saya tidak bisa memilih VPC tujuan saat membuat koneksi peering?

Pastikan wilayah dan akun yang dipilih sesuai dengan Region dan Owner dari VPC tujuan.

Wilayah peminta ditampilkan di bagian atas halaman, dan akun tempat Anda saat ini masuk adalah akun peminta. Anda harus menentukan akun penerima dan wilayah saat membuat koneksi peering.

Informasi lebih lanjut

Batasan

Anda tidak dapat membuat koneksi peering VPC dalam kasus berikut:
- Satu VPC milik akun yang dibuat di situs China (aliyun.com) dan yang lainnya di situs Internasional (alibabacloud.com).
Koneksi peering VPC tidak mendukung propagasi rute.
Sebagai contoh, jika VPC 2 dan VPC 3 keduanya terhubung ke VPC 1 menggunakan koneksi peering, VPC 2 dan VPC 3 tidak dapat berkomunikasi satu sama lain melalui VPC 1.
Dalam VPC bersama multi-akun, pemilik sumber daya dapat membuat, memodifikasi, atau menghapus koneksi peering, tetapi pihak yang berwenang tidak memiliki izin tersebut.

Penagihan

Tidak ada biaya yang dikenakan untuk koneksi peering VPC intra-region, baik jika kedua VPC milik akun yang sama maupun berbeda.

Untuk koneksi peering VPC antar-wilayah, CDT mengenakan biaya transfer data pada lalu lintas keluar.

Harga satuan ditentukan oleh granularitas wilayah dan jenis tautan. Platinum dan Gold, dua jenis tautan yang tersedia, memberikan tingkat kualitas transfer data yang berbeda.
Siklus penagihan adalah per jam. Jika Anda beralih jenis tautan dalam siklus penagihan, Anda akan dikenakan harga satuan tingkat yang lebih tinggi untuk siklus tersebut.

Seperti yang ditunjukkan pada gambar, koneksi peering VPC dibuat antara VPC1 dan VPC2. VPC ini berada di wilayah yang berbeda dan milik akun yang berbeda. Anggaplah lalu lintas keluar melalui koneksi peering VPC adalah 200 GB dari VPC1 dan 100 GB dari VPC2. Jenis tautannya adalah Gold. biaya transfer data antar-wilayah dari Cina (Hohhot) ke Cina (Guangzhou) adalah 0,072 USD/GB. Berdasarkan aturan penagihan:

Biaya untuk Akun A: USD 0,072/GB × 200 GB = USD 14,4

Biaya untuk Akun B: USD 0,072/GB × 100 GB = USD 7,2

Tahapan koneksi peering VPC

Koneksi peering VPC melewati beberapa tahap, mulai dari saat permintaan pembuatan dikirim.

Jika Anda membuat koneksi peering VPC dalam akun yang sama, sistem secara otomatis memulai dan menerima permintaan koneksi, dan koneksi peering VPC menjadi aktif.

Deskripsi status

Status	Deskripsi
Membuat	Status setelah peminta mengirim permintaan koneksi.
Menerima	Status saat koneksi sedang menunggu diterima oleh penerima.
Memperbarui	Status setelah penerima menerima permintaan koneksi.
Aktif	Status setelah peminta dan penerima mengaktifkan koneksi peering.
Ditolak	Status setelah penerima menolak permintaan koneksi.
Kadaluarsa	Koneksi peering VPC Kadaluarsa. Hal ini terjadi jika penerima tidak merespons permintaan selama lebih dari tujuh hari.
Menghapus	Status peralihan setelah peminta atau penerima menghapus koneksi.
Dihapus	Status setelah koneksi peering VPC berhasil dihapus.

Wilayah yang didukung

Area	Wilayah
Asia Pasifik - Tiongkok	Cina (Hangzhou), Cina (Shanghai), Cina (Nanjing - Wilayah Lokal, Ditutup), Cina (Qingdao), Cina (Beijing), Cina (Zhangjiakou), Cina (Hohhot), Cina (Ulanqab), Cina (Shenzhen), Cina (Heyuan), Cina (Guangzhou), Cina (Chengdu), Cina (Hong Kong), Cina (Wuhan - Wilayah Lokal), dan Cina (Fuzhou - Wilayah Lokal, Ditutup)
Asia Pasifik - Lainnya	Jepang (Tokyo), Korea Selatan (Seoul), Singapura, Malaysia (Kuala Lumpur), Indonesia (Jakarta), Filipina (Manila), dan Thailand (Bangkok)
Eropa & Amerika	Jerman (Frankfurt), Inggris (London), AS (Silicon Valley), dan AS (Virginia)
Timur Tengah	UEA (Dubai) dan SAU (Riyadh - Wilayah Mitra) Penting Wilayah SAU (Riyadh - Wilayah Mitra) dioperasikan oleh mitra.

Kuota

Nama Kuota	Deskripsi	Kuota Default	Tingkatkan Kuota
vpc_quota_cross_region_peer_num_per_vpc	Jumlah koneksi peering VPC antar-wilayah untuk sebuah VPC.	20	Pergi ke halaman Manajemen Kuota atau Pusat Kuota untuk meminta peningkatan.
vpc_quota_intra_region_peer_num_per_vpc	Jumlah koneksi peering VPC intra-region untuk sebuah VPC.	10
vpc_quota_peer_num	Jumlah koneksi peering VPC yang dibuat oleh akun Alibaba Cloud di wilayah tertentu.	20
vpc_quota_peer_cross_border_bandwidth	Bandwidth lintas batas maksimum.	1024 Mbps
vpc_quota_peer_cross_region_bandwidth	Bandwidth antar-wilayah maksimum.	1024 Mbps