Koneksi peering VPC - Virtual Private Cloud

Secara default, virtual private clouds (VPC) terisolasi satu sama lain. Untuk menghubungkan dua VPC yang Blok CIDR-nya tidak tumpang tindih, Anda dapat membuat koneksi peering VPC dan mengonfigurasi rute untuk kedua VPC tersebut. Resource di kedua VPC dapat saling mengakses seolah-olah berada dalam jaringan yang sama. Koneksi peering VPC dapat dibuat antara VPC dalam akun yang sama maupun berbeda, serta dalam wilayah yang sama maupun berbeda.

Cara kerja

Langkah-langkah berikut menjelaskan proses koneksi peering VPC, yang melibatkan VPC peminta dan VPC penerima:

Pemilik VPC peminta membuat koneksi peering VPC.
- Jika VPC penerima berada dalam akun yang sama, sistem secara otomatis menerima permintaan koneksi dan mengaktifkannya.
- Jika VPC penerima berada dalam akun lain, pemiliknya harus menerima permintaan tersebut.
Pemilik masing-masing VPC secara manual menambahkan rute yang mengarah ke Blok CIDR VPC lainnya, yang juga disebut VPC peer.

Untuk menghubungkan beberapa VPC yang memerlukan bandwidth tinggi dengan biaya rendah, Anda dapat menggabungkan koneksi peering VPC dan Cloud Enterprise Network (CEN). Untuk memahami perbedaan keduanya, lihat Hubungkan VPC.

Buat koneksi peering VPC

Konsol

Prasyarat:
1. Blok CIDR kedua VPC tidak tumpang tindih. Jika tumpang tindih, migrasikan layanan Anda ke VPC dengan Blok CIDR yang tidak tumpang tindih.
2. Jika ini pertama kalinya Anda menggunakan koneksi peering VPC, pastikan Cloud Data Transfer (CDT) telah diaktifkan untuk kedua VPC.
Buat koneksi peering VPC:
1. Buka halaman VPC - VPC Peering Connection. Di bilah navigasi atas, pilih wilayah tempat VPC berada, lalu klik Create VPC Peering Connection.
2. Pilih tipe akun penerima dan tipe wilayah penerima.
  - Tipe akun penerima:
    - Same-Account: Secara otomatis menerima permintaan dan mengaktifkan koneksi. Anda dapat mengklik Add route to peer VPC CIDR, dan sistem akan mengonfigurasi rute yang mengarah ke VPC peer.
    - Cross-Account: Pemilik akun penerima harus membuka halaman VPC console - VPC Peering Connection. Di bilah navigasi atas, pilih wilayah tempat VPC penerima berada. Temukan koneksi peering tersebut, lalu klik Accept pada kolom Actions.
      Penerima juga dapat Reject atau Delete permintaan koneksi. Untuk informasi lebih lanjut tentang proses ini, lihat Siklus hidup koneksi peering VPC.
  - Untuk koneksi Inter-Region, Anda harus mengonfigurasi Link Type dan Accepter Region.
    Platinum dan Gold menyediakan tingkat kualitas transfer data yang berbeda dan harga penagihan-nya bervariasi.
    - Platinum (ketersediaan layanan 99,995%): Direkomendasikan untuk layanan yang sensitif terhadap jitter dan latensi serta memerlukan kualitas koneksi tinggi, seperti perdagangan sekuritas, panggilan suara online, konferensi video, dan game real-time.
    - Gold (ketersediaan layanan 99,95%): Direkomendasikan untuk layanan yang tidak sensitif terhadap kualitas koneksi, seperti sinkronisasi data dan transfer file.
Konfigurasi rute:
Untuk mengaktifkan komunikasi melalui IPv6, Anda juga harus mengonfigurasi rute yang mengarah ke Blok CIDR IPv6 VPC peer.
1. Dari VPC peminta: Di kolom Requester VPC, klik Configure route. Pilih tabel rute Requester yang terkait dengan vSwitch, lalu atur Destination CIDR Block ke Blok CIDR VPC penerima.
2. Dari VPC penerima: Di kolom Accepter, klik Configure route. Pilih Requester route table yang terkait dengan vSwitch. Atur Destination CIDR Block ke CIDR VPC peminta.
Verifikasi konektivitas:
- Reachability Analyzer: Tidak ada paket data nyata yang dikirim dan layanan Anda tidak terpengaruh.
  1. Di kolom Diagnose koneksi peering, pilih Diagnose > Reachability Analyzer. Alternatifnya, Anda dapat mengklik ID instans koneksi peering untuk membuka tab Reachability Analyzer.
  2. Konfigurasikan sumber dan tujuan. Tentukan protokol dan port untuk mensimulasikan skenario bisnis dan periksa konektivitasnya.
  3. Sistem memeriksa pengaturan rute, security group, dan ACL jaringan, lalu memberikan hasil diagnosis.
  4. Jika jalur satu arah dapat dijangkau, klik reverse path analytics untuk memeriksa konektivitas balik.
- Verifikasi manual: Di instans ECS dalam VPC peminta, jalankan perintah ping <private IP of the peer ECS instance>.

Setelah membuat koneksi peering antar-wilayah, klik ID instans lalu klik Edit untuk mengubah Bandwidth (Mbit/s) dan Link Type.

Baik VPC peminta maupun penerima dapat menghapus koneksi peering. Setelah koneksi dihapus, akses privat terputus. Operasi ini tidak dapat dibatalkan. Pastikan layanan Anda tidak terganggu akibat penghapusan tersebut.

API

Buat koneksi peering

Panggil CreateVpcPeerConnection untuk membuat koneksi peering VPC.
Jika kedua VPC berada dalam akun berbeda, pemilik akun penerima harus memanggil AcceptVpcPeerConnection untuk menerima koneksi peering VPC tersebut.
Penerima dapat memanggil RejectVpcPeerConnection untuk menolak koneksi peering VPC.
Pemilik kedua VPC harus memanggil GetVpcPeerConnectionAttribute untuk menanyakan Blok CIDR kedua VPC.
Pemilik kedua VPC harus memanggil CreateRouteEntry untuk membuat rute yang mengarah ke koneksi peering.

Ubah koneksi peering antar-wilayah

Panggil ModifyVpcPeerConnection untuk mengubah bandwidth atau tipe tautan koneksi peering VPC antar-wilayah.

Hapus koneksi peering

Panggil DeleteRouteEntry untuk menghapus rute yang mengarah ke koneksi peering.
Panggil DeleteVpcPeerConnection untuk menghapus koneksi peering VPC.

Analisis jalur

Panggil operasi API berikut secara berurutan untuk menggunakan analisis jalur guna memeriksa konektivitas.

Terraform

Koneksi peering dalam akun yang sama

Resource: alicloud_vpc_peer_connection, alicloud_route_entry

Data Sources: alicloud_account

# Akun tempat VPC berada
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # Wilayah tempat VPC peminta berada.
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Konfigurasikan parameter ini sesuai wilayah VPC penerima.
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # ID VPC peminta
  accepting_ali_uid    = data.alicloud_account.default.id # ID akun penerima   
  accepting_region_id  = "cn-beijing"                     # Wilayah tempat VPC penerima berada
  accepting_vpc_id     = var.accepting_vpc_id             # ID VPC penerima
  bandwidth            = 1024                             # Bandwidth dalam Mbit/s. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"                           # Tipe tautan. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
}

# Konfigurasi rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # Tabel rute yang terikat pada vSwitch tempat instans peminta berada
  destination_cidrblock = "172.16.0.0/12"             # Blok CIDR VPC penerima
  nexthop_type          = "VpcPeer"                   # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasi rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # Tabel rute yang terikat pada vSwitch tempat instans penerima berada
  destination_cidrblock = "10.0.0.0/8"                # Blok CIDR VPC peminta
  nexthop_type          = "VpcPeer"                   # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Koneksi peering lintas akun

Resource: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # Wilayah VPC peminta 
}

# Wilayah VPC penerima. Bisa sama dengan wilayah VPC peminta. Anda perlu mengonfigurasinya sesuai wilayah VPC penerima.
variable "accepting_region" {
  default = "cn-beijing"
}

# Akun penerima
variable "accepting_uid" {
  default = "1234******"
}

# ID AccessKey akun penerima
variable "access_key_id" {
  description = "ID AccessKey untuk mengoperasikan infrastruktur Anda"
}
# Rahasia AccessKey akun penerima
variable "access_key_secret" {
  description = "Rahasia AccessKey untuk mengoperasikan infrastruktur Anda"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# ID VPC peminta
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# ID VPC penerima
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # ID VPC peminta
  accepting_ali_uid    = var.accepting_uid    # ID akun penerima   
  accepting_region_id  = var.accepting_region # Wilayah penerima
  accepting_vpc_id     = var.accepting_vpc_id # ID VPC penerima
  bandwidth            = 1024                 # Bandwidth dalam Mbit/s. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
  link_type            = "Gold"               # Tipe tautan. Parameter ini hanya dapat dikonfigurasi jika wilayah peminta dan penerima berbeda.
}

# Penerima menerima permintaan koneksi peering
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasi rute untuk VPC peminta
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # Tabel rute yang terikat pada vSwitch tempat instans peminta berada
  destination_cidrblock = "192.168.0.0/24" # Blok CIDR VPC penerima
  nexthop_type          = "VpcPeer"        # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Konfigurasi rute untuk VPC penerima
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # Tabel rute yang terikat pada vSwitch tempat instans penerima berada
  destination_cidrblock = "172.16.0.0/12"  # Blok CIDR VPC peminta
  nexthop_type          = "VpcPeer"        # Lompatan berikutnya adalah koneksi peering VPC
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Pemecahan masalah

Pertama-tama manfaatkan Analisis Jalur untuk memverifikasi konektivitas jaringan.

Item pemeriksaan	Periksa konten	Solusi
Status koneksi	Status koneksi peering adalah Activated.	Jika statusnya Accepting, pemilik akun penerima harus menerima permintaan koneksi tersebut.
Blok CIDR	Periksa Blok CIDR peminta dan penerima: Apakah tumpang tindih. Apakah menggunakan Blok CIDR pribadi non-standar RFC 1918. Apakah penerapan Docker pada instans ECS menyebabkan konflik dengan alamat kartu antarmuka jaringan Docker.	Jika Blok CIDR tumpang tindih, migrasikan layanan ke VPC lain dengan Blok CIDR yang tidak tumpang tindih dan buat ulang koneksi tersebut. Jika menggunakan Blok CIDR pribadi non-standar RFC 1918, buat gateway IPv4 untuk mengarahkan traffic ke VPC tujuan. Ubah Blok CIDR Docker.
Rute	Periksa Route Entry List di halaman detail koneksi peering: Apakah rute ke VPC peer telah dikonfigurasi untuk kedua VPC. Apakah CIDR tujuan diatur dengan benar ke CIDR VPC peer. Apakah rute ditambahkan ke tabel rute yang terkait dengan vSwitch tempat resource ditempatkan.	Ubah konfigurasi rute.
Aturan akses	Apakah aturan inbound dan outbound grup keamanan ECS mengizinkan traffic dari IP peer. Apakah IP peer masuk dalam daftar putih instans RDS. Apakah aturan inbound dan outbound ACL jaringan yang terkait dengan vSwitch mengizinkan traffic dari IP peer.	Pastikan grup keamanan, ACL jaringan, dan instans RDS memasukkan semua traffic dari alamat IP peer ke dalam daftar putih.

Kegagalan akibat konfigurasi Blok CIDR

Blok CIDR tumpang tindih:
Jika CIDR dua VPC tumpang tindih dan Anda mengatur tujuan ke CIDR VPC peer, traffic akan lebih memilih mencocokkan rute sistem dan tetap di dalam VPC lokal, bukan diarahkan ke VPC peer.
1. Jika Blok CIDR vSwitch dua VPC tidak tumpang tindih, Anda dapat mengatur tujuan ke CIDR vSwitch peer. Namun, saat membuat vSwitch baru, Blok CIDR-nya tidak boleh tumpang tindih dengan yang sudah ada. Oleh karena itu, kami menyarankan Anda memigrasikan layanan ke VPC dengan Blok CIDR yang tidak tumpang tindih dan membuat ulang koneksi peering.
2. Jika Blok CIDR vSwitch tumpang tindih, Anda hanya dapat memigrasikan layanan ke VPC dengan Blok CIDR yang tidak tumpang tindih dan membuat ulang koneksi tersebut. Hal ini karena Anda tidak dapat mengonfigurasi rute yang lebih spesifik daripada rute sistem.
Menggunakan Blok CIDR pribadi non-standar RFC 1918:
VPC memperlakukan ruang alamat IP di luar RFC 1918 sebagai Blok CIDR publik, seperti 30.0.0.0/16. Saat resource dalam VPC dapat mengakses Internet, traffic diarahkan ke Internet dan tidak dapat mencapai VPC tujuan melalui koneksi peering. Untuk mengatasinya, buat gateway IPv4 untuk memastikan traffic diarahkan ke VPC tujuan.

Contoh

Hubungkan tiga VPC

Saat mengonfigurasi rute untuk koneksi peering VPC:

Atur CIDR tujuan ke CIDR VPC peer agar semua instans dapat saling mengakses.
Konfigurasikan rute yang lebih spesifik, dan atur CIDR tujuan ke CIDR vSwitch atau alamat IP instans tertentu di VPC peer untuk meningkatkan keamanan. Namun, jika instans baru memerlukan komunikasi, Anda harus memperbarui tabel rute secara manual.

Sebagai contoh, VPC1 dikonfigurasi dengan rute yang mengarah ke CIDR vSwitch 3 di VPC2 dan ECS04 di VPC3. Resource di VPC1 hanya dapat berkomunikasi dengan resource di vSwitch 3 dan ECS04 melalui alamat IP privat. VPC2 dan VPC3 dikonfigurasi dengan rute yang mengarah ke CIDR VPC peer, sehingga memungkinkan komunikasi penuh antar resource mereka.

Hubungkan beberapa VPC ke VPC pusat

VPC cabang dapat mengakses layanan di VPC pusat, tetapi VPC cabang tidak saling terhubung. Kasus penggunaannya meliputi:

Isolasi departemen: VPC departemen yang saling terisolasi perlu mengakses VPC pusat.
Isolasi pengguna: Layanan di VPC pusat diakses oleh VPC pengguna. Setiap VPC pengguna berkomunikasi dengan VPC pusat, tetapi saling terisolasi satu sama lain.

Pemantauan dan O&M

Data pemantauan, seperti bandwidth dan tingkat kehilangan paket, tersedia untuk koneksi peering antar-wilayah. Gunakan CloudMonitor untuk membuat aturan peringatan berbasis ambang batas guna memantau status koneksi secara real-time. Deteksi dan atasi kemacetan jaringan atau titik kegagalan secara cepat.

Anda tidak dapat melihat metrik koneksi peering intra-wilayah.

Metrik pemantauan

Metrik	Deskripsi
Inbound Traffic in a Cycle	Traffic yang dikirim dari VPC peminta ke VPC penerima dalam periode statistik.
Outbound Traffic in a Cycle	Traffic yang dikirim dari VPC penerima ke VPC peminta dalam periode statistik.
Inbound Bandwidth	Bandwidth inbound dari VPC peminta ke VPC penerima.
Outbound Bandwidth	Bandwidth outbound dari VPC penerima ke VPC peminta.
Outbound Packets Dropped Due to Throttling	Laju paket data yang dibuang akibat pembatasan bandwidth outbound untuk instans koneksi peering VPC.

Konsol

Pantau koneksi peering

Buka halaman VPC - VPC Peering Connection. Di bilah navigasi atas, pilih wilayah tempat VPC berada.
Klik ikon di kolom Monitoring koneksi peering VPC antar-wilayah yang dituju untuk melihat metrik, seperti bandwidth dan kehilangan paket.

Peringatan CloudMonitor

Buka halaman CloudMonitor - Alert Rules, lalu klik + Create Alert Rule.
Konfigurasikan ambang batas untuk setiap level peringatan. Saat metrik mencapai ambang batasnya, pemberitahuan peringatan dikirim ke Alert Contact Group yang ditentukan. Lihat timeline peringatan dengan mengklik Alert History di kolom Actions aturan peringatan.
Di kolom Actions aturan peringatan, Anda dapat Modify, Disable, atau Delete aturan tersebut.

API

Panggil PutResourceMetricRules untuk menetapkan beberapa aturan peringatan berbasis ambang batas untuk metrik tertentu dari koneksi peering VPC. Untuk informasi selengkapnya, lihat Metrik CloudMonitor untuk koneksi peering.
Panggil EnableMetricRules untuk mengaktifkan satu atau beberapa aturan peringatan.
Panggil DisableMetricRules untuk menonaktifkan aturan peringatan.
Panggil DeleteMetricRules untuk menghapus satu atau beberapa aturan peringatan.

Terraform

Konfigurasikan aturan peringatan berbasis ambang batas. Untuk informasi selengkapnya, lihat Metrik CloudMonitor untuk koneksi peering.

Resource: alicloud_cms_alarm_contact, alicloud_cms_alarm_contact_group, alicloud_cms_alarm

# ID instans koneksi peering yang akan dipantau
variable "vpc_peer_id" {
  default = "pcc-28cv******"
}

# Buat kontak peringatan
resource "alicloud_cms_alarm_contact" "example_cms_alarm_contact" {
  alarm_contact_name = "example_cms_alarm_contact_name"
  describe           = "example_vpc_peer_alarm"
  channels_mail      = "xxx@xxx.com" # Ganti dengan alamat email Anda.
  lifecycle {
    ignore_changes = [channels_mail]
  }
}

# Buat kelompok kontak peringatan
resource "alicloud_cms_alarm_contact_group" "example_cms_alarm_contact_group" {
  alarm_contact_group_name = "example_cms_alarm_contact_group"
  contacts                 = [alicloud_cms_alarm_contact.example_cms_alarm_contact.id] # Kontak peringatan
}

# Buat aturan peringatan
resource "alicloud_cms_alarm" "example_cms_alarm" {
  name               = "example_cms_alarm_name"
  project            = "acs_vpcpeer" # Namespace data layanan cloud
  metric             = "IntranetRX"  # Nama metrik
  period             = 60            # Periode statistik
  contact_groups     = [alicloud_cms_alarm_contact_group.example_cms_alarm_contact_group.alarm_contact_group_name]
  effective_interval = "06:00-20:00" # Periode efektif
  metric_dimensions  = <<EOF
  [
    {
      "instanceId": "${var.vpc_peer_id}"
    }
  ]
  EOF
  escalations_critical {            # Peringatan level Info
    statistics          = "Sum"     # Metode statistik untuk peringatan
    comparison_operator = ">="      # Operator perbandingan untuk ambang batas
    threshold           = 104857600 # Ambang batas
    times               = 2         # Jumlah percobaan ulang untuk peringatan
  }
}

FAQ

Apakah koneksi peering lintas batas didukung?

Ya. Koneksi peering VPC mendukung skenario berikut:

Non-lintas batas: Menghubungkan dua wilayah di Tiongkok daratan, atau dua wilayah di luar Tiongkok daratan.
Lintas batas: Menghubungkan wilayah di Tiongkok daratan dengan wilayah di luar Tiongkok daratan.Pastikan akun Anda telah menyelesaikan verifikasi identitas bisnis.

Mengapa saya tidak dapat memilih VPC penerima saat membuat koneksi peering?

Pastikan Anda memilih wilayah dan akun yang benar.

Wilayah yang ditampilkan di bagian atas halaman adalah wilayah peminta, dan akun yang sedang Anda gunakan adalah akun peminta. Pastikan Anda memilih akun dan wilayah penerima yang benar saat membuat koneksi peering.

Mengapa instans ECS dengan Docker gagal setelah mengonfigurasi koneksi peering?

Jika rute dan aturan grup keamanan telah dikonfigurasi dengan benar, masalah ini biasanya disebabkan oleh konflik antara alamat kartu antarmuka jaringan Docker dan CIDR tujuan. Jalankan perintah ip addr untuk memeriksa konflik tersebut.

Jika terjadi konflik, ubah CIDR Docker agar tidak bertabrakan dengan CIDR tujuan. Ikuti langkah-langkah berikut:

Menghentikan Docker atau mengubah CIDR-nya akan mengganggu layanan. Lakukan operasi ini pada jam sepi.
Saat mengubah CIDR Docker, pastikan kompatibel dengan pengaturan jaringan semua kontainer dan aplikasi yang ada.

Jalankan sudo systemctl stop docker untuk menghentikan layanan Docker.
Jalankan sudo vim /etc/docker/daemon.json untuk mengedit dan menyimpan file konfigurasi Docker. Isi file tersebut sebagai berikut:
File konfigurasi Docker biasanya /etc/docker/daemon.json atau /etc/docker/daemon.conf. Nama file spesifiknya dapat berbeda.
```
{
    "bip":"new Docker CIDR block"
}
```
Jalankan sudo systemctl start docker untuk memulai layanan Docker dan verifikasi perubahan tersebut.

Informasi tambahan

Batasan

Anda tidak dapat membuat koneksi peering VPC jika satu VPC berada di akun Alibaba Cloud China Website (www.aliyun.com) dan yang lainnya di Alibaba Cloud International Website (www.alibabacloud.com).
Koneksi peering VPC tidak mendukung propagasi rute.
Sebagai contoh, jika VPC 2 dan VPC 3 keduanya terhubung ke VPC 1 menggunakan koneksi peering, VPC 2 dan VPC 3 tidak terhubung langsung.
Dalam VPC bersama, pemilik resource dapat membuat, mengubah, atau menghapus koneksi peering, tetapi pihak yang berwenang tidak memiliki izin tersebut.

Penagihan

Tidak ada biaya untuk koneksi peering VPC intra-wilayah, baik kedua VPC berada dalam akun yang sama maupun berbeda.

Untuk koneksi peering VPC antar-wilayah, Cloud Data Transfer (CDT) mengenakan biaya transfer data untuk lalu lintas keluar.

Harga satuan bervariasi berdasarkan wilayah dan tipe tautan.
Siklus penagihan per jam. Jika Anda mengganti tipe tautan dalam satu siklus, Anda akan dikenai tarif tier layanan yang lebih tinggi untuk seluruh jam tersebut.

Koneksi peering VPC dibuat antara VPC1 dan VPC2 yang dimiliki oleh akun berbeda di wilayah berbeda. Misalkan lalu lintas keluar adalah 200 GB dari VPC1 dan 100 GB dari VPC2. Tipe tautannya adalah Gold. Biaya transfer data antar-wilayah dari China (Hohhot) ke China (Guangzhou) adalah USD 0,072/GB. Biaya untuk kedua akun adalah:

Akun A: USD 0,072/GB × 200 GB = USD 14,4

Akun B: USD 0,072/GB × 100 GB = USD 7,2

Siklus hidup koneksi peering VPC

Setelah permintaan koneksi dikirim, koneksi peering VPC melewati tahapan berikut:

Untuk koneksi dalam akun yang sama, sistem secara otomatis menginisiasi dan menerima permintaan serta mengaktifkan koneksi tersebut.

Deskripsi status

Status	Deskripsi
Creating	Status setelah peminta mengirim permintaan koneksi.
Accepting	Status saat koneksi menunggu penerima untuk menerima.
Updating	Status setelah penerima menerima permintaan koneksi.
Activated	Status setelah peminta dan penerima mengaktifkan koneksi peering.
Rejected	Status setelah penerima menolak permintaan koneksi.
Expired	Kedaluwarsa terjadi jika penerima tidak merespons permintaan selama lebih dari tujuh hari.
Deleting	Status perantara setelah peminta atau penerima menghapus koneksi.
Deleted	Status setelah koneksi peering VPC berhasil dihapus.

Wilayah yang didukung

Area	Wilayah
Asia Pasifik - Tiongkok	China (Hangzhou), China (Shanghai), China (Nanjing - Local Region, Closing Down), China (Qingdao), China (Beijing), China (Zhangjiakou), China (Hohhot), China (Ulanqab), China (Shenzhen), China (Heyuan), China (Guangzhou), China (Chengdu), China (Hong Kong), China (Wuhan - Local Region), dan China (Fuzhou - Local Region, Closing Down)
Asia Pasifik - Lainnya	Jepang (Tokyo), Korea Selatan (Seoul), Singapura, Malaysia (Kuala Lumpur), Indonesia (Jakarta), Filipina (Manila), dan Thailand (Bangkok)
Eropa & Amerika	Jerman (Frankfurt), Inggris (London), AS (Silicon Valley), dan AS (Virginia)
Timur Tengah	UEA (Dubai) dan SAU (Riyadh - Partner Region)

Kuota

Nama kuota	Deskripsi	Kuota default	Tingkatkan kuota
vpc_quota_cross_region_peer_num_per_vpc	Jumlah koneksi peering VPC antar-wilayah yang dapat dimiliki oleh satu VPC.	20	Buka halaman Manajemen Kuota atau Quota Center untuk mengajukan peningkatan kuota.
vpc_quota_intra_region_peer_num_per_vpc	Jumlah koneksi peering VPC intra-wilayah yang dapat dimiliki oleh satu VPC.	10
vpc_quota_peer_num	Jumlah koneksi peering VPC yang dapat dibuat oleh satu Akun Alibaba Cloud di suatu wilayah.	20
vpc_quota_peer_cross_border_bandwidth	Bandwidth lintas batas maksimum.	1.024 Mbps
vpc_quota_peer_cross_region_bandwidth	Bandwidth antar-wilayah maksimum.	1.024 Mbps