All Products
Search

This Product

    Cloud Enterprise Network:Mengisolasi VPC dan mengakses layanan bersama

    Document Center

    Cloud Enterprise Network:Mengisolasi VPC dan mengakses layanan bersama

    Last Updated:Aug 29, 2026

    Cloud Enterprise Network (CEN) mendukung kebijakan konektivitas, isolasi, dan pengalihan lalu lintas yang fleksibel dalam satu wilayah. Tutorial ini menjelaskan cara mengizinkan VPC yang terisolasi untuk mengakses VPC layanan bersama sekaligus tetap saling terisolasi satu sama lain.

    Latar Belakang

    Sebuah perusahaan memiliki tiga VPC yang diterapkan di wilayah China (Hangzhou). VPC3 menyediakan layanan bersama. Tujuannya adalah memungkinkan VPC1 dan VPC2 mengakses VPC3 sekaligus menjaga agar VPC1 dan VPC2 tetap terisolasi satu sama lain.

    Perencanaan jaringan

    Gunakan tabel rute kustom CEN, asosiasi tabel rute, dan pembelajaran rute untuk mengonfigurasi segmen jaringan dan routing sebagai berikut:

    Dalam contoh ini, ketiga VPC dan router transit berada dalam satu Akun Alibaba Cloud yang sama. Untuk penerapan lintas akun, lihat bagian "Isolasi rute VPC lintas akun".

    • Saat menyambungkan VPC3 ke router transit, aktifkan pengaturan lanjutan Associate with Default Route Table of Transit Router dan Propagate system routes to transit router route table.

      Tabel rute sistem router transit kemudian secara otomatis mempelajari rute VPC3, dan VPC3 meneruskan lalu lintas melalui tabel rute sistem ini.

    • Saat menyambungkan VPC1 dan VPC2 ke router transit, aktifkan hanya pengaturan lanjutan Propagate system routes to transit router route table. Lalu, asosiasikan VPC1 dan VPC2 dengan tabel rute kustom pada router transit dan tambahkan entri rute kustom yang mengarah ke VPC3.

      Tabel rute sistem router transit mempelajari rute dari VPC1 dan VPC2. VPC1 dan VPC2 meneruskan lalu lintas ke VPC3 melalui tabel rute kustom, sehingga mencegah komunikasi langsung antara VPC1 dan VPC2.

    • Tambahkan rute ke 0.0.0.0/0 pada tabel rute VPC1, VPC2, dan VPC3. Tetapkan lompatan berikutnya untuk rute ini ke router transit.

    • Tabel berikut merinci paket jaringan untuk VPC tersebut.

      Penting

      Saat merancang jaringan Anda, pastikan Blok CIDR VPC tidak tumpang tindih.

      VPC

      vSwitch

      Zona vSwitch

      Blok CIDR

      ECS

      VPC1

      Blok CIDR primer: 192.168.0.0/16

      vSwitch1

      Zona A

      192.168.0.0/24

      Alamat ECS1:

      192.168.0.224

      vSwitch2

      Zona B

      192.168.1.0/24

      VPC2

      Blok CIDR primer: 172.16.0.0/16

      vSwitch3

      Zona A

      172.16.0.0/24

      Alamat ECS2:

      172.16.0.222

      vSwitch4

      Zona B

      172.16.1.0/24

      VPC3

      Blok CIDR primer: 10.0.0.0/16

      vSwitch5

      Zona A

      10.0.0.0/24

      Alamat ECS3:

      10.0.0.112

      vSwitch6

      Zona B

      10.0.1.0/24

    Prosedur

    Anda dapat menyelesaikan tutorial ini menggunakan Konsol Alibaba Cloud atau Terraform.

    Konsol

    Langkah 1: Buat instans CEN

    Buat instans CEN sebelum menyambungkan instans jaringan Anda.

    1. Login ke Konsol CEN.

    2. Pada halaman CEN Instance, klik Create CEN Instance.

    3. Pada kotak dialog Create CEN Instance, konfigurasikan parameter berikut lalu klik OK.

      • Name: Masukkan nama untuk instans CEN.

      • Description: Masukkan deskripsi untuk instans CEN.

    Langkah 2: Buat koneksi VPC

    1. Pada halaman CEN Instance, klik ID instans CEN Anda.

    2. Pada tab Basic Settings, di bagian VPC, klik ikon 添加网络实例.

    3. Pada halaman Connection with Peer Network Instance, konfigurasikan parameter berikut lalu klik OK.

      • Instance Type: VPC dipilih secara default.

      • Region: Pilih wilayah tempat instans jaringan diterapkan. Dalam contoh ini, China (Hangzhou) dipilih.

      • Transit Router: Sistem secara otomatis membuat router transit di wilayah yang dipilih.

      • Account: Pilih jenis akun pemilik instans jaringan. Dalam contoh ini, nilai default Your Account digunakan.

      • Metode penagihan: Nilai default adalah pay-as-you-go.

      • Connection Name: Masukkan nama untuk koneksi.

      • Networks: Pilih ID VPC yang ingin disambungkan. Dalam contoh ini, VPC3 dipilih.

      • vSwitch: Pilih instans vSwitch di zona yang didukung oleh router transit.

        Untuk wilayah single-zone, pilih satu vSwitch. Untuk wilayah multi-zona, pilih minimal dua vSwitch di zona berbeda. Untuk mengurangi latensi, pilih satu vSwitch per zona.

      • Advanced Settings: Dalam contoh ini, untuk VPC3, aktifkan hanya Associate with Default Route Table of Transit Router dan Propagate system routes to transit router route table.

        Tiga opsi diaktifkan secara default: Associate with default route table of transit router (mengasosiasikan koneksi VPC dengan tabel rute default router transit), Propagate system routes to default route table of transit router (mengiklankan rute sistem VPC ke router transit, memungkinkan komunikasi dengan instans jaringan terlampir lainnya), dan Automatically create route that points to transit router and add to all route tables of current VPC (menambahkan tiga rute — 10.0.0.0/8, 172.16.0.0/12, 192.168.0.0/16 — ke semua tabel rute VPC, dengan lompatan berikutnya mengarah ke router transit; secara default, router transit tidak mengiklankan rute ke VPC). Untuk menyesuaikan routing, kosongkan centang ini dan konfigurasikan asosiasi serta propagasi rute secara manual. Lihat Kelola rute.

        Catatan

        Untuk lalu lintas IPv6, setelah membuat koneksi VPC, aktifkan sinkronisasi rute atau tambahkan entri rute IPv6 secara manual yang mengarah ke koneksi VPC di dalam VPC.

    4. Setelah koneksi untuk VPC3 dibuat, klik Create More Connections.

      Ulangi langkah 3 untuk membuat koneksi bagi VPC1 dan VPC2. Saat membuat koneksi untuk VPC1 dan VPC2, pilih hanya pengaturan lanjutan Propagate system routes to transit router route table.

    5. Setelah koneksi VPC dibuat, klik Return to the List untuk kembali ke halaman detail instans.

    Langkah 3: Asosiasikan VPC dengan tabel rute kustom

    1. Pada halaman detail instans, temukan router transit yang telah Anda buat lalu klik ID-nya.

    2. Pada halaman detail router transit, klik tab Route Table.

    3. Di panel kiri tab tersebut, klik Create Route Table.

    4. Pada kotak dialog Create Route Table, konfigurasikan parameter berikut lalu klik OK.

      • Transit Router: Sistem secara otomatis memilih router transit di wilayah saat ini.

      • Name: Masukkan nama untuk tabel rute.

      • Description: Masukkan deskripsi untuk tabel rute.

      • Multi-region ECMP Routing: Pertahankan nilai default.

    5. Klik View Route Table Details untuk kembali ke tab Route Table.

    6. Pada tab Route Table, pilih tabel rute kustom yang baru saja Anda buat, klik tab Route Table Association, lalu klik Create Association.

    7. Pada kotak dialog Add Association, pilih koneksi instans jaringan yang akan diasosiasikan dengan tabel rute kustom ini, lalu klik OK.

      Setelah asosiasi dibuat, VPC1 dan VPC2 meneruskan lalu lintas dengan mencari di tabel rute ini.

    8. Pada halaman detail tabel rute kustom, klik tab Route Entry, lalu klik Add Route Entry.

    9. Pada kotak dialog Add Route Entry, konfigurasikan parameter berikut lalu klik OK.

      • Route Table: Sistem secara otomatis memilih tabel rute kustom saat ini.

      • Transit Router ID: Sistem secara otomatis memilih router transit di wilayah saat ini.

      • Name: Masukkan nama untuk entri rute.

      • Destination CIDR: Masukkan blok CIDR tujuan untuk rute. Dalam contoh ini, masukkan 10.0.0.0/16.

      • Blackhole Route: Jika Anda memilih opsi ini, seluruh lalu lintas yang ditujukan ke rute ini akan dibuang. Dalam contoh ini, pilih No.

      • Next Hop: Pilih lompatan berikutnya untuk rute. Dalam contoh ini, pilih koneksi VPC3.

      • Description: Masukkan deskripsi untuk entri rute.

    Langkah 4: Tambahkan rute default ke setiap VPC

    Di Konsol VPC, tambahkan rute dengan tujuan 0.0.0.0/0 ke tabel rute VPC1, VPC2, dan VPC3. Tetapkan lompatan berikutnya untuk rute tersebut ke router transit.

    1. Login ke Konsol VPC.

    2. Di panel navigasi kiri, klik Route Table.

    3. Di bilah navigasi atas, pilih wilayah tempat tabel rute berada.

    4. Pada halaman Route Table, temukan tabel rute target lalu klik ID-nya.

      Dalam contoh ini, pilih tabel rute untuk VPC3.

    5. Pada halaman detail tabel rute, di tab Route Entry List, klik Custom Route, lalu klik Add Route Entry.

    6. Pada panel Add Route Entry, konfigurasikan parameter berikut lalu klik OK.

      • Name: Masukkan nama untuk entri rute.

      • Destination CIDR Block: Masukkan blok CIDR tujuan. Dalam contoh ini, masukkan 0.0.0.0/0.

      • Next Hop Type: Pilih jenis lompatan berikutnya. Dalam contoh ini, pilih Transit Router.

      • Transit Router: Pilih koneksi instans jaringan. Dalam contoh ini, pilih koneksi VPC3.

      Untuk informasi lebih lanjut tentang parameter, lihat Kelola lalu lintas jaringan menggunakan tabel rute kustom.

    7. Ulangi langkah 4 hingga langkah 6 untuk menambahkan rute dengan tujuan 0.0.0.0/0 dan lompatan berikutnya mengarah ke router transit untuk VPC1 dan VPC2.

      Anda dapat melihat informasi routing untuk VPC1, VPC2, VPC3, dan tabel rute router transit pada halaman detail router transit di Konsol CEN.

      1. Pada halaman detail router transit, klik Network Instance Route Table untuk melihat rute untuk VPC1, VPC2, dan VPC3.

        1. Pada halaman detail router transit, klik Network Instance Route Table.

        2. Dari daftar drop-down Networks, pilih ID VPC1, VPC2, atau VPC3 untuk melihat rutenya.

          Gambar 1. Rute VPC1

          image

          Gambar 2. Rute VPC2

          image

          Gambar 3. Rute VPC3

          image

      2. Pada tab Route Table, Anda dapat melihat rute yang telah dipelajari oleh tabel rute sistem router transit dari VPC1, VPC2, dan VPC3.

        1. Pada halaman detail router transit, klik Route Table.

        2. Pada tab Route Table, lihat entri rute dalam tabel rute tersebut.

          Gambar 4. Tabel rute sistem

          image

          Gambar 5. Tabel rute kustom

          image

    Langkah 5: Uji konektivitas jaringan

    Uji konektivitas antara VPC1, VPC2, dan VPC3.

    Catatan

    Sebelum memulai, verifikasi bahwa aturan grup keamanan untuk Instance ECS di VPC1, VPC2, dan VPC3 mengizinkan komunikasi antar instans. Untuk informasi lebih lanjut, lihat Lihat aturan grup keamanan.

    1. Login ke Instance ECS di VPC1. Untuk informasi lebih lanjut, lihat Metode koneksi untuk Instance ECS.

    2. Jalankan perintah ping untuk ping alamat IP Instance ECS di VPC3 dan uji konektivitas antara VPC1 dan VPC3.

      Output mengonfirmasi bahwa VPC1 dan VPC3 dapat berkomunikasi.共享VPC-VPC1-VPC3

    3. Login ke Instance ECS di VPC2 dan gunakan perintah ping untuk ping alamat IP Instance ECS di VPC3 guna menguji konektivitas antara VPC2 dan VPC3.

      Output mengonfirmasi bahwa VPC2 dan VPC3 dapat berkomunikasi.共享VPC-VPC2-VPC3

    4. Login ke Instance ECS di VPC1 dan gunakan perintah ping untuk ping alamat IP Instance ECS di VPC2 guna menguji konektivitas antara VPC1 dan VPC2.

      Output mengonfirmasi bahwa VPC1 dan VPC2 tidak dapat berkomunikasi.共享VPC-VPC1-VPC2

    Isolasi rute VPC lintas akun

    Mekanisme routing dan isolasi yang dijelaskan dalam tutorial ini berlaku identik untuk penerapan lintas akun. Isolasi tetap dicapai dengan hanya mengaktifkan pembelajaran rute (Propagate system routes to transit router route table) untuk VPC1 dan VPC2, mengasosiasikannya dengan tabel rute kustom, dan menambahkan rute kustom ke VPC3 dalam tabel rute tersebut. Mekanisme ini tidak bergantung pada Akun Alibaba Cloud mana yang dimiliki oleh VPC.

    Prasyarat: Sebelum membuat koneksi VPC lintas akun, akun pemilik VPC harus memberikan otorisasi kepada akun pemilik router transit. Untuk petunjuknya, lihat Otorisasi lintas akun untuk instans jaringan.

    Perbedaan konfigurasi: Di Langkah 2: Buat koneksi VPC, untuk bidang Account, pilih Different Account alih-alih Your Account, dan masukkan ID akun utama Akun Alibaba Cloud pemilik VPC. Semua item konfigurasi lainnya sama seperti skenario satu akun. Untuk detail parameter, lihat Buat koneksi VPC.

    Kepemilikan operasi: Langkah 1 hingga Langkah 3 (membuat instans CEN, router transit, koneksi VPC, dan tabel rute kustom beserta entri rutanya) semuanya dilakukan di akun pemilik router transit. Langkah 4: Tambahkan rute default ke setiap VPC harus dilakukan oleh masing-masing pemilik VPC, di Konsol VPC milik akun tersebut.

    Isolasi VPC lintas akun menggunakan peta rute

    Setelah VPC lintas akun disambungkan ke CEN, VPC tersebut terhubung penuh ke semua instans VPC lainnya pada router transit secara default. Untuk mengisolasi VPC lintas akun dari instans VPC tertentu secara selektif, konfigurasikan peta rute pada tabel rute router transit alih-alih menggunakan metode tabel rute kustom dan asosiasi tabel rute yang dijelaskan sebelumnya dalam topik ini. Mekanisme ini independen dari isolasi berbasis tabel rute kustom yang dijelaskan di Isolasi rute VPC lintas akun: isolasi ini dicapai dengan memfilter pengumuman rute di lapisan kontrol, bukan dengan mengubah tabel rute yang digunakan oleh lampiran VPC.

    Cara kerja: Peta rute mengontrol rute mana yang diiklankan oleh router transit ke lampiran VPC tertentu. Saat Anda membuat peta rute Deny yang cocok dengan lalu lintas antara dua lampiran VPC, router transit berhenti mengiklankan rute yang sesuai, sehingga kedua instans VPC tidak dapat lagi saling menjangkau, meskipun tabel rute dasarnya tidak diubah.

    Sebelum memulai: Peta rute hanya berlaku untuk pengumuman rute yang terjadi setelah peta rute dibuat. Jika entri rute yang memungkinkan komunikasi antara kedua instans VPC sudah ada di tabel rute, hapus entri rute tersebut terlebih dahulu. Jika tidak, rute yang ada tetap berfungsi dan isolasi tidak berlaku.

    Untuk mengonfigurasi peta rute deny:

    1. Buat peta rute pada tabel rute router transit dengan pengaturan berikut:

      • Action: Deny.

      • Priority: 20. Nilai lebih rendah menunjukkan prioritas lebih tinggi.

      • Direction: Egress from the regional gateway (peta rute memfilter rute saat diiklankan keluar dari wilayah).

      • Source instance IDs: ID lampiran VPC lintas akun, misalnya, vpc-xxx.

      • Destination instance IDs: ID lampiran VPC yang ingin diisolasi dari VPC sumber, misalnya, vpc-yyy.

      Catatan

      Dalam beberapa kasus, daftar drop-down Source instance IDs pada halaman pembuatan peta rute di konsol tidak menampilkan opsi yang dapat dipilih, meskipun koneksi VPC telah diasosiasikan dengan tabel rute melalui asosiasi tabel rute. Jika hal ini terjadi, panggil operasi CreateCenRouteMap sebagai gantinya, dan masukkan ID instans VPC dalam format vpc-xxx untuk membuat peta rute.

    2. Setelah peta rute berlaku, login ke Instance ECS di VPC sumber dan jalankan perintah ping untuk menguji konektivitas ke Instance ECS di VPC yang diisolasi. Perintah ping seharusnya gagal (kehilangan paket 100%), yang mengonfirmasi bahwa isolasi peta rute berlaku.

    Terraform

    Anda dapat menggunakan Terraform untuk membangun lingkungan tutorial ini. Untuk petunjuk instalasi dan konfigurasi Terraform, lihat Instal Terraform.

    Prosedur berikut menjelaskan cara menjalankan Terraform v1.9.8 pada host Linux. Sebelum memulai, pastikan Anda telah mengonfigurasi Otentikasi.

    Catatan

    Beberapa resource dalam tutorial ini dikenai biaya. Untuk menghindari tagihan tak terduga, lepas resource tersebut saat tidak lagi diperlukan.

    Langkah 1: Buat resource

    Kode berikut mendefinisikan semua resource untuk skenario ini. Simpan sebagai file .tf di direktori baru.

    variable "pname" {
  description = "The prefix name for the resources"
  type        = string
  default     = "tf-CenSharedVpc"
}

variable "default_region" {
  description = "Default region"
  type        = string
  default     = "cn-hangzhou"
}

variable "az_list" {
  description = "List of availability zones to use"
  type        = list(string)
  default     = ["cn-hangzhou-j", "cn-hangzhou-k"]
}

variable "vpc_cidr_list" {
  description = "List of VPC CIDR block"
  type        = list(string)
  default     = ["192.168.0.0/16", "172.16.0.0/16", "10.0.0.0/16"]
}

variable "vsw_cidr_list" {
  description = "List of VSW CIDR block"
  type        = list(string)
  default = [
    "192.168.0.0/24", "192.168.1.0/24",
    "172.16.0.0/24", "172.16.1.0/24",
    "10.0.0.0/24", "10.0.1.0/24"
  ]
}

variable "ecs_ip_list" {
  description = "List of ECS ip"
  type        = list(string)
  default     = ["192.168.0.124", "172.16.0.222", "10.0.0.112"]
}

provider "alicloud" {
  region = var.default_region
}

# --- 3vpc 6vsw 3ecs
resource "alicloud_vpc" "vpc" {
  count      = length(var.vpc_cidr_list)
  vpc_name   = "${var.pname}-vpc${count.index + 1}"
  cidr_block = var.vpc_cidr_list[count.index]
}

resource "alicloud_vswitch" "vsw" {
  count        = length(var.vsw_cidr_list)
  vpc_id       = alicloud_vpc.vpc[floor(count.index / length(var.az_list))].id
  cidr_block   = var.vsw_cidr_list[count.index]
  zone_id      = var.az_list[count.index % length(var.az_list)]
  vswitch_name = "${var.pname}-vsw${count.index + 1}"
}

resource "alicloud_instance" "ecs" {
  count                = length(var.vpc_cidr_list)
  instance_name        = "${var.pname}-ecs${count.index + 1}"
  instance_type        = "ecs.e-c1m1.large"
  security_groups      = [alicloud_security_group.sg[count.index].id]
  vswitch_id           = alicloud_vswitch.vsw[count.index * length(var.az_list)].id
  image_id             = "aliyun_3_x64_20G_qboot_alibase_20230727.vhd"
  system_disk_category = "cloud_essd"
  private_ip           = var.ecs_ip_list[count.index]
  instance_charge_type = "PostPaid"
}

# --- 3 sg
resource "alicloud_security_group" "sg" {
  count  = length(var.vpc_cidr_list)
  name   = "${var.pname}-${count.index + 1}"
  vpc_id = alicloud_vpc.vpc[count.index].id
}

resource "alicloud_security_group_rule" "allow_inbound_ssh" {
  count             = length(var.vpc_cidr_list)
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "22/22"
  priority          = 1
  security_group_id = alicloud_security_group.sg[count.index].id
  cidr_ip           = "0.0.0.0/0"
}

resource "alicloud_security_group_rule" "allow_inbound_icmp" {
  count             = length(var.vpc_cidr_list)
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.sg[count.index].id
  cidr_ip           = "0.0.0.0/0"
}

# --- cen and tr
resource "alicloud_cen_instance" "cen" {
  cen_instance_name = "${var.pname}-cen1"
}
resource "alicloud_cen_transit_router" "tr" {
  transit_router_name = "${var.pname}-tr"
  cen_id              = alicloud_cen_instance.cen.id
}
data "alicloud_cen_transit_router_route_tables" "tr" { # get tr sys table
  transit_router_id               = alicloud_cen_transit_router.tr.transit_router_id
  transit_router_route_table_type = "System"
}

# 3 attach
resource "alicloud_cen_transit_router_vpc_attachment" "attach" {
  count             = length(var.vpc_cidr_list)
  cen_id            = alicloud_cen_instance.cen.id
  transit_router_id = alicloud_cen_transit_router.tr.transit_router_id
  vpc_id            = alicloud_vpc.vpc[count.index].id
  zone_mappings {
    zone_id    = var.az_list[0]
    vswitch_id = alicloud_vswitch.vsw[count.index * length(var.az_list)].id
  }
  zone_mappings {
    zone_id    = var.az_list[1]
    vswitch_id = alicloud_vswitch.vsw[count.index * length(var.az_list) + 1].id
  }
  transit_router_vpc_attachment_name = "attach${count.index + 1}"
}

# 3 propa
resource "alicloud_cen_transit_router_route_table_propagation" "propa" {
  count                         = length(var.vpc_cidr_list)
  transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr.tables[0].id
  transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach[count.index].transit_router_attachment_id
}

# 1 custom_table
resource "alicloud_cen_transit_router_route_table" "custom_table" { # create tr custom_table
  transit_router_id               = alicloud_cen_transit_router.tr.transit_router_id
  transit_router_route_table_name = "custom_table"
}

resource "alicloud_cen_transit_router_route_entry" "tr_entry" {
  transit_router_route_table_id                     = alicloud_cen_transit_router_route_table.custom_table.transit_router_route_table_id
  transit_router_route_entry_destination_cidr_block = "10.0.0.0/16"
  transit_router_route_entry_next_hop_type          = "Attachment"
  transit_router_route_entry_name                   = "entry1_name"
  transit_router_route_entry_description            = "entry1_desc"
  transit_router_route_entry_next_hop_id            = alicloud_cen_transit_router_vpc_attachment.attach[2].transit_router_attachment_id
}

# associate attach1\2   custom_table
resource "alicloud_cen_transit_router_route_table_association" "ass1" {
  transit_router_route_table_id = alicloud_cen_transit_router_route_table.custom_table.transit_router_route_table_id
  transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach[0].transit_router_attachment_id
}
resource "alicloud_cen_transit_router_route_table_association" "ass2" {
  transit_router_route_table_id = alicloud_cen_transit_router_route_table.custom_table.transit_router_route_table_id
  transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach[1].transit_router_attachment_id
}
# ass attach3 sys_table
resource "alicloud_cen_transit_router_route_table_association" "ass3" {
  transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr.tables[0].id
  transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach[2].transit_router_attachment_id
}

# vpc entry
resource "alicloud_route_entry" "vpc_entry" {
  count                 = length(var.vpc_cidr_list)
  route_table_id        = alicloud_vpc.vpc[count.index].route_table_id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Attachment"
  nexthop_id            = alicloud_cen_transit_router_vpc_attachment.attach[count.index].transit_router_attachment_id
}

output "ecs1_login_address" {
  value = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=${var.default_region}&instanceId=${alicloud_instance.ecs[0].id}"
}

output "ecs2_login_address" {
  value = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=${var.default_region}&instanceId=${alicloud_instance.ecs[1].id}"
}

output "ecs3_login_address" {
  value = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=${var.default_region}&instanceId=${alicloud_instance.ecs[2].id}"
}

    Langkah 2: Uji konektivitas jaringan

    Ikuti langkah-langkah berikut untuk menguji konektivitas antara VPC1, VPC2, dan VPC3.

    1. Login ke Instance ECS1 di VPC1 (nama instans: tf-CenSharedVpc-ecs1).

      Temukan URL login untuk ECS1 di output Terraform. Buka URL tersebut di browser Anda dan gunakan autentikasi Temporary SSH Key-based.

      image

    2. Jalankan perintah ping dan ping alamat IP Instance ECS3 di VPC3 untuk menguji konektivitas antara VPC1 dan VPC3.

      ping 10.0.0.112

      Output mengonfirmasi bahwa VPC1 dan VPC3 dapat berkomunikasi.共享VPC-VPC1-VPC3

    3. Login ke Instance ECS2 (tf-CenSharedVpc-ecs2) di VPC2 dan jalankan perintah ping untuk ping alamat IP Instance ECS3 di VPC3 guna menguji konektivitas antara VPC2 dan VPC3.

      ping 10.0.0.112

      Output mengonfirmasi bahwa VPC2 dan VPC3 dapat berkomunikasi.共享VPC-VPC2-VPC3

    4. Login ke Instance ECS1 (tf-CenSharedVpc-ecs1) di VPC1. Gunakan perintah ping untuk ping alamat IP Instance ECS2 di VPC2 guna menguji konektivitas antara VPC1 dan VPC2.

      ping 172.16.0.222

      Output mengonfirmasi bahwa VPC1 dan VPC2 tidak dapat berkomunikasi.共享VPC-VPC1-VPC2

    Langkah 3: Bersihkan resource

    Setelah verifikasi, jalankan perintah berikut untuk melepas resource.

    terraform destroy --auto-approve