Virtual Private Cloud:VPC ピアリング接続

ピアリング接続の作成

1. CreateVpcPeerConnection を呼び出して VPC ピアリング接続を作成します。

2. 2 つの VPC が異なるアカウントに属している場合、受信側アカウントを使用して AcceptVpcPeerConnection を呼び出してリクエストを承諾します。

   受信側は RejectVpcPeerConnection を呼び出して接続リクエストを拒否できます。

3. リクエスト元または受信側アカウントのいずれかを使用して GetVpcPeerConnectionAttribute を呼び出し、それぞれの VPC の CIDR ブロックを取得します。

4. リクエスト元または受信側アカウントのいずれかを使用して CreateRouteEntry を呼び出し、ピアリング接続を指すルートを作成します。

リージョン間ピアリング接続の変更

ModifyVpcPeerConnection を呼び出して、リージョン間 VPC ピアリング接続の帯域幅またはリンクタイプを変更します。

ピアリング接続の削除

• DeleteRouteEntry を呼び出して、ピアリング接続を指すルートを削除します。

• DeleteVpcPeerConnection を呼び出して、VPC ピアリング接続を削除します。

到達可能性アナライザー

到達可能性アナライザーを使用して接続性を確認するには、次の API 操作を順番に呼び出します。

1. CreateNetworkPath - ネットワーク分析パスを作成します

2. CreateNetworkReachableAnalysis - ネットワーク到達可能性分析タスクを作成します

3. GetNetworkReachableAnalysis - ネットワーク到達可能性分析タスクの結果を取得します

同一アカウントのピアリング接続

リソース: alicloud_vpc_peer_connection, alicloud_route_entry

データソース: alicloud_account

# VPC が属するアカウント
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元 VPC があるリージョン。
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # 受信側 VPC のリージョン。リクエスト元 VPC のリージョンと同じにすることができます。受信側 VPC のリージョンに基づいて構成します。
}

# リクエスト元 VPC ID
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# 受信側 VPC ID
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# VPC ピアリング接続の作成
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # リクエスト元 VPC ID
  accepting_ali_uid    = data.alicloud_account.default.id # 受信側アカウント ID   
  accepting_region_id  = "cn-beijing"                     # 受信側 VPC があるリージョン
  accepting_vpc_id     = var.accepting_vpc_id             # 受信側 VPC ID
  bandwidth            = 1024                             # 帯域幅 (Mbit/s)。このパラメーターは、リクエスト元リージョンと受信側リージョンが異なる場合にのみ構成できます。
  link_type            = "Gold"                           # リンクタイプ。このパラメーターは、リクエスト元リージョンと受信側リージョンが異なる場合にのみ構成できます。
}

# リクエスト元 VPC のルートを構成
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # リクエスト元インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "172.16.0.0/12"             # 受信側 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 受信側 VPC のルートを構成
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # 受信側インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "10.0.0.0/8"                # リクエスト元 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

クロスアカウントのピアリング接続

リソース: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元 VPC のリージョン 
}

# 受信側 VPC のリージョン。リクエスト元 VPC のリージョンと同じにすることができます。受信側 VPC のリージョンに基づいて構成する必要があります。
variable "accepting_region" {
  default = "cn-beijing"
}

# 受信側アカウント
variable "accepting_uid" {
  default = "1234******"
}

# 受信側アカウントの AccessKey ID
variable "access_key_id" {
  description = "インフラストラクチャを操作するための AccessKey ID"
}
# 受信側アカウントの AccessKey シークレット
variable "access_key_secret" {
  description = "インフラストラクチャを操作するための AccessKey シークレット"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# リクエスト元 VPC ID
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# 受信側 VPC ID
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# VPC ピアリング接続の作成
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # リクエスト元 VPC ID
  accepting_ali_uid    = var.accepting_uid    # 受信側アカウント ID   
  accepting_region_id  = var.accepting_region # 受信側リージョン
  accepting_vpc_id     = var.accepting_vpc_id # 受信側 VPC ID
  bandwidth            = 1024                 # 帯域幅 (Mbit/s)。このパラメーターは、リクエスト元リージョンと受信側リージョンが異なる場合にのみ構成できます。
  link_type            = "Gold"               # リンクタイプ。このパラメーターは、リクエスト元リージョンと受信側リージョンが異なる場合にのみ構成できます。
}

# 受信側がピアリング接続リクエストを承諾
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# リクエスト元 VPC のルートを構成
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # リクエスト元インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "192.168.0.0/24" # 受信側 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# 受信側 VPC のルートを構成
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # 受信側インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "172.16.0.0/12"  # リクエスト元 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

ピアリング接続の監視

1. VPC コンソールの VPC コンソール - VPC ピアリング接続 ページに移動します。上部のナビゲーションバーで、VPC があるリージョンを選択します。

2. 対象のリージョン間 VPC ピアリング接続の [モニタリング] 列にある アイコンをクリックすると、帯域幅やパケット損失などのメトリックを表示できます。

CloudMonitor アラート

1. CloudMonitor コンソールの [アラートルール] ページに移動し、アラートルールの作成 をクリックします。

2. VPC ピアリング接続メトリックの各アラートレベルのしきい値を構成します。メトリックがしきい値に達すると、指定された [アラート連絡先グループ] にアラート通知が送信されます。また、アラートルールの [操作] 列にある [アラート履歴] をクリックして、アラートのタイムラインを表示することもできます。

3. [操作] 列でアラートルールを [変更]、[無効化]、または [削除] できます。