Container Service for Kubernetes:Backup dan pulihkan aplikasi dengan Terraform

Buat tugas backup instan

1. Tambahkan berikut ini ke csdr.tf, ganti placeholder-nya:

   Jika kluster ACK Anda menggunakan Velero, bergabunglah dengan grup DingTalk 35532895 untuk dukungan teknis.

   Parameter	Wajib	Deskripsi
   csdr.alibabacloud.com/backuplocations	Ya	Anotasi penyimpanan cadangan. Harus persis sesuai dengan konfigurasi BackupLocation.
   name	Ya	Nama tugas backup instan.
   includedNamespaces	Ya	Namespace yang akan dibackup.
   includedResources	Tidak	Jenis resource yang disertakan. Tentukan hanya salah satu dari includedResources atau excludedResources. Jika keduanya kosong, semua jenis resource akan dibackup.
   excludedResources	Tidak	Jenis resource yang dikecualikan. Lihat includedResources.
   matchLabels	Tidak	Label dari resource yang akan dibackup.
   includeClusterResources	Tidak	Mengontrol resource berskala kluster. true: semua resource berskala kluster. false atau tidak diatur: hanya yang dirujuk oleh namespace yang ditentukan. Nilai default di Konsol ACK: false.
   defaultPvBackup	Tidak	true: backup aplikasi dan volume. false: backup hanya aplikasi.
   storageLocation	Ya	Nama penyimpanan cadangan (BackupLocation).
   ttl	Ya	Periode validitas backup. Format: 720h0m0s. Rentang valid: 24h0m0s hingga 1572864h0m0s. Backup yang kedaluwarsa tidak dapat dipulihkan.

   resource "kubernetes_manifest" "applicationbackup-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "ApplicationBackup"
       metadata = {
         name      = "<your-backup-task-name>"
         namespace = "csdr"
         annotations = {
           # Harus persis sesuai dengan konfigurasi penyimpanan cadangan
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         includedNamespaces = ["default", "default1"]  # Namespace yang akan dibackup
   
         # Tentukan hanya salah satu dari includedResources atau excludedResources.
         # Jika keduanya kosong, semua jenis resource akan dibackup.
         includedResources = ["statefulset"]
         excludedResources = ["excludedResources"]
   
         labelSelector = {
           matchLabels = {
             "app" = "mysql-sts"  # Opsional: backup hanya resource dengan label ini
           }
         }
   
         pvBackup = {
           defaultPvBackup = "false"  # "true": backup aplikasi dan volume; "false": hanya aplikasi
         }
   
         storageLocation = "<your-backup-vault-name>"  # Harus sesuai dengan nama BackupLocation
   
         ttl = "720h0m0s"  # Periode validitas backup. Format: 720h0m0s
                           # Rentang valid: 24h0m0s hingga 1572864h0m0s
                           # Backup yang kedaluwarsa tidak dapat dipulihkan
   
         # includeClusterResources mengontrol apakah resource berskala kluster disertakan:
         # "true"  — sertakan semua resource berskala kluster (StorageClasses, CRDs, webhook, dll.)
         # "false" — sertakan hanya resource berskala kluster yang dirujuk oleh namespace yang ditentukan
         #           (misalnya, jika pod menggunakan service account dengan cluster role,
         #            cluster role tersebut secara otomatis disertakan)
         # Tidak diatur — perilaku sama seperti "false" saat menggunakan filter namespace
         includeClusterResources = "false"
       }
     }
   
     # Hapus komentar untuk menunggu hingga backup selesai (disarankan untuk alur kerja skrip).
     # Durasi backup tergantung pada jumlah aplikasi dan ukuran data volume.
     #wait {
     #  fields = {
     #    "status.phase" = "Completed"
     #  }
     #}
     #timeouts {
     #  create = "60m"
     #}
   }

2. Pratinjau perubahan:

   terraform plan

3. Buat tugas backup instan:

   terraform apply

   Expand to view the output

   kubernetes_manifest.applicationbackup-demo: Creating...
   kubernetes_manifest.applicationbackup-demo: Creation complete after 1s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

Buat tugas backup terjadwal

1. Tambahkan berikut ini ke csdr.tf, ganti placeholder-nya:

   Expand to view the configuration file

   resource "kubernetes_manifest" "backupschedule-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "BackupSchedule"
       metadata = {
         name      = "<your-schedule-name>"
         namespace = "csdr"
         annotations = {
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         # Ekspresi cron untuk jadwal backup (zona waktu server).
         # Format:  menit  jam  hari-dalam-bulan  bulan  hari-dalam-minggu
         # Contoh: "1 4 * * *" dijalankan setiap hari pukul 04:01.
         schedule = "1 4 * * *"
   
         template = {
           includedNamespaces = ["default", "default1"]
           includedResources  = ["statefulset"]
           excludedResources  = ["excludedResources"]
           labelSelector = {
             matchLabels = {
               "app" = "mysql-sts"
             }
           }
           pvBackup = {
             defaultPvBackup = "false"  # Wajib untuk BackupSchedule
           }
           storageLocation         = "<your-backup-vault-name>"
           ttl                     = "720h0m0s"
           includeClusterResources = "false"
         }
       }
     }
   
     wait {
       fields = {
         "status.phase" = "Enabled"
       }
     }
   
     timeouts {
       create = "10m"
     }
   }

   Parameter	Wajib	Deskripsi
   csdr.alibabacloud.com/backuplocations	Ya	Anotasi penyimpanan cadangan. Harus persis sesuai dengan konfigurasi BackupLocation.
   name	Ya	Nama tugas backup terjadwal.
   schedule	Ya	Frekuensi backup dalam bentuk ekspresi cron. Format: menit jam hari-dalam-bulan bulan hari-dalam-minggu. Contoh: "1 4 * * *" dijalankan setiap hari pukul 04:01.
   includedNamespaces	Ya	Namespace yang akan dibackup.
   includedResources	Tidak	Jenis resource yang disertakan. Tentukan hanya salah satu dari includedResources atau excludedResources. Jika keduanya kosong, semua jenis resource akan dibackup.
   excludedResources	Tidak	Jenis resource yang dikecualikan. Lihat catatan untuk includedResources.
   matchLabels	Tidak	Label dari resource yang akan dibackup.
   includeClusterResources	Tidak	Mengontrol resource berskala kluster. true: semua resource berskala kluster. false atau tidak diatur: hanya yang dirujuk oleh namespace yang ditentukan.
   defaultPvBackup	Ya	true: backup aplikasi dan volume. false: backup hanya aplikasi.
   storageLocation	Ya	Nama penyimpanan cadangan (BackupLocation).
   ttl	Ya	Periode validitas backup. Format: 720h0m0s. Rentang valid: 24h0m0s hingga 1572864h0m0s.

2. Pratinjau perubahan:

   terraform plan

3. Buat tugas backup terjadwal:

   terraform apply

   Expand to view the output

   kubernetes_manifest.backupschedule-demo: Creating...
   kubernetes_manifest.backupschedule-demo: Creation complete after 1s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

Kelola tugas backup terjadwal

Temukan backup yang dibuat oleh jadwal

Daftar backup dari jadwal tertentu:

data "kubernetes_resources" "list-applicationbackup" {
  api_version    = "csdr.alibabacloud.com/v1beta1"
  kind           = "ApplicationBackup"
  namespace      = "csdr"
  label_selector = "csdr/schedule-name=<your-schedule-name>"
}

output "applicationbackup-name" {
  value = data.kubernetes_resources.list-applicationbackup.objects
}

Ubah tugas backup terjadwal

Untuk mengubah parameter seperti frekuensi jadwal:

1. Tetapkan spec.paused ke "true" untuk menjeda jadwal, lalu perbarui parameter. Contoh:

   Expand to view the configuration file

   resource "kubernetes_manifest" "backupschedule-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "BackupSchedule"
       metadata = {
         name      = "<your-schedule-name>"
         namespace = "csdr"
         annotations = {
           "csdr.alibabacloud.com/backuplocations" = "{\"name\":\"<your-backup-vault-name>\",\"region\":\"cn-beijing\",\"bucket\":\"<cnfs-oss-your-bucket-name>\",\"prefix\":\"<sub-directory>\",\"provider\":\"alibabacloud\"}"
         }
       }
       spec = {
         paused   = "true"        # Jeda jadwal sebelum mengubah
         schedule = "0 5 * * *"   # Frekuensi backup yang diperbarui
         template = {
           includedNamespaces      = ["default", "default1"]
           includedResources       = ["statefulset"]
           excludedResources       = ["excludedResources"]
           labelSelector = {
             matchLabels = {
               "app" = "mysql-sts"
             }
           }
           pvBackup = {
             defaultPvBackup = "false"
           }
           storageLocation         = "<your-backup-vault-name>"
           ttl                     = "720h0m0s"
           includeClusterResources = "false"
         }
       }
     }
     wait {
       fields = {
         "status.phase" = "Paused"  # Pastikan jadwal telah dijeda sebelum menerapkan perubahan lebih lanjut
       }
     }
     timeouts {
       create = "10m"
     }
   }

2. Pratinjau perubahan:

   terraform plan

3. Terapkan konfigurasi yang diperbarui:

   terraform apply

   Output yang diharapkan:

   kubernetes_manifest.backupschedule-demo: Modifying...
   kubernetes_manifest.backupschedule-demo: Modifications complete after 1s
   
   Apply complete! Resources: 0 added, 1 changed, 0 destroyed.

Proteksi data (PvBackup)

Tetapkan backupType ke PvBackup untuk hanya melakukan backup data volume. Tentukan pvcList untuk backup PVC tertentu, atau storageClassList untuk backup volume dari StorageClass tertentu. Jika Anda menetapkan keduanya, storageClassList akan diabaikan. Jika tidak menetapkan keduanya, semua volume dalam namespace yang disertakan akan dibackup.

Hapus tugas backup terjadwal

Jalankan terraform destroy untuk menghapus BackupSchedule dan menghentikan jadwal.

Hapus tugas backup atau tugas pemulihan

Gunakan DeleteRequest CR untuk menghapus tugas backup atau pemulihan serta sumber daya cloud terkait secara aman.

Menghapus tugas backup tidak memengaruhi backup yang sudah ada. Menghapus tugas pemulihan tidak memengaruhi data yang telah dipulihkan.

1. Tambahkan berikut ini ke csdr.tf:

   Parameter	Wajib	Deskripsi
   name	Ya	Nama permintaan penghapusan. Format: <ApplicationBackup-name>-dbr untuk menghapus tugas backup, atau <ApplicationRestore-name>-dbr untuk menghapus tugas pemulihan.
   deleteObjectName	Ya	Nama resource yang akan dihapus.
   deleteObjectType	Ya	"Backup": menghapus ApplicationBackup CR dan resource terkait. "Restore": menghapus ApplicationRestore CR dan resource terkait.

   resource "kubernetes_manifest" "deleterequest-demo" {
     manifest = {
       apiVersion = "csdr.alibabacloud.com/v1beta1"
       kind       = "DeleteRequest"
       metadata = {
         name      = "<object-name>-dbr"  # Format: <ApplicationBackup-or-ApplicationRestore-name>-dbr
         namespace = "csdr"
       }
       spec = {
         deleteObjectName = "<object-name>"   # Nama tugas backup atau pemulihan yang akan dihapus
         deleteObjectType = "Backup"          # "Backup": menghapus ApplicationBackup dan resource terkait
                                              # "Restore": menghapus ApplicationRestore dan resource terkait
       }
     }
   }

2. Pratinjau perubahan:

   terraform plan

3. Terapkan penghapusan:

   terraform apply

   Expand to view the output

   kubernetes_manifest.deleterequest-demo: Creating...
   kubernetes_manifest.deleterequest-demo: Creation complete after 0s
   
   Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

   Setelah menghapus resource target, sistem juga akan menghapus DeleteRequest CR.