Virtual Private Cloud：專用網路與交換器

控制台

API

與控制台邏輯不同的是，使用CreateVpc僅建立一個空的專用網路，您還需要使用CreateVSwitch建立交換器。

• 依次調用CreateVpc和CreateVSwitch建立專用網路和交換器。

• 依次調用DeleteVSwitch和DeleteVpc刪除交換器和專用網路。

  1、刪除交換器前，需要確保交換器未共用、未綁定自訂路由表和網路ACL並且交換器內的雲產品資源已釋放。

  2、刪除專用網路前，需要確保VPC內資源已釋放完成，且已取消與雲企業網等網路服務的關聯。

Terraform

Resources：alicloud_vpc、alicloud_vswitch

Data Sources：alicloud_zones

# 指定建立VPC的地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 根據資料來源自動擷取可以建立交換器的可用性區域列表
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查詢VPC內可建立的可用性區域
  # available_instance_type = "ecs.g7.large"  # 查詢VPC內可建立ECS執行個體的可用性區域
  # available_resource_creation = "slb"  # 查詢VPC內可建立SLB執行個體的可用性區域
}

# 建立VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" #指定網段 
}

# 建立交換器 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # 指定網段 
  vpc_id       = alicloud_vpc.example_vpc.id                       # 指定交換器所屬VPC的執行個體ID 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # 指定交換器所屬可用性區域
}

控制台

API

• 建立專用網路和交換器時，調整CreateVpc和CreateVSwitch的EnableIPv6參數開啟/關閉IPv6。

• 針對已建立的專用網路和交換器，調整ModifyVpcAttribute與ModifyVSwitchAttribute的EnableIPv6參數開啟/關閉IPv6。

Terraform

Resources：alicloud_vpc、alicloud_vswitch

Data Sources：alicloud_zones

# 指定建立VPC的地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 根據資料來源自動擷取可以建立交換器的可用性區域列表
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查詢VPC內可建立的可用性區域
  # available_instance_type = "ecs.g7.large"  # 查詢VPC內可建立ECS執行個體的可用性區域
  # available_resource_creation = "slb"  # 查詢VPC內可建立SLB執行個體的可用性區域
}

# 建立雙棧VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # 開啟IPv6，false為關閉IPv6
  ipv6_isp    = "BGP" # 指定IPv6網段類型
}

# 建立雙棧交換器 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # 開啟IPv6，false為關閉IPv6
  ipv6_cidr_block_mask = 1    # 指定交換器IPv6網段的最後8位元位 
} 

控制台

API

• 調用AssociateVpcCidrBlock添加附加網段。

• 調用UnassociateVpcCidrBlock刪除附加網段。

Terraform

Terraform當前僅支援建立IPv4附加網段，暫不支援建立IPv6附加網段。

Resources：alicloud_vpc_ipv4_cidr_block

# 指定建立VPC的地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定VPC的ID
variable "vpc_id" {
  default = "vpc-xxx" # 修改為VPC的實際ID
}

# 在VPC中建立附加網段
resource "alicloud_vpc_ipv4_cidr_block" "example_secondary_cidr_block" {
  vpc_id               = var.vpc_id
  secondary_cidr_block = "192.168.0.0/16" # 指定附加網段
}

控制台

API

• 調用CreateVSwitchCidrReservation建立預留網段。

• 調用GetVSwitchCidrReservationUsage查看已佔用IP段。

• 調用DeleteVSwitchCidrReservation刪除預留網段。

Terraform

Resources: alicloud_vpc_vswitch_cidr_reservation

# 指定建立VPC的地區
provider "alicloud" {
  region = "cn-hangzhou" # 資源所在的地區
}

# 指定交換器的ID
variable "vsw_id" {
  default = "vsw-xxx" # 修改為交換器的實際ID
}

# 建立預留網段
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 指定預留網段 
}

控制台

前往專用網路控制台的建立專用網路頁面，使用IPAM分配的IPv4位址區段，選擇IPAM位址集區並配置掩碼，從IPAM位址集區中為專用網路分配網段。

配置網路遮罩後，系統會預設分配指定掩碼範圍內第一個可用的CIDR，您也可以在位址集區預置CIDR內，調整IPv4網段。

建立專用網路前，請確保已通過IPAM控制台建立IPAM和IPAM位址集區。

API

• 如已建立過IPAM位址集區，可在調用CreateVpc時傳入Ipv4IpamPoolId來指定IPAM位址集區，同時傳入Ipv4CidrMask來指定掩碼從IPAM位址集區中分配地址作為建立VPC的網段。您也可以傳入CidrBlock來指定VPC使用的網段，而不是通過指定掩碼自動分配網段。

• 如未建立過IPAM位址集區，可依次調用如下API來建立IPAM位址集區，然後參考上述邏輯建立專用網路。

  1. OpenVpcIpamService-開通IPAM功能

  2. CreateIpam-建立一個IPAM執行個體

  3. CreateIpamPool-建立IPAM位址集區

  4. AddIpamPoolCidr-為IPAM位址集區預置CIDR位址區段

Terraform

Resources：vpc_ipam_ipam、alicloud_vpc_ipam_ipam_pool、alicloud_vpc_ipam_ipam_pool_cidr、alicloud_vpc

# 指定建立IPAM、IPAM 位址集區、VPC的地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 建立IPAM
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # 指定IPAM的生效地區
}

# 建立IPAM位址集區
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # 指定IPAM位址集區的作用範圍
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # 指定IPAM位址集區的生效地區
  ip_version     = "IPv4"                                     # 指定IPAM位址集區的版本
}

# 為IPAM位址集區分配CIDR
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # 指定CIDR
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定IPAM位址集區的ID
}

# 建立VPC
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定IPAM位址集區的ID
  ipv4_cidr_mask    = 24                                                 # IPv4網路遮罩
}