通過Terraform建立ACS叢集-容器計算服務-阿里雲

本文介紹如何使用Terraform建立ACS叢集。

前提條件

已開通容器計算服務ACS。
由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

為運行Terraform命令的RAM使用者綁定以下最小權限原則，以擷取管理本樣本所涉及資源的許可權。更多資訊，請參見為RAM使用者授權。

該權限原則允許RAM使用者進行ACS叢集以及依賴雲產品資源的建立、查看與刪除操作。

{
  "Version": "1",
  "Statement": [
    {
      "Effect": "Allow",
      "Action": [
        "cs:CreateCluster",
        "cs:DescribeTaskInfo",
        "cs:DescribeClusterDetail",
        "cs:GetClusterCerts",
        "cs:CheckControlPlaneLogEnable",
        "cs:DeleteCluster",
        "cs:GetClusterAuditProject",
        "cs:ModifyCluster",
        "vpc:DescribeNatGateways"
      ],
      "Resource": "*"
    }
  ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
  - RAM使用者或角色使用Cloud Shell，需要主帳號參考身份管理對RAM使用者或角色授權許可權。
- 在Resource Orchestration Service（ROS）中使用Terraform：Resource Orchestration Service服務（ROS）為Terraform提供了託管的能力，您可以建立Terraform類型的模板，定義阿里雲、AWS或Azure資源，配置資源參數和資源間的依賴關係。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。
重要
請確保版本不低於v0.12.28。如需檢查現有版本，請運行terraform --version命令。

使用的資源

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

alicloud_cs_managed_kubernetes：以建立ACK託管版叢集為基礎，建立ACS叢集。

使用Terraform建立ACS叢集

本樣本將建立一個包含為該叢集預設安裝一系列組件，包括managed-csiprovisioner（儲存群組件）、ebs-token-controller（儲存群組件）、alibaba-log-controller（日誌採集組件）、arms-prometheus（監控組件）等的ACS叢集。

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下參考代碼複製到main.tf中，請根據需要修改。

provider "alicloud" {
  region      = var.region_id
}
variable "region_id" {
  type        = string
  default     = "cn-guangzhou"
}
variable "availability_zone" {
  type        = list(string)
  description = "The availability zones of vswitches."
  default     = ["cn-guangzhou-a", "cn-guangzhou-b"]
}
variable "k8s_name_prefix" {
  description = "The name prefix used to create ACS cluster."
  default     = "acs-example"
}
variable "acs_version" {
  type        = string
  description = "Desired Kubernetes version. "
  default     = "1.31.1-aliyun.1"      # 請按需修改
}
variable "service_cidr" {
  type        = string
  description = "The Kubernetes services CIDR. "
  default     = "10.13.0.0/16"      # 請按需修改
}

# 指定ACS叢集安裝的組件。包括alibaba-log-controller（日誌採集組件）、arms-prometheus（監控組件）、managed-coredns、managed-metrics-server。
variable "cluster_addons" {   # 請按需修改
  type = list(object({
    name   = string
    config = string
  }))
  default = [
    {
      "name"   = "arms-prometheus",
      "config" = "",
    },
    {
      "name"   = "alibaba-log-controller",
      "config" = "",
    },
    {
      "name"   = "managed-coredns",
      "config" = "",
    },
    {
      "name"   = "managed-metrics-server",
      "config" = "",
    }
  ]
}
# 預設資源名稱。
locals {
  k8s_name_acs     = substr(join("-", [var.k8s_name_prefix, "acs"]), 0, 63)
  log_project_name = "log-for-${local.k8s_name_acs}"
}

# 建立ACS叢集。
resource "alicloud_cs_managed_kubernetes" "default" {
  name                         = local.k8s_name_acs   # Kubernetes叢集名稱。
  cluster_spec                 = "ack.pro.small"
  profile                      = "Acs"
  version                      = var.acs_version # 替換為您所需建立的叢集版本。 
  zone_ids                     = var.availability_zone
  is_enterprise_security_group = true
  control_plane_log_ttl        = "30"    
  new_nat_gateway              = true   # 是否在建立Kubernetes叢集時建立新的NAT Gateway。預設為true。                                                           
  control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"] # 控制平面日誌。
  deletion_protection          = true
  # 通過RRSA配置ServiceAccount。
  enable_rrsa                  = true
  timezone                     = "Asia/Shanghai"
  service_cidr                 = var.service_cidr  # 請按需修改
  slb_internet_enabled         = false  # 是否為API Server建立Internet負載平衡。預設為false。
  dynamic "addons" {  # 組件管理。
    for_each = var.cluster_addons
    content {
      name   = lookup(addons.value, "name", var.cluster_addons)
      config = lookup(addons.value, "config", var.cluster_addons)
    }
  }
}

說明

該設定檔僅為參考，請根據實際需要修改。

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

建立執行計畫，並預覽變更。

terraform plan

執行以下命令，建立叢集。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示ACS叢集建立成功。

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

...
alicloud_cs_managed_kubernetes.default: Creation complete after 5m48s [id=ccb53e72ec6c447c990762800********]
...

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

驗證結果

執行terraform show命令

您可以使用以下命令查詢Terraform已建立資源的詳細資料。

terraform show

登入ACS控制台

登入容器計算服務控制台，查看已建立的叢集。

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行terraform destroy命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy