通過Terraform建立、刪除及查詢Kafka Topic - ApsaraMQ for Kafka

Topic是ApsaraMQ for Kafka裡對訊息進行的一級歸類，使用Kafka的第一步就是先為您的應用建立Topic。本文介紹如何通過Terraform提供的alicloud_alikafka_topic資源建立、刪除及查詢Topic。

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

前提條件

由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式請參見建立RAM使用者和建立AccessKey。

通過RAM授權，阿里雲使用者可以有效地管理其雲資源存取權限，適應多使用者協同工作的需求，並且能夠按需為使用者指派最小許可權，避免許可權過大導致的安全性漏洞‌。具體操作方式請參見為RAM使用者授權。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "ecs:CreateSecurityGroup",
                "ecs:ModifySecurityGroupPolicy",
                "ecs:DescribeSecurityGroups",
                "ecs:ListTagResources",
                "ecs:DeleteSecurityGroup",
                "ecs:DescribeSecurityGroupAttribute",
                "ecs:AuthorizeSecurityGroup",
                "ecs:RevokeSecurityGroup"
            ],
            "Resource": "*"
        },
        {
            "Action": "alikafka:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "connector.alikafka.aliyuncs.com",
                        "instanceencryption.alikafka.aliyuncs.com",
                        "alikafka.aliyuncs.com",
                        "etl.alikafka.aliyuncs.com"
                    ]
                }
            }
        }
    ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

使用的資源

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

alicloud_vpc：建立一個Virtual Private Cloud。
alicloud_vswitch：建立一個專用網路交換器。
alicloud_security_group：建立一個安全性群組。
alicloud_alikafka_instance：建立一個Kafka執行個體。
alicloud_alikafka_topic：建立一個Kafka Topic。
alicloud_alikafka_topics：查詢Kafka Topic。

建立Topic

本樣本以在華南1（深圳）地區下建立Topic為例，Topic名稱為example-topic。Topic建立完成後不支援修改名稱。

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔，然後將以下代碼複製到main.tf中。

建立前置資源。

variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立安全性群組。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# 建立執行個體，磁碟類型為高效雲端硬碟，磁碟容量為500 GB，流量規格為alikafka.hw.2xlarge。
# 部署執行個體。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

在main.tf檔案中增加resource "alicloud_alikafka_topic" "default" {}配置項。

variable "partition_num" {
  default = "12"
}

variable "remark" {
  default = "kafka_topic_remark"
}

resource "alicloud_alikafka_topic" "default" {
  instance_id   = alicloud_alikafka_instance.default.id
  topic         = "example-topic"
  local_topic   = "false"
  compact_topic = "false"
  partition_num = var.partition_num
  remark        = var.remark
}

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the
following symbols:
  + create

Terraform will perform the following actions:

  # alicloud_alikafka_topic.default will be created
  + resource "alicloud_alikafka_topic" "default" {
      + compact_topic = false
      + id            = (known after apply)
      + instance_id   = "alikafka_post-cn-****"
      + local_topic   = false
      + partition_num = 12
      + remark        = "kafka_topic_remark"
      + topic         = "example-topic"
    }

Plan: 1 to add, 0 to change, 0 to destroy.

Changes to Outputs:
  + partition_num = (known after apply)

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_alikafka_topic.default: Creating...
alicloud_alikafka_topic.default: Creation complete after 8s [id=alikafka_post-cn-****:example-topic]

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

驗證結果。

執行terraform show命令

執行terraform show查看Kafka Topic資訊。

terraform show

# alicloud_alikafka_topic.default:
resource "alicloud_alikafka_topic" "default" {
    compact_topic = false
    id            = "alikafka_post-cn-****:example-topic"
    instance_id   = "alikafka_post-cn-****"
    local_topic   = false
    partition_num = 12
    remark        = "kafka_topic_remark"
    topic         = "example-topic"
}

登入雲訊息佇列 Kafka 版控制台

登入雲訊息佇列 Kafka 版控制台，查看Kafka Topic資訊。

更新Topic

本樣本以修改Topic的分區數和備忘為例。

在上述main.tf檔案中，修改variable "partition_num"與variable "remark"的default參數值，具體配置如下。

variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

variable "partition_num" {
  default = "24"
}

variable "remark" {
  default = "updated_kafka_topic_remark"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立安全性群組。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# 建立執行個體，磁碟類型為高效雲端硬碟，磁碟容量為500 GB，流量規格為alikafka.hw.2xlarge。
# 部署執行個體。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

resource "alicloud_alikafka_topic" "default" {
  instance_id   = alicloud_alikafka_instance.default.id
  topic         = "example-topic"
  local_topic   = "false"
  compact_topic = "false"
  partition_num = var.partition_num
  remark        = var.remark
}

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]
alicloud_alikafka_topic.default: Refreshing state... [id=alikafka_post-cn-****:example-topic]

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the
following symbols:
  ~ update in-place

Terraform will perform the following actions:

  # alicloud_alikafka_topic.default will be updated in-place
  ~ resource "alicloud_alikafka_topic" "default" {
        id            = "alikafka_post-cn-****:example-topic"
      ~ partition_num = 12 -> 24
      ~ remark        = "kafka_topic_remark" -> "updated_kafka_topic_remark"
        tags          = {}
        # (4 unchanged attributes hidden)
    }

Plan: 0 to add, 1 to change, 0 to destroy.

Changes to Outputs:
  ~ partition_num = "12" -> "24"
  ~ remark        = "kafka_topic_remark" -> "updated_kafka_topic_remark"

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_alikafka_topic.default: Modifying... [id=alikafka_post-cn-****:example-topic]
alicloud_alikafka_topic.default: Modifications complete after 2s [id=alikafka_post-cn-****:example-topic]

Apply complete! Resources: 0 added, 1 changed, 0 destroyed.

驗證結果。

執行terraform show命令

執行terraform show查看修改後的Kafka Topic資訊。

terraform show

# alicloud_alikafka_topic.default:
resource "alicloud_alikafka_topic" "default" {
    compact_topic = false
    id            = "alikafka_post-cn-****:example-topic"
    instance_id   = "alikafka_post-cn-****"
    local_topic   = false
    partition_num = 24
    remark        = "updated_kafka_topic_remark"
    tags          = {}
    topic         = "example-topic"
}

登入雲訊息佇列 Kafka 版控制台

登入雲訊息佇列 Kafka 版控制台，查看Kafka Topic資訊。

查詢Topic

在上述main.tf檔案中，增加data "alicloud_alikafka_topics" "topics_ds" 配置項，具體配置如下。
```
data "alicloud_alikafka_topics" "topics_ds" {
  instance_id = alicloud_alikafka_instance.default.id
}
```
建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立資源。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示運行成功。

No changes. Your infrastructure matches the configuration.

Terraform has compared your real infrastructure against your configuration and found no differences, so no changes are needed.

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

Outputs:

first_topic_name = "testtopic"

驗證結果。執行terraform show查看Kafka Topic資訊。

terraform show

# data.alicloud_alikafka_topics.topics_ds:
data "alicloud_alikafka_topics" "topics_ds" {
    id          = "29****"
    ids         = [
        "alikafka_post-cn-****:example-topic",
    ]
    instance_id = "alikafka_post-cn-****"
    names       = [
        null,
    ]
    output_file = "topics.txt"
    page_size   = 50
    topics      = [
        {
            compact_topic = false
            create_time   = "1732****"
            id            = "alikafka_post-cn-****:example-topic"
            instance_id   = "alikafka_post-cn-****"
            local_topic   = false
            partition_num = 24
            remark        = "updated_kafka_topic_remark"
            status        = 0
            status_name   = "服務中"
            tags          = {}
            topic         = "example-topic"
        },
    ]
    total_count = 1
}

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

variable "partition_num" {
  default = "12"
}

variable "remark" {
  default = "kafka_topic_remark"
}

provider "alicloud" {
  region = var.region
}

# 建立VPC
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 建立交換器
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 建立安全性群組。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# 建立執行個體，磁碟類型為高效雲端硬碟，磁碟容量為500 GB，流量規格為alikafka.hw.2xlarge。
# 部署執行個體。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

# 建立Kafka Topic
resource "alicloud_alikafka_topic" "default" {
  instance_id   = alicloud_alikafka_instance.default.id
  topic         = "example-topic"
  local_topic   = "false"
  compact_topic = "false"
  partition_num = var.partition_num
  remark        = var.remark
}

# 查詢Kafka Topic
data "alicloud_alikafka_topics" "topics_ds" {
  instance_id = alicloud_alikafka_instance.default.id
  depends_on = [alicloud_alikafka_topic.default]
}

ApsaraMQ for Kafka：通過 Terraform 管理 Kafka Topic

前提條件

使用的資源

建立Topic

執行terraform show命令

登入雲訊息佇列 Kafka 版控制台

更新Topic

執行terraform show命令

登入雲訊息佇列 Kafka 版控制台

查詢Topic

清理資源

完整樣本

範例程式碼

相關文檔