Elastic Compute Service：Terraform參考

Terraform準系統

Terraform是IT基礎架構自動化編排工具，可以用代碼來管理維護IT資源。更多資訊，請參見Terraform產品介紹。

• Terraform的命令列介面CLI（Command Line Interface）提供一種簡單機制，用於將設定檔部署到阿里雲或其他任意支援的雲上，並對其進資料列版本設定。它編寫了描述雲資源拓撲的設定檔中的基礎結構，例如虛擬機器、儲存賬戶和網路介面。

• Terraform通過Provider支援新的基礎架構，讓您在阿里雲上能夠便於使用簡單範本語言來定義、預覽和部署雲基礎結構。

• Terraform可以建立、修改和刪除多種阿里雲產品的相關資源。

關於阿里雲與Terraform整合的更多資訊，請參見Alibaba Cloud Provider。

Terraform安裝

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Terraform 身份認證

基於環境變數配置身份認證是將訪問憑證儲存在特定的環境變數中，當執行Terraform命令時，如果配置模板中沒有顯式聲明訪問憑證，那麼將嘗試從如下的環境變數中擷取。具體環境變數的設定方式如下：

# Access Key Id
$ export ALICLOUD_ACCESS_KEY="<你的 Access Key ID>"
# Access Key Secret
$ export ALICLOUD_SECRET_KEY="<你的 Access Key Secret>"
# 如果是 STS 的訪問憑證，此處需要配置 security_token
$ export ALICLOUD_SECURITY_TOKEN="<你的訪問 Token>"

設定了環境變數之後，provider塊可以不在配置模板中顯式聲明或者只聲明地區資訊：

provider "alicloud" {
  region = "cn-hangzhou"
}

當然，region也是支援通過環境變數 ALICLOUD_REGION進行配置的。如果 region 沒有顯式聲明也沒有配置環境變數，cn-beijing 將是其預設配置值。

支援的資源清單

使用Terraform建立並管理ECS

下文以建立ECS為例，介紹如何使用Terraform建立並管理ECS資源。

1. 建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔。以下代碼將建立一個ECS執行個體，以及建立ECS執行個體所需的VPC、安全性群組與交換器資源。將以下代碼複製到main.tf中。

   # 定義一個變數region，預設值為"cn-beijing"，用於指定阿里雲地區
   variable "region"{
     default = "cn-beijing"
   }
   
   # 配置阿里雲provider，使用變數region中定義的地區
   provider "alicloud"{
     region = var.region
   }
   
   # 定義一個字串類型的變數instance_type，預設值為"ecs.e-c1m1.large"，用於指定ECS執行個體類型
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # 使用資料來源查詢可用性區域資訊，通過指定的執行個體類型、資源建立類型（如VSwitch）以及磁碟種類來過濾結果
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # 定義一個變數vpc_cidr_block，預設值為"172.16.0.0/16"，用於指定VPC的CIDR塊
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # 定義一個變數vsw_cidr_block，預設值為"172.16.0.0/24"，用於指定VSwitch的CIDR塊
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # 產生一個介於10000到99999之間的隨機整數，用於確保某些資源名稱的唯一性
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # 建立名為vpc-test的VPC，並使用隨機整數確保名稱唯一性
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # 建立安全性群組，名稱包含隨機整數以保證唯一性，並關聯至上述VPC
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # 替換了這裡的欄位名
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # 建立一條允許所有TCP流量進入的安全性群組規則，與之前建立的安全性群組關聯
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # 修改了這裡，將nic_type改為'intranet'
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # 建立VSwitch，名稱中包含隨機整數以確保唯一性，並與VPC、可用性區域關聯
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # 建立ECS執行個體，設定多個參數如可用性區域、安全性群組、執行個體類型等，並使用隨機整數保證執行個體名稱的唯一性
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # 使用者根據自己實際情況修改
   }

2. 執行如下命令，初始化Terraform運行環境。

   terraform init

   返回資訊如下，則Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 執行如下命令，開始執行代碼。

   terraform apply

   在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示代碼執行成功。

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

4. 結果驗證

terraform show

相關文檔

• 更多實踐教程，請參見Terraform的教程。

• 更多Terraform的常用命令，請參見常用命令。

• ROS提供了Terraform託管服務，因此您可以直接在ROS控制台部署Terraform模板。詳細操作，請參見建立Terraform類型資源棧。