Elastic Compute Service:Referensi Terraform

Fitur dasar Terraform

Terraform adalah alat otomatisasi dan orkestrasi infrastruktur TI yang memungkinkan Anda mengelola dan memelihara sumber daya TI melalui kode. Untuk informasi selengkapnya, lihat Apa itu Terraform?.

• Antarmuka baris perintah (CLI) Terraform menyediakan cara sederhana untuk menyebarkan file konfigurasi ke Alibaba Cloud atau cloud lain yang didukung serta mengelola versinya. Anda dapat mendefinisikan infrastruktur Anda—seperti virtual machine, akun penyimpanan, dan antarmuka jaringan—dalam file konfigurasi yang menggambarkan topologi sumber daya cloud Anda.

• Terraform mendukung infrastruktur baru melalui provider, sehingga memungkinkan Anda dengan mudah mendefinisikan, meninjau, dan menyebarkan infrastruktur cloud di Alibaba Cloud menggunakan bahasa templat sederhana.

• Anda dapat menggunakan Terraform untuk membuat, mengubah, dan menghapus sumber daya dari berbagai layanan Alibaba Cloud.

Untuk informasi selengkapnya tentang integrasi Alibaba Cloud dan Terraform, lihat Alibaba Cloud Provider.

Menginstal Terraform

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Autentikasi Terraform

Anda dapat mengautentikasi Terraform dengan menyimpan kredensial akses dalam variabel lingkungan. Saat menjalankan perintah Terraform, alat ini akan mencoba mengambil kredensial dari variabel tersebut jika tidak dideklarasikan secara eksplisit dalam templat konfigurasi. Bagian berikut menjelaskan cara mengatur variabel lingkungan tersebut.

# ID AccessKey
$ export ALICLOUD_ACCESS_KEY="<your AccessKey ID>"
# Rahasia AccessKey
$ export ALICLOUD_SECRET_KEY="<your AccessKey secret>"
# Jika Anda menggunakan kredensial STS, Anda harus mengonfigurasi security_token.
$ export ALICLOUD_SECURITY_TOKEN="<your access token>"

Setelah mengatur variabel lingkungan, Anda tidak perlu mendeklarasikan kredensial dalam blok provider. Cukup deklarasikan wilayah saja.

provider "alicloud" {
  region = "cn-hangzhou"
}

Anda juga dapat mengonfigurasi wilayah menggunakan variabel lingkungan ALICLOUD_REGION. Jika wilayah tidak dideklarasikan secara eksplisit dan variabel lingkungan ini tidak diatur, nilai default-nya adalah cn-beijing.

Sumber daya yang didukung

Menggunakan Terraform untuk membuat dan mengelola sumber daya ECS

Bagian ini memberikan contoh cara membuat dan mengelola sumber daya ECS dengan Terraform.

1. Buat direktori kerja. Di dalam direktori tersebut, buat file konfigurasi bernama main.tf. Kode berikut membuat instance ECS beserta sumber daya VPC, grup keamanan, dan vSwitch yang diperlukan. Salin kode tersebut ke file main.tf.

   # Mendefinisikan variabel "region" dengan nilai default "cn-beijing" untuk menentukan wilayah Alibaba Cloud.
   variable "region"{
     default = "cn-beijing"
   }
   
   # Mengonfigurasi provider Alibaba Cloud untuk menggunakan wilayah yang ditentukan dalam variabel "region".
   provider "alicloud"{
     region = var.region
   }
   
   # Mendefinisikan variabel string "instance_type" dengan nilai default "ecs.e-c1m1.large" untuk menentukan tipe instance ECS.
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # Menggunakan sumber data untuk mengkueri informasi zona. Memfilter hasil berdasarkan tipe instance, tipe pembuatan sumber daya (seperti VSwitch), dan kategori disk.
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # Mendefinisikan variabel "vpc_cidr_block" dengan nilai default "172.16.0.0/16" untuk menentukan blok CIDR untuk VPC.
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # Mendefinisikan variabel "vsw_cidr_block" dengan nilai default "172.16.0.0/24" untuk menentukan blok CIDR untuk vSwitch.
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # Menghasilkan bilangan bulat acak antara 10000 dan 99999 untuk memastikan keunikan nama beberapa sumber daya.
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # Membuat VPC bernama "vpc-test" dan menggunakan bilangan bulat acak untuk memastikan nama unik.
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # Membuat grup keamanan, menyertakan bilangan bulat acak dalam nama untuk memastikan keunikan, dan mengaitkannya dengan VPC yang dibuat di atas.
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # Nama bidang di sini telah diganti.
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # Membuat aturan grup keamanan untuk mengizinkan semua trafik TCP inbound dan mengaitkannya dengan grup keamanan yang dibuat sebelumnya.
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # Diubah di sini, nic_type diubah menjadi 'intranet'.
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # Membuat vSwitch, menyertakan bilangan bulat acak dalam nama untuk memastikan keunikan, dan mengaitkannya dengan VPC dan zona.
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # Membuat instance ECS. Mengatur beberapa parameter seperti zona, grup keamanan, dan tipe instans. Menggunakan bilangan bulat acak untuk memastikan nama instans unik.
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # Ubah kata sandi sesuai kebutuhan Anda.
   }

2. Jalankan perintah berikut untuk menginisialisasi lingkungan runtime Terraform.

   terraform init

   Output berikut menunjukkan bahwa Terraform berhasil diinisialisasi.

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. Jalankan perintah berikut untuk mengeksekusi kode.

   terraform apply

   Saat eksekusi, masukkan yes saat diminta dan tekan Enter. Tunggu hingga perintah selesai. Jika output berikut muncul, kode berhasil dieksekusi.

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. Verifikasi hasilnya

terraform show

Referensi

• Untuk tutorial lainnya, lihat Tutorial Terraform.

• Untuk informasi selengkapnya tentang perintah Terraform umum, lihat Perintah Umum.

• Terraform tersedia sebagai layanan terkelola di ROS. Anda dapat menyebarkan templat Terraform di Konsol ROS. Untuk informasi selengkapnya, lihat Membuat tumpukan Terraform.