Virtual Private Cloud：VPC 和 vSwitch

主控台

API

與主控台不同，呼叫 CreateVpc 操作僅建立一個空的 VPC。您還必須呼叫 CreateVSwitch 操作來建立 vSwitch。

• Call CreateVpc and then CreateVSwitch to create a VPC and a vSwitch.

• Call DeleteVSwitch and then DeleteVpc to delete a vSwitch and a VPC.

  1. 刪除 vSwitch 之前，請確保它未被共用、未繫結至自訂路由表或網路 ACL，且其中所有雲端資源均已釋放。

  2. 刪除 VPC 之前，請確保其中所有資源均已釋放，且與其他網路服務（如 CEN）的連線已移除。

Terraform

資源： alicloud_vpc, alicloud_vswitch

資料來源： alicloud_zones

# 指定要建立 VPC 的地區。
provider "alicloud" {
  region = "cn-hangzhou"
}

# 使用資料來源自動擷取可建立 vSwitch 的可用區清單。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查詢 VPC 中可建立 vSwitch 的可用區。
  # available_instance_type = "ecs.g7.large"  # 查詢 VPC 中可建立 ECS 執行個體的可用區。
  # available_resource_creation = "slb"  # 查詢 VPC 中可建立 SLB 執行個體的可用區。
}

# 建立 VPC。
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # 指定 CIDR 區塊。
}

# 建立 vSwitch。
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # 指定 CIDR 區塊。
  vpc_id       = alicloud_vpc.example_vpc.id                       # 指定 vSwitch 所屬的 VPC ID。
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # 指定 vSwitch 所屬的可用區。
}

主控台

API

與主控台不同，透過呼叫 API 為 VPC 和 vSwitch 啟用 IPv6 時，不會自動建立 IPv6 閘道。您必須呼叫 CreateIpv6Gateway 自行建立一個。

• When you create a VPC and a vSwitch, set the EnableIPv6 parameter in CreateVpc and CreateVSwitch to enable or disable IPv6. When you create a VPC, specify the Ipv6IpamPoolId and Ipv6CidrMask parameters to allocate an IPv6 CIDR block from a specified IPv6 IPAM pool to the VPC.

• For existing VPC 和 vSwitch, modify the EnableIPv6 parameter of ModifyVpcAttribute and ModifyVSwitchAttribute to enable or disable IPv6. To assign an IPv6 CIDR block to a VPC from a specified IPv6 address pool, call AssociateVpcCidrBlock.

Terraform

Terraform 目前僅支援系統分配的 IPv6 CIDR 區塊。不支援從 IPAM 集區分配。

資源： alicloud_vpc, alicloud_vswitch

資料來源： alicloud_zones

# 指定要建立 VPC 的地區。
provider "alicloud" {
  region = "cn-hangzhou"
}

# 使用資料來源自動擷取可建立 vSwitch 的可用區清單。
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查詢 VPC 中可建立 vSwitch 的可用區。
  # available_instance_type = "ecs.g7.large"  # 查詢 VPC 中可建立 ECS 執行個體的可用區。
  # available_resource_creation = "slb"  # 查詢 VPC 中可建立 SLB 執行個體的可用區。
}

# 建立雙堆疊 VPC。
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # 啟用 IPv6。設定為 false 以停用 IPv6。
  ipv6_isp    = "BGP" # 指定 IPv6 CIDR 區塊的類型。
}

# 建立雙堆疊 vSwitch。
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # 啟用 IPv6。設定為 false 以停用 IPv6。
  ipv6_cidr_block_mask = 1    # 指定 vSwitch 的 IPv6 CIDR 區塊最後 8 位元。
} 

主控台

API

• Call CreateVSwitchCidrReservation to create a reserved CIDR block.

• Call GetVSwitchCidrReservationUsage to view used IP addresses.

• Call DeleteVSwitchCidrReservation to delete a reserved CIDR block.

Terraform

資源： alicloud_vpc_vswitch_cidr_reservation

# 指定資源所在的地區。
provider "alicloud" {
  region = "cn-hangzhou" # 資源所在的地區。
}

# 指定 vSwitch 的 ID。
variable "vsw_id" {
  default = "vsw-xxx" # 替換為您實際的 vSwitch ID。
}

# 建立保留的 CIDR 區塊。
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 指定保留的 CIDR 區塊。
}

主控台

建立 VPC 之前，請確保您已在 IPAM 主控台.

1. Go to the 建立 VPC page in the VPC console.

2. To allocate an IPv4 CIDR block, select Allocated by IPAM, choose an IPAM pool, and configure a mask. The system automatically allocates the first available CIDR block matching the specified mask length. You can also adjust the IPv4 CIDR block within the pre-provisioned range of the pool.

3. To enable IPv6, select Allocated by IPAM, choose an IPv6 IPAM pool, and then configure a mask or specify a CIDR block.

API

• If you have an existing IPAM pool:

  • Allocate an IPv4 CIDR block: You can call CreateVpc and pass the Ipv4IpamPoolId parameter to specify an IPAM pool and the Ipv4CidrMask parameter to specify a mask. A CIDR block is then allocated from the IPAM pool and used as the IPv4 CIDR block for the new VPC. Alternatively, you can pass the CidrBlock parameter to specify the CIDR block for the VPC instead of automatically allocating a CIDR block by specifying a mask.

  • Allocate an IPv6 CIDR block: If you pass both Ipv6IpamPoolId and Ipv6CidrMask, an IPv6 CIDR block is allocated to the VPC from the specified IPv6 IPAM pool.

• If you have not created an IPAM pool, call the following APIs in sequence to create one, and then create your VPC as described above.

  1. OpenVpcIpamService - 啟用 IPAM 功能

  2. CreateIpam - 建立 IPAM 執行個體

  3. CreateIpamPool - 建立 IPAM 集區

  4. AddIpamPoolCidr - 為 IPAM 集區佈建 CIDR 區塊

Terraform

Terraform 目前僅支援從 IPAM 集區分配 IPv4 CIDR 區塊。不支援分配 IPv6 CIDR 區塊。

資源： vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# 指定要建立 IPAM 執行個體、IPAM 集區和 VPC 的地區。
provider "alicloud" {
  region = "cn-hangzhou"
}

# 建立 IPAM 執行個體。
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # 指定 IPAM 執行個體的操作地區。
}

# 建立 IPAM 集區。
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # 指定 IPAM 集區的範圍。
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # 指定 IPAM 集區的地區。
  ip_version     = "IPv4"                                     # 指定 IPAM 集區的 IP 版本。
}

# 為 IPAM 集區分配 CIDR。
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # 指定 CIDR。
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定 IPAM 集區的 ID。
}

# 建立 VPC。
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定 IPAM 集區的 ID。
  ipv4_cidr_mask    = 24                                                 # IPv4 網路遮罩。
}