Virtual Private Cloud：共用VPC

一、開啟共用

此處僅介紹將交換器共用給任意賬戶的方式。針對資來源目錄方式，請參考僅在資來源目錄內共用資源。

1. 登入交換器所有者的帳號，前往資源管理主控台的資源共用-我的共用頁面。先在頂部功能表列左上處，選擇共用資源所在的地區，再單擊建立共用單元，在開啟的頁面中：

   第一步：輸入共用單元名稱，然後選中需要共用的交換器。

   第二步：系統會預設選擇AliyunRSDefaultPermissionVSwitch許可權。

   第三步：使用者範圍選擇允許共用給任意帳號，添加方式選擇手動添加，使用者ID輸入交換器使用者的阿里雲帳號ID，並點擊添加。

   第四步：檢查無誤後，在頁面底部單擊確定。

2. 登入交換器使用者的帳號，接受共用邀請：

   1. 前往資源管理主控台的資源共用-共用給我頁面。

   2. 在頂部功能表列左上處，選擇共用資源所在的地區，再單擊目標共用單元狀態列的接受。

   3. 接受後，交換器使用者就可以訪問共用的交換器，且後續該共用單元新增的共用資源將預設接受共用邀請。

二、在共用交換器建立雲資源

登入交換器使用者的帳號：

1. 前往專用網路控制台交換器頁面，在頂部狀態列選擇共用交換器的地區後，您可以看到共用交換器（被標記為來自共用）。

   

2. 針對ECS、RDS、SLB執行個體，您可以在目標共用交換器的操作列，單擊添加雲產品進行建立。

3. 其他支援在共用交換器下建立的雲資源類型，請在建立時選擇共用交換器。

一、開啟共用

• 方式一：共用給任意賬戶

  1. 使用交換器所有者的身份憑證，調用CreateResourceShare建立共用單元，並確保將AllowExternalTargets參數設為True。

  2. 使用交換器使用者的身份憑證，先調用ListResourceShareInvitations 查詢收到的資源邀請資訊，再調用AcceptResourceShareInvitation接受資源共用邀請。

• 方式二：僅在資來源目錄內共用

  1. 使用交換器所有者的身份憑證，調用EnableSharingWithResourceDirectory啟用資來源目錄組織共用。

  2. 繼續使用交換器所有者的身份憑證，調用CreateResourceShare建立共用單元，並確保將AllowExternalTargets參數設為False。

二、建立雲資源

登入交換器使用者的帳號：

1. 調用DescribeVSwitches擷取交換器列表。

2. 在交換器列表中，過濾出共用交換器（ShareType欄位值為Sharing）。

3. 調用雲資源的建立介面（例如ECS的RunInstances），基於共用交換器建立雲資源。

一、開啟共用

交換器所有者建立共用單元：

當前Terraform不支援將交換器共用給任意賬戶，僅支援在資來源目錄內共用，請您在操作前確保交換器所有者已啟用資來源目錄組織共用。

Resources: alicloud_resource_manager_resource_share、alicloud_resource_manager_shared_resource、alicloud_resource_manager_shared_target

# 指定地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定共用單元名稱
resource "alicloud_resource_manager_resource_share" "example_unit" {
  resource_share_name = "example_unit_name"
}

# 指定共用交換器
resource "alicloud_resource_manager_shared_resource" "example_vsw" {
  resource_share_id = alicloud_resource_manager_resource_share.example_unit.id
  resource_id       = "vsw-bp1omg98fixldnwcxxxxx" # 修改為實際的共用交換器ID
  resource_type     = "VSwitch"                   # 資源類型為交換器 
}

# 指定共用交換器的使用者
resource "alicloud_resource_manager_shared_target" "example_target" {
  resource_share_id = alicloud_resource_manager_resource_share.example_unit.id
  target_id         = "10xxxxxxxxxxxxxx" # 修改為交換器使用者的實際UID
}

二、在共用交換器建立雲資源

以交換器使用者在共用交換器中建立1台ECS為例：

Resources: alicloud_security_group、alicloud_instance

Data Sources: alicloud_vswitches

# 指定地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定共用交換器
variable "vsw_id" {
  default = "vsw-bp1omg98fixldnwcxxxxx" # 替換為實際的共用交換器ID
}

# 擷取目標共用交換器的資訊
data "alicloud_vswitches" "example_vsw" {
  ids = [var.vsw_id]  
}

# 建立安全性群組
resource "alicloud_security_group" "example_sg" {
  security_group_name = "example_sg_name"
  vpc_id              = data.alicloud_vswitches.example_vsw.vswitches[0].vpc_id
}

# 建立ECS
resource "alicloud_instance" "example_ecs" {
  instance_name        = "example_ecs_name"
  instance_type        = "ecs.e-c1m1.large"
  security_groups      = [alicloud_security_group.example_sg.id]
  vswitch_id           = var.vsw_id
  image_id             = "aliyun_3_x64_20G_alibase_20250117.vhd"
  system_disk_category = "cloud_essd"
}

查看共用交換器、共用交換器的使用者

交換器所有者查看共用單元、共用的資源、共用資源的使用者：

Datasources: alicloud_resource_manager_resource_shares、alicloud_resource_manager_shared_resources、alicloud_resource_manager_shared_targets

# 指定地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 共用單元列表
data "alicloud_resource_manager_resource_shares" "example_units" {
  resource_share_owner = "Self" # 查看自己共用給別人的共用單元
}
# 輸出資料行表
output "first_resource_manager_resource_share_id" {
  value = data.alicloud_resource_manager_resource_shares.example_units.shares
}

# 共用的資源清單
data "alicloud_resource_manager_shared_resources" "example_resources" {
}
# 輸出資料行表
output "first_resource_manager_shared_resource_id" {
  value = data.alicloud_resource_manager_shared_resources.example_resources.resources
}

# 共用資源的使用者列表
data "alicloud_resource_manager_shared_targets" "example_targets" {
}
# 輸出資料行表
output "first_resource_manager_shared_target_id" {
  value = data.alicloud_resource_manager_shared_targets.example_targets.targets
}

增加或刪除共用交換器

交換器所有者可以通過在.tf檔案中增加或刪除alicloud_resource_manager_shared_resource，實現增加或刪除共用交換器。

增加或刪除共用交換器的使用者

交換器所有者可以通過在.tf檔案中增加或刪除alicloud_resource_manager_shared_target，實現增加或刪除共用交換器的使用者。