全部產品
Search

搜尋本產品

    Key Management Service：通過Terraform建立應用存取點

    文件中心

    Key Management Service：通過Terraform建立應用存取點

    更新時間：Feb 13, 2025

    您可以通過Terraform建立並管理應用存取點。本文以建立應用存取點為例進行介紹。

    概述

    自建應用進行密碼運算操作、擷取憑據值前，需要通過應用存取點中的應用身份憑證（ClientKey）訪問KMS執行個體。

    說明

    如果您是通過雲產品加密使用KMS執行個體中密鑰，或者通過KMS SDK使用憑據，不需要建立應用存取點。如果需要通過KMS執行個體SDK調用KMS執行個體中的密鑰或憑據，則需要建立應用存取點。

    說明

    當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

    前提條件

    • 由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

    • 使用以下樣本為RAM使用者授權，需要為該RAM使用者授予以下許可權：AliyunKMSFullAccess（管理Key Management Service）許可權。具體操作方式請參見為RAM使用者授權。

      {
  "Version": "1",
  "Statement": [
    {
      "Effect": "Allow",
      "Action": [
        "kms:*"
      ],
      "Resource": [
        "*"
      ],
      "Condition": {}
    }
  ]
}

    • 準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。

      在Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。

      Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。

      在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

      重要

      請確保Terraform版本不低於v0.12.28。如需檢查現有版本，請運行terraform --version命令。

    使用的資源

    通過Terraform建立應用存取點

    本樣本將在KMS執行個體中建立一個應用存取點。

    1. 建立一個工作目錄，並且在工作目錄中建立以下名為main.tf的設定檔。main.tf是Terraform主檔案，定義了將要部署的資源。在此之前，請確保您已建立KMS執行個體：

      variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
variable "instance_name" {
  default = "tf-kms-vpc-172-16"
}
variable "instance_type" {
  default = "ecs.n1.tiny"
}
# 使用資料來源來擷取可用的可用性區域資訊。資源只能在指定的可用性區域內建立。
data "alicloud_zones" "default" {
  available_disk_category     = "cloud_efficiency"
  available_resource_creation = "VSwitch"
  available_instance_type     = var.instance_type
}
# 建立VPC
resource "alicloud_vpc" "vpc" {
  vpc_name   = var.instance_name
  cidr_block = "192.168.0.0/16"
}
# 建立一個Vswitch CIDR 塊為 192.168.10.0.24
resource "alicloud_vswitch" "vsw" {
  vpc_id     = alicloud_vpc.vpc.id
  cidr_block = "192.168.10.0/24"
  zone_id    = data.alicloud_zones.default.zones.0.id
  vswitch_name = "terraform-example-1"
}
# 建立另一個Vswitch CIDR 塊為 192.168.20.0/24
resource "alicloud_vswitch" "vsw1" {
  vpc_id     = alicloud_vpc.vpc.id
  cidr_block = "192.168.20.0/24"
  zone_id    = data.alicloud_zones.default.zones.0.id
  vswitch_name = "terraform-example-2"
}
# 建立KMS軟體密鑰管理執行個體，並使用網路參數啟動
resource "alicloud_kms_instance" "default" {
  # 軟體密鑰管理執行個體
  product_version = "3"
  vpc_id          = alicloud_vpc.vpc.id
  # 規定 KMS 執行個體所在的可用性區域，使用前面擷取的可用性區域 ID
  zone_ids = [
    "cn-heyuan-a",
    "cn-heyuan-b",
  ]
  # 交換器id
  vswitch_ids = [
    alicloud_vswitch.vsw.id,alicloud_vswitch.vsw1.id
  ]
  # 計算效能、密鑰數量、憑據數量、訪問管理數量
  vpc_num    = "1"
  key_num    = "1000"
  secret_num = "100"
  spec       = "1000"
  # 為KMS執行個體關聯其他VPC，選擇性參數
  # 如果VPC與KMS執行個體的VPC屬於不同阿里雲帳號，您需要先共用交換器。
  #bind_vpcs {
  #vpc_id = "vpc-j6cy0l32yz9ttxfy6****"
  #vswitch_id = "vsw-j6cv7rd1nz8x13ram****"
  #region_id = "cn-shanghai"
  #vpc_owner_id = "119285303511****"
  #}
  #bind_vpcs {
  #vpc_id = "vpc-j6cy0l32yz9ttd7g3****"
  #vswitch_id = "vsw-3h4yrd1nz8x13ram****"
  #region_id = "cn-shanghai"
  #vpc_owner_id = "119285303511****"
  #}
}
# 儲存KMS執行個體CA認證到本地檔案
 resource "local_file" "ca_certificate_chain_pem" {
 content  = alicloud_kms_instance.default.ca_certificate_chain_pem
 filename = "ca.pem"
}

      建立應用存取點：

      # 建立網路控制規則
resource "alicloud_kms_network_rule" "network_rule_example" {
  # 網路規則的名稱
  network_rule_name = "sample_network_rule"
  # 描述
  description = "description_test_module"
  # 允許的源私人IP位址範圍
  source_private_ip = ["172.16.0.0/12"]
}
# 建立存取控制策略
resource "alicloud_kms_policy" "policy_example" {
  # 策略名稱稱
  policy_name = "sample_policy"
  # 描述
  description = "description_test_module"
  # 定義的許可權列表，包括Data Encryption Service密鑰和Data Encryption Service密鑰的存取權限
  permissions = ["RbacPermission/Template/CryptoServiceKeyUser", "RbacPermission/Template/CryptoServiceSecretUser"]
  # 資源清單，指向所有密鑰和憑據
  resources = ["key/*", "secret/*"]
  # KMS執行個體的ID
  kms_instance_id = alicloud_kms_instance.default.id
  # 存取控制規則，以JSON格式提供，引用先前定義的網路規則
  access_control_rules = <<EOF
  {
      "NetworkRules":[
          "alicloud_kms_network_rule.network_rule_example.network_rule_name"
      ]
  }
  EOF
}

# 建立應用存取點的資源定義
resource "alicloud_kms_application_access_point" "application_access_point_example" {
  # 應用存取點的名稱
  application_access_point_name = "sample_aap"
  # 關聯的策略列表，引用之前建立的存取控制策略名稱稱
  policies = [alicloud_kms_policy.policy_example.policy_name]
  # 應用存取點的描述
  description = "aap_description"
}

# 建立應用身份憑證的資源定義
resource "alicloud_kms_client_key" "client_key" {
  # 指定應用存取點的名稱
  aap_name = alicloud_kms_application_access_point.application_access_point_example.application_access_point_name
  # 身份憑證的密碼,替換為您的密碼
  password = "testPassword@"
  # 身份憑證的有效開始時間
  not_before = "2023-09-01T14:11:22Z"
  not_after  = "2032-09-01T14:11:22Z"
  # 設定儲存應用身份憑證的本地檔案地址
  private_key_data_file = "./client_key.json"

}
      重要

      • 應用存取點建立成功後，請您在自己設定的本地檔案地址擷取應用身份憑證，並妥善儲存。

      • password可通過Terraform的敏感輸入參數方式設定。

    2. 執行以下命令，初始化Terraform運行環境。

      terraform init

      返回如下資訊，表示Terraform初始化成功。

      Initializing the backend...

Initializing provider plugins...
- Reusing previous version of hashicorp/alicloud from the dependency lock file
- Using previously-installed hashicorp/alicloud v1.231.0

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

    3. 建立執行計畫，並預覽變更。

      terraform plan

    4. 執行以下命令，建立應用存取點。

      terraform apply

      在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示應用存取點建立成功。

      Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

...
alicloud_kms_network_rule.network_rule_example: Creating...
alicloud_kms_policy.policy_example: Creating...
alicloud_kms_network_rule.network_rule_example: Creation complete after 0s [id=sample_network_***]
alicloud_kms_policy.policy_example: Creation complete after 0s [id=sample_pol***]
alicloud_kms_application_access_point.application_access_point_example: Creating...
alicloud_kms_application_access_point.application_access_point_example: Creation complete after 0s [id=sample_***]
alicloud_kms_client_key.client_key: Creation complete after 0s [id=KAAP.5093ea57-0b84-4455-a8e9-7679bdc****]
...

Apply complete! Resources: 4 added, 0 changed, 0 destroyed.

    5. 驗證結果

      執行terraform show命令

      您可以使用以下命令查詢Terraform已建立的資來源詳細資料：

      terraform show

      image

      登入Key Management Service控制台

      登入Key Management Service控制台，查看已建立的應用存取點。image

    清理資源

    當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

    terraform destroy

    完整樣本

    說明

    當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

    範例程式碼

    variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
variable "instance_name" {
  default = "tf-kms-vpc-172-16"
}
variable "instance_type" {
  default = "ecs.n1.tiny"
}
# 使用資料來源來擷取可用的可用性區域資訊。資源只能在指定的可用性區域內建立。
data "alicloud_zones" "default" {
  available_disk_category     = "cloud_efficiency"
  available_resource_creation = "VSwitch"
  available_instance_type     = var.instance_type
}
# 建立VPC
resource "alicloud_vpc" "vpc" {
  vpc_name   = var.instance_name
  cidr_block = "192.168.0.0/16"
}
# 建立一個Vswitch CIDR 塊為 192.168.10.0.24
resource "alicloud_vswitch" "vsw" {
  vpc_id     = alicloud_vpc.vpc.id
  cidr_block = "192.168.10.0/24"
  zone_id    = data.alicloud_zones.default.zones.0.id
  vswitch_name = "terraform-example-1"
}
# 建立另一個Vswitch CIDR 塊為 192.168.20.0/24
resource "alicloud_vswitch" "vsw1" {
  vpc_id     = alicloud_vpc.vpc.id
  cidr_block = "192.168.20.0/24"
  zone_id    = data.alicloud_zones.default.zones.0.id
  vswitch_name = "terraform-example-2"
}
# 建立KMS軟體密鑰管理執行個體，並使用網路參數啟動
resource "alicloud_kms_instance" "default" {
  # 軟體密鑰管理執行個體
  product_version = "3"
  vpc_id          = alicloud_vpc.vpc.id
  # 規定 KMS 執行個體所在的可用性區域，使用前面擷取的可用性區域 ID
  zone_ids = [
    "cn-heyuan-a",
    "cn-heyuan-b",
  ]
  # 交換器id
  vswitch_ids = [
    alicloud_vswitch.vsw.id,alicloud_vswitch.vsw1.id
  ]
  # 計算效能、密鑰數量、憑據數量、訪問管理數量
  vpc_num    = "1"
  key_num    = "1000"
  secret_num = "100"
  spec       = "1000"
  # 為KMS執行個體關聯其他VPC，選擇性參數
  # 如果VPC與KMS執行個體的VPC屬於不同阿里雲帳號，您需要先共用交換器。
  #bind_vpcs {
  #vpc_id = "vpc-j6cy0l32yz9ttxfy6****"
  #vswitch_id = "vsw-j6cv7rd1nz8x13ram****"
  #region_id = "cn-shanghai"
  #vpc_owner_id = "119285303511****"
  #}
  #bind_vpcs {
  #vpc_id = "vpc-j6cy0l32yz9ttd7g3****"
  #vswitch_id = "vsw-3h4yrd1nz8x13ram****"
  #region_id = "cn-shanghai"
  #vpc_owner_id = "119285303511****"
  #}
}
# 儲存KMS執行個體CA認證到本地檔案
 resource "local_file" "ca_certificate_chain_pem" {
 content  = alicloud_kms_instance.default.ca_certificate_chain_pem
 filename = "ca.pem"
}
# 建立網路控制規則
resource "alicloud_kms_network_rule" "network_rule_example" {
  # 網路規則的名稱
  network_rule_name = "sample_network_rule"
  # 描述
  description = "description_test_module"
  # 允許的源私人IP位址範圍
  source_private_ip = ["172.16.0.0/12"]
}

# 建立存取控制策略
resource "alicloud_kms_policy" "policy_example" {
  # 策略名稱稱
  policy_name = "sample_policy"
  # 描述
  description = "description_test_module"
  # 定義的許可權列表，包括Data Encryption Service密鑰和Data Encryption Service密鑰的存取權限
  permissions = ["RbacPermission/Template/CryptoServiceKeyUser", "RbacPermission/Template/CryptoServiceSecretUser"]
  # 資源清單，指向所有密鑰和憑據
  resources = ["key/*", "secret/*"]
  # KMS執行個體的ID
  kms_instance_id = alicloud_kms_instance.default.id
  # 存取控制規則，以JSON格式提供，引用先前定義的網路規則
  access_control_rules = <<EOF
  {
      "NetworkRules":[
          "alicloud_kms_network_rule.network_rule_example.network_rule_name"
      ]
  }
  EOF
}

# 建立應用存取點的資源定義
resource "alicloud_kms_application_access_point" "application_access_point_example" {
  # 應用存取點的名稱
  application_access_point_name = "sample_aap"
  # 關聯的策略列表，引用之前建立的存取控制策略名稱稱
  policies = [alicloud_kms_policy.policy_example.policy_name]
  # 應用存取點的描述
  description = "aap_description"
}

# 建立應用身份憑證的資源定義
resource "alicloud_kms_client_key" "client_key" {
  # 指定應用存取點的名稱
  aap_name = alicloud_kms_application_access_point.application_access_point_example.application_access_point_name
  # 身份憑證的密碼,替換為您的密碼
  password = "testPassword@"
  # 身份憑證的有效開始時間
  not_before = "2023-09-01T14:11:22Z"
  not_after  = "2032-09-01T14:11:22Z"
  # 設定儲存應用身份憑證的本地檔案地址
  private_key_data_file = "./client_key.json"
}