CDN：Fungsi string

Fitur

Deskripsi

Sintaks

substr(s, i, j)

Deskripsi

Mengekstrak bagian dari sebuah string.

Parameter

• s: string sumber.

• i: posisi untuk memulai ekstraksi dalam string sumber, dihitung dari 1. Nilai -1 menentukan karakter paling kanan dari string. Tipe data: integer.

• j: posisi untuk mengakhiri ekstraksi dalam string sumber, dihitung dari 1. Nilai -1 menentukan karakter paling kanan dari string. Tipe data: integer.

Nilai kembali

Mengembalikan substring s[i, j] yang diekstrak dari string sumber yang ditentukan oleh s.

Contoh

//Catatan: Dua metode yang digunakan untuk menentukan apakah file adalah file M3U8.
if eq(substr($uri, -5, -1), '.m3u8') {
    say(concat($uri, ' adalah .m3u8'))
}

uri_len = len($uri)
if eq(substr($uri, -5, uri_len), '.m3u8') {
    say(concat($uri, ' adalah .m3u8'))
}

Fitur

Deskripsi

Sintaks

concat(s1, ...)

Deskripsi

Menggabungkan string.

Parameter

String yang ingin Anda gabungkan. Anda dapat menentukan satu atau lebih string. Nilai numerik didukung.

Nilai kembali

Mengembalikan string yang telah digabungkan.

Contoh

// Menggabungkan string-string berikut
str1 = 'hello'
str2 = ' '
str3 = 'world'
say(concat(str1, str2, str3))

Output:

  hello world

Fitur

Deskripsi

Sintaks

upper(s)

Deskripsi

Mengonversi string menjadi huruf besar.

Parameter

s: string yang ingin Anda konversi.

Nilai kembali

Mengembalikan string yang ditentukan oleh parameter s dalam huruf besar.

Contoh

str = 'hello world'                                                                                                                                                                                   
say(upper(str)) 

Output:

HELLO WORLD

Fitur

Deskripsi

Sintaks

lower(s)

Deskripsi

Mengonversi string menjadi huruf kecil.

Parameter

s: string yang ingin Anda konversi.

Nilai kembali

Mengembalikan string yang ditentukan oleh parameter s dalam huruf kecil.

Contoh

str = 'HELLO WORLD'
say(lower(str))

Output:

hello world

Fitur

Deskripsi

Sintaks

len(s)

Deskripsi

Memeriksa panjang string.

Parameter

s: string yang ingin Anda ukur.

Nilai kembali

Mengembalikan panjang string yang ditentukan oleh parameter s. Tipe data: integer.

Contoh

str = 'hello world'
say(len(str)) // Mengembalikan panjang str. Di sini adalah 11.

Fitur

Deskripsi

Sintaks

byte(c)

Deskripsi

Memeriksa nilai ASCII dari sebuah karakter.

Parameter

c: karakter yang nilainya ASCII ingin Anda periksa. Anda hanya dapat menentukan satu karakter.

Nilai kembali

Mengembalikan nilai ASCII dari karakter yang ditentukan. Tipe data: numerik.

Contoh

say(byte('a'))
say(byte('A'))

Output:

97
65

Fitur

Deskripsi

Sintaks

match_re(s, p [, o])

Deskripsi

Menggunakan mesin Perl Compatible Regular Expressions (PCRE) untuk pencocokan ekspresi reguler. Untuk informasi lebih lanjut, lihat Sintaks PCRE.

Parameter

• s: string yang ingin Anda cocokkan. Tipe data: string.

• p: ekspresi reguler untuk pencocokan. Tipe data: string.

• o: mesin ekspresi reguler. Tipe data: string. Parameter ini opsional.

  • nilai kosong: menentukan bahwa fungsi ini peka terhadap huruf besar/kecil.

  • i: menentukan bahwa fungsi ini tidak peka terhadap huruf besar/kecil.

Nilai kembali

Jika string cocok dengan ekspresi reguler, true dikembalikan. Jika tidak, false dikembalikan.

Contoh

str = 'Hello'
// Pencocokan tepat dengan "Hello"
say(match_re(str, 'Hello'))
// Pencocokan tanpa memperhatikan huruf besar/kecil dengan "Hello" 
say(match_re(str, 'hello', i))
// Cocok dengan string apa pun yang berakhir dengan huruf "l"
say(match_re(str, '.*l$'))

Output:

true
true
false

Fitur

Deskripsi

Sintaks

capture_re(s, p [,init])

Deskripsi

Menangkap kecocokan dari string dan mengembalikan substring yang cocok. Untuk informasi lebih lanjut tentang PCRE, lihat Sintaks PCRE.

Parameter

• s: string yang ingin Anda cocokkan. Tipe data: string.

• p: ekspresi reguler untuk pencocokan. Tipe data: string.

• init: posisi untuk memulai pencocokan, dihitung dari 1. Tipe data: integer.

Nilai kembali

Mengembalikan substring yang cocok dalam tipe kamus jika string cocok dengan ekspresi reguler. Jika tidak, kamus kosong dikembalikan.

Contoh

pcs = capture_re($request_uri,'^/([^/]+)/([^/]+)([^?]+)\?(.*)')
sec1 = get(pcs, 1)
sec2 = get(pcs, 2)
sec3 = get(pcs, 3)
if or(not(sec1), not(sec2), not(sec3)) {
   add_rsp_header('X-TENGINE-ERROR', 'auth failed - missing necessary uri set')
   exit(403)
}
digest = md5(concat(sec1, sec3))
if ne(digest, sec2) {
    add_rsp_header('X-TENGINE-ERROR', 'auth failed - invalid digest')
    exit(403)
}                                                                                                                                                      

Contoh respons

"X-TENGINE-ERROR:auth failed - missing necessary uri set"

Fitur

Deskripsi

Sintaks

gsub_re(subject, regex, replace [,option])

Deskripsi

Mengganti semua kecocokan dari string dan mengembalikan string setelah penggantian. Untuk informasi lebih lanjut tentang PCRE, lihat Sintaks PCRE.

Parameter

• subject: string yang ingin Anda cocokkan. Tipe data: string.

• regex: ekspresi reguler. Tipe data: string.

• replace: string untuk penggantian. Tipe data: string.

  Anda dapat menentukan parameter replace menggunakan substring yang cocok.

  • $0: menentukan semua substring yang cocok dengan regex.

  • $N: menentukan substring yang cocok dengan subekspresi berkurung ke-N () dari regex.

• option: mesin ekspresi reguler. Tipe data: string. Parameter ini opsional.

Nilai kembali

Mengganti semua substring yang cocok dengan parameter regex yang ditentukan dalam parameter subject yang ditentukan dengan yang ditentukan oleh parameter replace dan mengembalikan string setelah penggantian.

Contoh

subject = 'Hello, Es'
regex = '([a-zA-Z])[a-z]+'
replace = '[$0,$1]'
add_rsp_header('X-DEBUG-GSUB-RE', gsub_re(subject, regex, replace))                                                                                                                                    

Contoh respons

"X-DEBUG-GSUB-RE:[Hello,H], [Es,E]"

Fitur

Deskripsi

Sintaks

split(s [,sep])

Deskripsi

Memisahkan string menjadi array substring dan mengembalikan array tersebut.

Parameter

• s: string yang ingin Anda pisahkan. Tipe data: string.

• sep: pemisah yang digunakan untuk memisahkan string. Tipe data: string.

Nilai kembali

Mengembalikan array pasangan kunci-nilai dalam tipe kamus. Nilai parameter key adalah angka yang dimulai dari 1, misalnya, [1]=xx dan [2]=y. Jika sep dibiarkan kosong, string dipisahkan oleh karakter spasi putih. Karakter spasi putih mencakup karakter spasi dan karakter tab (\t).

Contoh

if $arg_from {
    t = split($arg_from, ',')
    if get(t, 1) {
        say(concat('[1]=', get(t, 1)))
    }
    if get(t, 2) {
        say(concat('[2]=', get(t, 1)))
    }
}                                                                                                                                

Permintaan:

http://www.example.com?from=xx1,xx2,xx3

Output:

[1]=xx1
[2]=xx1

Fitur

Deskripsi

Sintaks

split_as_key(s [,sep])

Deskripsi

Memisahkan string menjadi array substring dan mengembalikan array tersebut.

Parameter

• s: string yang ingin Anda pisahkan. Tipe data: string.

• sep: pemisah yang digunakan untuk memisahkan string. Tipe data: string.

Nilai kembali

Mengembalikan parameter respons dengan cara yang sama seperti fungsi split(). Namun, parameter key dinamai setelah setiap elemen yang dipisahkan: Elemen 1 -> Elemen 2.

Contoh

def echo_each(k, v, u) {
    s = concat(k, '=', v, ' u=', get(u, 1))
    say(s) 
}
if $arg_from {
    t = split_as_key($arg_from, ',')
    foreach(t, echo_each, ['hi,dsl'])
}                                                                                                                                  

Permintaan:

http://www.example.com?from=xx1,xx2,xx3

Output:

xx2=xx2 u=hi,dsl
xx1=xx1 u=hi,dsl
xx3=xx3 u=hi,dsl

Fitur

Deskripsi

Sintaks

tohex(s)

Deskripsi

Mengonversi string menjadi string heksadesimal.

Parameter

s: string yang ingin Anda konversi.

Nilai kembali

Mengembalikan string heksadesimal yang dikonversi dari string yang ditentukan oleh parameter s.

Contoh

digest = sha1('xxxx')
add_rsp_header('X-DSL-TOHEX', tohex(digest))

Contoh respons

"X-DSL-TOHEX: 4ad583af22c2e7d40c1c916b2920299155a46464"

Fitur

Deskripsi

Sintaks

tostring(a)

Deskripsi

Mengonversi data dari tipe apa pun menjadi string.

Parameter

a: data yang ingin Anda konversi. Tipe data: tipe apa pun.

Nilai kembali

Mengembalikan string yang dikonversi dari nilai yang ditentukan oleh parameter a.

Contoh

say(tostring(123))

Output:

123

Fitur

Deskripsi

Sintaks

tochar(n1, n2, ...)

Deskripsi

• Mengonversi satu atau lebih bilangan bulat internal (nilai ASCII) menjadi string. Contohnya, 48 sesuai dengan karakter "0".

• Panjang string yang dikembalikan didasarkan pada jumlah parameter yang ditentukan.

Parameter

nX: bilangan bulat yang ingin Anda konversi. Anda dapat menentukan satu atau lebih bilangan bulat.

Nilai kembali

Mengembalikan string yang dikonversi dari bilangan bulat.

Contoh

say(tochar(97))
say(tochar(65))

Output:

a
A

Fitur

Deskripsi

Sintaks

reverse(str)

Deskripsi

Membalikkan string.

Parameter

str: string yang ingin Anda balikkan.

Nilai kembali

Mengembalikan string yang dibalik dari string yang ditentukan.

Contoh

say(reverse('hello'))

Output:

olleh

Fitur

Deskripsi

Sintaks

string.find (s, substr, pos)

Deskripsi

Mencari substring dalam string yang ditentukan.

Parameter

• s: string yang ingin Anda cari.

• substr: substring yang ingin Anda cari.

• pos: posisi di mana pencarian dimulai. Tipe data: numerik. Parameter ini opsional. Anda dapat menentukan bilangan bulat negatif. Nilai defaultnya adalah 1.

Nilai kembali

• Mengembalikan array jika substring yang ditentukan ditemukan.

  • Indeks 1 menunjukkan posisi di mana pencarian dimulai.

  • Indeks 2 menunjukkan posisi di mana pencarian berakhir.

• Mengembalikan array kosong jika substring yang ditentukan tidak ditemukan.

Contoh

str = 'hello world'
say(concat('r start pos: ',get(find(str, 'r'), 1)))
say(concat('r end pos: ',get(find(str, 'r'), 2)))
say(concat('rl start pos: ',get(find(str, 'rl'), 1)))
say(concat('rl end pos: ',get(find(str, 'rl'), 2)))

Output:

r start pos: 9
r end pos: 9
rl start pos: 9
rl end pos: 10

Fitur

Deskripsi

Sintaks

format(fmt, ···)

Deskripsi

Memformat nilai satu atau lebih parameter. String format adalah parameter pertama, yang harus menentukan string. String format mengikuti spesifikasi parameter sprintf yang digunakan oleh fungsi dalam bahasa pemrograman C.

Parameter

• fmt: tipe string. Parameter ini menentukan string format.

• Jumlah variabel parameter: tipe apa pun.

Nilai kembali

Mengembalikan string ACSII.

Contoh

say(concat('format:', format('%%%s$%.2s$%s$%c$%d$%2.2f$%.2o$%x$%X', 'format', 3.1415926, true, 95, 3.1415926, 3.1415926, 3.1415926, 10, 10)))

Output:

format:%format$3.$true$_$3$3.14$03$a$A

Fitur

Deskripsi

Sintaks

tobin(str)

Deskripsi

Mengonversi string heksadesimal menjadi string ASCII.

Parameter

str: string heksadesimal yang ingin Anda konversi. Tidak peka terhadap huruf besar/kecil.

Nilai kembali

Mengembalikan string ACSII.

Contoh

say(concat('tobin:', tobin('2F2F')))

Output:

tobin://

Fitur

Deskripsi

Sintaks

trim(s, [, loc])

Deskripsi

Menghapus semua karakter spasi putih sebelum atau sesudah string yang ditentukan oleh parameter s, dan mengembalikan string dengan karakter spasi putih yang ditentukan dihapus.

Parameter

• s: string.

• loc: nilai defaultnya adalah both. Parameter ini opsional. Nilai valid:

  • both: menghapus karakter spasi putih sebelum dan sesudah string.

  • left: hanya menghapus karakter spasi putih sebelum string.

  • right: hanya menghapus karakter spasi putih sesudah string.

Nilai kembali

Mengembalikan string dengan karakter spasi putih yang ditentukan dihapus.

Contoh

say(concat('trim():', trim(' abcd ')))
say(concat('trim(left):', trim(' abcd', 'left')))
say(concat('trim(right):', trim('abcd ', 'right')))

Output:

trim():abcd
trim(left):abcd
trim(right):abcd