Virtual Private Cloud:VPC と vSwitch

コンソール

API

コンソールで VPC を作成する場合とは異なり、CreateVpc 操作では空の VPC のみが作成されます。 vSwitch を作成するには、CreateVSwitch 操作を呼び出す必要があります。

• CreateVpc と CreateVSwitch を順番に呼び出します。

• VPC を作成した後、ModifyVpcAttribute 操作の CidrBlock パラメーターを変更して、元の IPv4 CIDR ブロックを拡大または縮小します。 縮小する場合は、新しい CIDR ブロック外の IP をアクティブなリソースが使用していないことを確認してください。

• vSwitch の IPv4 CIDR ブロックは変更できません。

• vSwitch と VPC を削除するには、DeleteVSwitch と DeleteVpc を順番に呼び出します。

  1. vSwitch が共有されておらず、カスタムルートテーブルまたはネットワーク ACL に接続されておらず、vSwitch 内のすべてのクラウド リソースがリリースされていることを確認します。

  2. VPC 内のすべてのリソースがリリースされており、VPC が Cloud Enterprise Network (CEN) などのネットワーク サービスに関連付けられていないことを確認します。

Terraform

リソース: alicloud_vpc、alicloud_vswitch

データソース: alicloud_zones

# VPC が作成されるリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou"
}

# データソースに基づいて、vSwitch を作成できるゾーンのリストを自動的に取得します
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # vSwitch を作成できるゾーンをクエリします
  // available_instance_type = "ecs.g7.large"  // ECS インスタンスを作成できるゾーンをクエリします
  // available_resource_creation = "slb"  // SLB インスタンスを作成できるゾーンをクエリします
}

# VPC を作成します
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # CIDR ブロックを指定します
}

# vSwitch を作成します
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # CIDR ブロックを指定します
  vpc_id       = alicloud_vpc.example_vpc.id                       # vSwitch が属する VPC の ID を指定します
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # vSwitch ゾーンを指定します
}

コンソール

API

• VPC と vSwitch を作成する際に、CreateVpc と CreateVSwitch の EnableIPv6 パラメーターを設定して、IPv6 を有効または無効にします。

• 既存の VPC と vSwitch の場合は、ModifyVpcAttribute と ModifyVSwitchAttribute の EnableIPv6 パラメーターを設定して、IPv6 を有効または無効にします。

Terraform

リソース: alicloud_vpc、alicloud_vswitch

データソース: alicloud_zones

# VPC が作成されるリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou"
}

// データソースに基づいて、vSwitch を作成できるゾーンのリストを自動的に取得します
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" // VPC 内に vSwitch を作成できるゾーンをクエリします
  // available_instance_type = "ecs.g7.large"  // VPC 内に ECS インスタンスを作成できるゾーンをクエリします
  // available_resource_creation = "slb"  // VPC 内に SLB インスタンスを作成できるゾーンをクエリします
}

// デュアルスタック VPC を作成します
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  // IPv6 を有効にします。無効にするには false に設定します
  ipv6_isp    = "BGP" // IPv6 CIDR ブロックタイプを指定します
}

// デュアルスタック vSwitch を作成します
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true // IPv6 を有効にします。無効にするには false に設定します
  ipv6_cidr_block_mask = 1    // vSwitch IPv6 CIDR ブロックの最後の 8 ビットを指定します
}

コンソール

API

• AssociateVpcCidrBlock を呼び出して、セカンダリ CIDR ブロックを追加します。

• UnassociateVpcCidrBlock を呼び出して、セカンダリ CIDR ブロックを削除します。

Terraform

Terraform は現在、IPv4 セカンダリ CIDR ブロックのみをサポートしています。

リソース: alicloud_vpc_ipv4_cidr_block

# VPC が作成されるリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou"
}

# VPC ID を指定します
variable "vpc_id" {
  default = "vpc-xxx" # 実際の VPC ID に置き換えます
}

# VPC にセカンダリ CIDR ブロックを作成します
resource "alicloud_vpc_ipv4_cidr_block" "example_secondary_cidr_block" {
  vpc_id               = var.vpc_id
  secondary_cidr_block = "192.168.0.0/16" # セカンダリ CIDR ブロックを指定します
}

コンソール

API

• 予約済み CIDR ブロックを作成するには、CreateVSwitchCidrReservation を呼び出します。

• 占有 IP を表示するには、GetVSwitchCidrReservationUsage を呼び出します。

• 予約済み CIDR ブロックを削除するには、DeleteVSwitchCidrReservation を呼び出します。

Terraform

リソース: alicloud_vpc_vswitch_cidr_reservation

# VPC が作成されるリージョンを指定します
provider "alicloud" {
  region = "cn-hangzhou" # リソースが配置されているリージョン
}

# vSwitch ID を指定します
variable "vsw_id" {
  default = "vsw-xxx" # 実際の vSwitch ID に置き換えます
}

# 予約済み CIDR ブロックを作成します
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 予約済み CIDR ブロックを指定します
}

コンソール

VPC コンソールの VPC の作成 ページに移動し、[IPAM によって割り当てられた IPv4 CIDR ブロック] を使用して、IPAM プールを選択し、サブネットマスクを構成して IPAM プールから CIDR ブロックを割り当てます。

サブネットマスクを構成すると、システムは指定されたサブネットマスク範囲内で最初に使用可能な CIDR ブロックを自動的に割り当てます。 また、IPAM プールでプロビジョニングされた CIDR ブロック内で IPv4 CIDR ブロックを調整することもできます。

VPC を作成する前に、IPAM コンソールで IPAM と IPAM プールを作成済みであることを確認してください。

API

• IPAM プールをすでに作成している場合は、CreateVpc を呼び出すときに Ipv4IpamPoolId パラメーターを渡して IPAM プールを指定し、Ipv4CidrMask パラメーターを渡して、IPAM プールからアドレスを新しい VPC の CIDR ブロックとして割り当てるサブネットマスクを指定します。 サブネットマスクを指定して CIDR ブロックを自動的に割り当てる代わりに、CidrBlock パラメーターを渡して VPC CIDR ブロックを指定することもできます。

• IPAM プールを作成していない場合は、次の API 操作を順番に呼び出して IPAM プールを作成し、上記のように VPC を作成します。

  1. OpenVpcIpamService - IPAM をアクティブ化する

  2. CreateIpam - IPAM インスタンスを作成する

  3. CreateIpamPool - IPAM プールを作成する

  4. AddIpamPoolCidr - IPAM プールに CIDR ブロックをプロビジョニングする

Terraform

リソース: vpc_ipam_ipam、alicloud_vpc_ipam_ipam_pool、alicloud_vpc_ipam_ipam_pool_cidr、alicloud_vpc

# Specify the region where IPAM, IPAM pool, and VPC are created
provider "alicloud" {
  region = "cn-hangzhou"
}

# Create IPAM
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Specify the effective region of IPAM
}

# Create an IPAM address pool
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Specify the scope of the IPAM pool
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Specify the effective region of the IPAM pool
  ip_version     = "IPv4"                                     # Specify the version of the IPAM pool
}

# Allocate a CIDR block to the IPAM address pool
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Specify the CIDR block
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool
}

# Create a VPC
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool
  ipv4_cidr_mask    = 24                                                 # IPv4 subnet mask
}