Terraform：使用Terraform快速建立資源

自訂參數建立資源

如需根據實際需求配置參數，按以下步驟操作：

1. 登入Terraform Explorer，選擇產品和資源類型，參照資來源文件填寫參數，單擊發起調試。

   建立 VPC 的主要參數如下。更多參數資訊，請參見 alicloud_vpc。

   參數名稱	參數描述	樣本值
   vpc_name	VPC 名稱	tf-test-vpc
   cidr_block	VPC 私網網段	192.168.0.0/16
   description	VPC 描述資訊	The VPC was created using Terraform.

   

2. 在模板詳情頁簽確認參數無誤後，單擊預覽查看執行計畫。

   

3. 在預覽詳情頁簽確認待建立資源的資訊，單擊執行。

   

4. 在執行詳情頁簽查看結果。執行成功會提示 "Apply complete! Resources: 1 added, 0 changed, 0 destroyed."。執行失敗時，請根據提示修改參數後重新調試。

   

5. 在資源詳情頁簽查看已建立的資源資訊。

   

6. （可選）修改資源：調整參數後單擊預覽並執行，重複步驟 2~4。更新成功會提示 "Apply complete! Resources: 0 added, 1 changed, 0 destroyed."。

   

7. （可選）釋放資源：在執行詳情頁簽單擊銷毀資源，然後在預覽詳情頁簽單擊執行。

   

使用樣本模板建立資源

如果對資源參數不熟悉或僅希望快速體驗，可直接使用 Terraform Explorer 提供的樣本模板。

1. 登入Terraform Explorer，選擇相應的產品、資源類型及樣本模板，單擊發起調試。在右側的樣本模板頁簽可查看模板詳情。

   

2. 在模板詳情頁簽單擊預覽並執行。

   

3. 在執行詳情頁簽，您可以查看執行結果。

   

4. （可選）若您希望釋放已建立的資源，在執行詳情頁簽單擊銷毀資源，然後在預覽詳情頁簽單擊執行。

   

阿里雲 Cloud Shell 是一款免費的營運工具，已預裝 Terraform 並配置好身份憑證，可直接運行 Terraform 命令。

驗證安裝

運行以下命令確認 Terraform 已正確安裝：

terraform version

命令成功執行並顯示版本號碼，表示安裝完成。

以下以建立一台 ECS 執行個體為例，示範 Terraform Resource Orchestration Service的完整流程：建立 VPC → 建立交換器 → 建立安全性群組 → 建立 ECS 執行個體。

1. 建立工作目錄並編寫 Terraform 設定檔 main.tf：

   mkdir tf-demo && cd tf-demo
   vim main.tf

   將以下代碼複製到 main.tf：

   provider "alicloud" {
     region = var.region
   }
   
   # 資源建立的地區
   variable "region" {
     default = "cn-beijing"
   }
   
   # ECS執行個體名稱
   variable "instance_name" {
     default = "tf-cloudshell-test"
   }
   
   # ECS執行個體規格
   variable "instance_type" {
     default = "ecs.n2.small"
   }
   
   # 公網出頻寬，值為0時，表示不開通公網
   variable "internet_bandwidth" {
     default = 10
   }
   
   # ECS系統鏡像
   variable "image_id" {
     default = "ubuntu_18_04_64_20G_alibase_20190624.vhd"
   }
   
   # ECS系統硬碟類型
   variable "disk_category" {
     default = "cloud_efficiency"
   }
   # ECS執行個體登入密碼
   variable "password" {
     default = "TF-test@1234"
   }
   
   # 建立VPC
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "tf_test_foo"
     cidr_block = "172.16.0.0/12"
   }
   
   # 根據執行個體規格和雲端硬碟類型查詢存在資源的可用性區域
   data "alicloud_zones" "default" {
     available_disk_category     = var.disk_category
     available_resource_creation = "VSwitch"
     available_instance_type     = var.instance_type
   }
   
   # 建立vSwitch
   resource "alicloud_vswitch" "vsw" {
     vpc_id     = alicloud_vpc.vpc.id
     cidr_block = "172.16.0.0/21"
     zone_id    = data.alicloud_zones.default.zones.0.id
   }
   
   # 建立安全性群組
   resource "alicloud_security_group" "default" {
     security_group_name   = "default"
     vpc_id = alicloud_vpc.vpc.id
   }
   
   # 建立安全性群組入方向規則
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.default.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   resource "alicloud_instance" "instance" {
     # 綁定安全性群組
     security_groups = alicloud_security_group.default.*.id
     instance_type = var.instance_type
     system_disk_category = var.disk_category
     image_id = var.image_id
     instance_name = var.instance_name
     # 所在交換器
     vswitch_id = alicloud_vswitch.vsw.id
     internet_max_bandwidth_out = var.internet_bandwidth
     password  = var.password
   }

   重要

   樣本中的安全性群組規則開放了所有 TCP 通訊埠（1-65535）且來源 IP 為 0.0.0.0/0，僅適用於測試環境。生產環境請根據實際需求限制連接埠範圍和來源 IP。

2. 初始化 Terraform 工作目錄：

   terraform init

3. 預覽執行計畫，確認將要建立的資源：

   terraform plan

   

4. 建立資源。輸出 Apply complete! 表示建立成功：

   terraform apply

   

5. 不再需要這些資源時，執行以下命令釋放：

   terraform destroy