容器服务 Kubernetes 版 ACK：使用Terraform创建ACK Serverless集群

使用Terraform创建ACK Serverless集群

1. 创建一个工作目录，并在工作目录中创建以下名为main.tf的配置文件。

   main.tf文件中描述了以下Terraform配置：

   • 创建一个新的VPC，并创建一个该VPC下的vSwitch。

   • 创建一个ACK Serverless集群。

   provider "alicloud" {
   }
   
   variable "k8s_name_prefix" {
     description = "The name prefix used to create ASK cluster."
     default     = "ask-example"
   }
   
   # 默认资源名称。
   locals {
     k8s_name_ask = substr(join("-", [var.k8s_name_prefix, "ask"]), 0, 63)
     new_vpc_name = "tf-vpc-172-16"
     new_vsw_name = "tf-vswitch-172-16-0"
   }
   
   data "alicloud_eci_zones" "default" {}
   
   resource "alicloud_vpc" "vpc" {
     vpc_name   = local.new_vpc_name
     cidr_block = "172.16.0.0/12"
   }
   
   resource "alicloud_vswitch" "vsw" {
     vswitch_name = local.new_vsw_name
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = cidrsubnet(alicloud_vpc.vpc.cidr_block, 8, 8)
     zone_id      = data.alicloud_eci_zones.default.zones.0.zone_ids.1
   }
   
   
   resource "alicloud_cs_serverless_kubernetes" "serverless" {
     name                           = local.k8s_name_ask
     version                        = "1.28.3-aliyun.1" # 替换为您所需创建的集群版本。
     cluster_spec                   = "ack.pro.small"
     vpc_id                         = alicloud_vpc.vpc.id
     vswitch_ids                    = split(",", join(",", alicloud_vswitch.vsw.*.id))
     new_nat_gateway                = true
     endpoint_public_access_enabled = true
     deletion_protection            = false
   
     # 通过RRSA配置ServiceAccount。
     enable_rrsa = true
   
     load_balancer_spec      = "slb.s2.small"
     time_zone               = "Asia/Shanghai"
     service_cidr            = "10.13.0.0/16"
     service_discovery_types = ["CoreDNS"]
   
     # tags
     tags = {
       "cluster" = "ack-serverless"
     }
     # addons
     addons {
       name = "nginx-ingress-controller"
       # 使用Internet。
       config = "{\"IngressSlbNetworkType\":\"internet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
       # 如果使用Intranet, 配置如下。
       # config = "{\"IngressSlbNetworkType\":\"intranet\",\"IngressSlbSpec\":\"slb.s2.small\"}"
     }
     addons {
       name = "metrics-server"
     }
     addons {
       name = "knative"
     }
     addons {
       name = "managed-arms-prometheus"
     }
     addons {
       name = "logtail-ds"
       # 指定具体的sls_project_name
       # config = "{\"sls_project_name\":\"<YOUR-SLS-PROJECT-NAME>}\"}"
     }
   }

2. 执行如下命令，初始化Terraform运行环境。

   terraform init

   返回信息如下，Terraform初始化成功。

   Initializing the backend...
   
   Initializing provider plugins...
   - Checking for available provider plugins...
   - Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.184.0...
   ...
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 执行如下命令，生成资源规划。

   terraform plan

   返回信息如下，资源规划生成成功。

   Refreshing Terraform state in-memory prior to plan...
   The refreshed state will be used to calculate this plan, but will not be
   persisted to local or remote state storage.
   ...
   Plan: 3 to add, 0 to change, 0 to destroy. 
   ...

4. 执行如下命令，创建集群。

   terraform apply

   返回信息如下，输入yes，按Enter键，集群创建成功。

   ...
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   ...
   alicloud_cs_serverless_kubernetes.serverless: Creation complete after 8m26s [id=************]
   
   Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

使用Terraform删除ACK Serverless集群

您可以通过执行如下命令，删除通过Terraform创建的ACK Serverless集群。

terraform destroy

返回信息如下，输入yes，按Enter键，集群删除成功。

...
Do you really want to destroy all resources?
  Terraform will destroy all your managed infrastructure, as shown above.
  There is no undo. Only 'yes' will be accepted to confirm.

  Enter a value: yes
...
Destroy complete! Resources: 3 destroyed.