Provision Resource Cloud pada Windows dengan Terraform - Terraform

Topik ini menjelaskan cara menggunakan Terraform untuk membuat sumber daya Alibaba Cloud di Windows dengan cepat.

Anda dapat menggunakan Terraform untuk mengelola infrastruktur sebagai kode (IaC). Prosedur ini mencakup langkah-langkah berikut:

Instal Terraform: Pastikan sistem Anda dapat mendeteksi dan mengeksekusi perintah Terraform.
Tulis file konfigurasi Terraform: File konfigurasi adalah inti dari Terraform. Ini digunakan untuk mendefinisikan pembuatan, konfigurasi, dan dependensi sumber daya seperti VPC, Instance ECS, dan Bucket OSS.
Inisialisasi dan buat sumber daya: Langkah ini merupakan kunci dalam mewujudkan desain infrastruktur Anda.
Lihat dan kelola sumber daya: Setelah penyebaran, Anda dapat melihat dan mengelola lingkungan infrastruktur untuk memastikan kesesuaian dengan kebutuhan dan desain terbaru Anda.
Hapus sumber daya: Saat sumber daya tidak lagi diperlukan, Anda dapat menghapusnya.

1. Instal Terraform

Kunjungi situs resmi Terraform, unduh file biner Terraform untuk sistem operasi Windows Anda, lalu ekstrak file tersebut.
Tambahkan jalur instalasi Terraform ke Variabel lingkungan sistem Path.
1. Di desktop, klik kanan This PC, lalu pilih Properties > Advanced system settings > Environment Variables > System variables/User variables.
2. Di bagian System variables/User variables, klik Path, pilih Edit > New, masukkan jalur folder tempat file berada, lalu klik OK.
Verifikasi instalasi. Tekan Win+R, masukkan cmd, lalu klik OK untuk membuka command prompt. Jalankan perintah terraform --version. Jika output serupa dengan berikut, instalasi berhasil.
```
Terraform v1.9.3
on windows_amd64
```

2. Tulis file konfigurasi Terraform

File konfigurasi adalah inti dari Terraform. Ini digunakan untuk mendefinisikan sumber daya infrastruktur yang akan diterapkan di cloud atau on-premises, seperti VPC, Instance ECS, dan Bucket OSS.

Buat folder baru bernama ecs. Di dalam folder ini, buat file konfigurasi Terraform bernama main.tf.
Membuat direktori kerja independen untuk setiap proyek Terraform memastikan organisasi sumber daya yang jelas, mencegah pengaburan file state, memfasilitasi Pengendalian versi dan kolaborasi tim, serta membantu menerapkan isolasi lingkungan dan manajemen modular. Praktik ini meningkatkan kemampuan pemeliharaan dan keamanan manajemen konfigurasi Anda.

Tulis file konfigurasi Terraform. Contoh berikut menunjukkan cara membuat Instance ECS. Dalam file konfigurasi, Anda mendefinisikan Instance ECS dan sumber daya dependennya, seperti VPC dan grup keamanan, secara terkode. Untuk kenyamanan, Anda dapat menyalin kode berikut ke file main.tf.

Penting

Instance ECS dalam contoh ini menggunakan metode penagihan bayar sesuai pemakaian. Anda akan dikenakan biaya untuk sumber daya setelah dibuat.
Contoh ini menggunakan Variabel lingkungan untuk otentikasi Terraform. Untuk informasi lebih lanjut, lihat Otentikasi identitas Terraform.

Sumber daya yang diperlukan untuk membuat Instance ECS adalah sebagai berikut:

Sumber Daya	Deskripsi
alicloud_vpc	Membuat instansi terhubung-VPC
alicloud_vswitch	Membuat instansi vSwitch
alicloud_security_group	Membuat instansi grup keamanan
alicloud_security_group_rule	Membuat aturan akses arah masuk dan arah keluar untuk grup keamanan
alicloud_instance	Membuat Instance ECS

variable "name" {
  type    = string
  default = "tf-test"
}

# Atur wilayah
variable "region" {
  type    = string
  default = "cn-beijing"
}

# Bandwidth publik. Jika nilainya lebih besar dari 0, alamat IP publik akan ditetapkan ke instans.
variable "internet_max_bandwidth_out" {
  type    = number
  default = 10
}

# Atur tipe instans ECS
variable "instance_type" {
  type    = string
  default = "ecs.e-c1m1.large"
}

# Atur ID citra
variable "image_id" {
  default = "ubuntu_18_04_64_20G_alibase_20190624.vhd"
}

# Atur tag
variable "tags" {
  type    = map(string)
  default = {
    From =  "Terraform"
    Usage =  "demo"
  }
}

provider "alicloud" {
  region = var.region
}

# Dapatkan ID zona
data "alicloud_zones" "default" {
  available_instance_type = var.instance_type
  available_resource_creation = "VSwitch"
  available_disk_category = "cloud_ssd"
}

# Buat VPC
resource "alicloud_vpc" "vpc" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# Buat vSwitch
resource "alicloud_vswitch" "vsw" {
  vpc_id     = alicloud_vpc.vpc.id
  cidr_block = "172.16.0.0/21"
  zone_id    = data.alicloud_zones.default.zones[0].id
}

# Buat grup keamanan
resource "alicloud_security_group" "default" {
  name   = var.name
  vpc_id = alicloud_vpc.vpc.id
}

# Tambahkan aturan arah masuk ke grup keamanan
resource "alicloud_security_group_rule" "allow_tcp_22" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "22/22"
  priority          = 1
  security_group_id = alicloud_security_group.default.id
  cidr_ip           = "0.0.0.0/0"
}

# Buat Instance ECS
resource "alicloud_instance" "instance" {
  availability_zone          = data.alicloud_zones.default.zones.0.id
  security_groups            = alicloud_security_group.default.*.id
  instance_type              = var.instance_type
  system_disk_category       = "cloud_essd_entry"
  image_id                   = var.image_id
  instance_name              = var.name
  vswitch_id                 = alicloud_vswitch.vsw.id
  internet_max_bandwidth_out = var.internet_max_bandwidth_out
  tags                       = var.tags
}

output "ecs_id" {
  value = alicloud_instance.instance.id
}

output "ecs_ip" {
  value = alicloud_instance.instance.public_ip
}

3. Inisialisasi dan pembuatan sumber daya

Setelah Anda menulis file konfigurasi Terraform, Anda harus menginisialisasi direktori kerja sebelum membuat sumber daya.

3.1 Inisialisasi Terraform

Di jendela cmd, beralihlah ke folder yang Anda buat di Langkah 2, lalu jalankan perintah terraform init untuk melakukan inisialisasi. Perintah terraform init adalah perintah pertama yang harus dijalankan di proyek Terraform baru. Ini menginisialisasi direktori kerja dengan mengunduh plug-in penyedia Alibaba Cloud yang diperlukan dan berbagai file rekaman lainnya.

# Beralih ke drive D
d:
# Perintah untuk beralih ke jalur folder di Langkah 2. tool/terraform/projects/ecs adalah jalur folder yang dibuat di Langkah 2. Anda dapat menggantinya dengan jalur aktual.
cd tool/terraform/projects/ecs
# Jalankan perintah inisialisasi
terraform init

3.2 Buat sumber daya

Jalankan perintah terraform plan untuk membuat rencana eksekusi. Rencana ini menunjukkan detail semua sumber daya yang akan dibuat, dimodifikasi, atau dihapus saat Anda menjalankan perintah `terraform apply`.
Saat Anda menjalankan perintah terraform apply, sumber daya dibuat berdasarkan rencana eksekusi yang dihasilkan oleh perintah terraform plan. Selama proses pembuatan, Anda harus memasukkan yes saat diminta untuk melanjutkan pembuatan sumber daya. Untuk informasi lebih lanjut tentang melewati nilai variabel, lihat Variabel.

4. Lihat dan kelola sumber daya

Setelah penyebaran, Anda dapat mengelola dan memelihara lingkungan infrastruktur Anda untuk memastikan bahwa itu sesuai dengan kebutuhan dan desain terbaru Anda.

4.1 Lihat sumber daya

Jalankan perintah terraform show untuk melihat detail sumber daya Anda.
Jalankan perintah terraform state list untuk mencantumkan semua sumber daya yang telah dibuat.
Jalankan perintah terraform state show <resource_type>.<resource_name> untuk melihat detail sumber daya tertentu.
Lihat informasi tentang sumber daya yang telah dibuat di Konsol Manajemen Alibaba Cloud.

4.2 Kelola sumber daya

Setelah Terraform membuat dan memodifikasi sumber daya, status dan informasi properti sumber daya disimpan ke file terraform.tfstate. Anda dapat menggunakan perintah terraform state untuk mengelola status. Untuk informasi lebih lanjut, lihat Pengantar prinsip status.

4.3 Perubahan sumber daya

Ubah definisi sumber daya yang ingin Anda ubah di file konfigurasi, seperti main.tf atau file .tf lainnya. Misalnya, Anda mungkin ingin menambahkan aturan arah masuk baru ke grup keamanan.

resource "alicloud_security_group_rule" "allow_tcp_443" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "443/443"
  priority          = 1
  security_group_id = alicloud_security_group.default.id
  cidr_ip           = "0.0.0.0/0"
}

Jalankan perintah terraform plan untuk melihat pratinjau perubahan.
Jika perubahan sesuai dengan harapan Anda, jalankan perintah terraform apply untuk menerapkan perubahan ke infrastruktur Anda. Terraform akan meminta Anda untuk konfirmasi. Masukkan yes dan tekan Enter untuk menerapkan perubahan.

5. Hapus sumber daya

Saat sumber daya tidak lagi diperlukan, Anda dapat menjalankan perintah terraform destroy untuk menghapus semua sumber daya yang Anda buat.

Terraform:Gunakan Terraform di Windows