Virtual Private Cloud:HaVip

コンソール

API

• CreateHaVip API を呼び出して HaVip を作成します。

• AssociateHaVip API を呼び出して HaVip を ECS インスタンスまたは ENI に関連付けます。

• UnassociateHaVip API を呼び出して HaVip と ECS インスタンスまたは ENI の関連付けを解除します。

• DeleteHaVip API を呼び出して HaVip を削除します。

Terraform

リソース：alicloud_havip、alicloud_havip_attachment、alicloud_instance、alicloud_security_group、alicloud_security_group_rule

# HaVip を作成するリージョンを指定します。
provider "alicloud" {
  region = "cn-hangzhou"
}

# VPC の ID を指定します。
variable "vpc_id" {
  default = "vpc-bp1k******" # 実際の VPC ID に置き換えてください。
}

# vSwitch ID を指定します。
variable "vswitch_id" {
  default = "vsw-bp1y******" # 実際の vSwitch ID に置き換えてください。
}

# インスタンスタイプを指定します。
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# イメージ ID を指定します。
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# HaVip を作成します。
resource "alicloud_havip" "test_havip" {
  ha_vip_name = "test_havip_name"
  vswitch_id  = var.vswitch_id
  ip_address  = "192.168.0.24" # vSwitch の CIDR ブロックから HaVip の IP アドレスを指定します。指定しない場合、システムが割り当てます。
}

# セキュリティグループを作成します。
resource "alicloud_security_group" "test_security_group" {
  security_group_name = "test_security_group_name"
  vpc_id              = var.vpc_id
}

# セキュリティグループルールを作成します。実際のトラフィックに基づいてプロトコル、ソース、ポートを調整する必要があります。
resource "alicloud_security_group_rule" "allow_vpc_tcp" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "8000/8000"
  priority          = 1
  security_group_id = alicloud_security_group.test_security_group.id
  cidr_ip           = "192.168.0.0/24"
}

# プライマリサーバーを作成します。 
resource "alicloud_instance" "test_master_instance" {
  instance_name        = "test_master_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! keepalived の設定ファイル
    vrrp_instance VI_1 {
        state MASTER            # プライマリインスタンスとして設定します。
        interface eth0          # 仮想 IP アドレスがバインドされるネットワークインターフェースです。この例では eth0 を使用します。  
        virtual_router_id 51    # プライマリ/セカンダリクラスターの virtual_router_id です。同一 VPC 内の異なるクラスターには、異なる virtual_router_id 値が必要です。
        nopreempt               # 非preemptive モードに設定します。
        priority 100            # 優先度です。値が大きいほど優先度が高くなります。この例では、優先度を 100 に設定して、このインスタンスをプライマリインスタンスにします。
        advert_int 1            # ハートビートメッセージを送信する間隔 (秒) です。値が小さいと、設定がネットワークのジッターの影響を受けやすくなり、頻繁なフェイルオーバーや一時的なスプリットブレインシナリオが発生する可能性があります。値が大きいと、プライマリインスタンスに障害が発生した後のフェイルオーバー時間が増加する可能性があります。
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.25     # このインスタンスのプライベート IP アドレスです。この例では 192.168.0.25 を使用します。
        unicast_peer {
            192.168.0.26                # ピアインスタンスのプライベート IP アドレスです。この例では 192.168.0.26 を使用します。複数のセカンダリ ECS インスタンスがある場合は、各ピアインスタンスの IP アドレスを新しい行に記述します。カンマや他の区切り文字は使用しないでください。
        }
        virtual_ipaddress {
            192.168.0.24                # 仮想 IP アドレスです。これを HaVip の IP アドレスに設定します。この例では 192.168.0.24 を使用します。
        }   
        garp_master_delay 1             # MASTER 状態に遷移してから Gratuitous ARP パケットを送信するまでの遅延時間 (秒) です。 
        garp_master_refresh 5           # Gratuitous ARP メッセージを定期的に送信する間隔 (秒) です。 

        track_interface {
            eth0                        # 仮想 IP アドレスがバインドされるネットワークインターフェースです。この例では eth0 を使用します。
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # Keepalived をインストールするためのプライマリサーバーの初期化スクリプトを指定します。
  private_ip           = "192.168.0.25"       # プライマリサーバーのプライベート IP アドレスを指定します。
  instance_charge_type = "PostPaid"           # 課金方法を従量課金に設定します。
  spot_strategy        = "SpotWithPriceLimit" # 価格上限付きのスポットインスタンスとして設定します。
}

# セカンダリサーバーを作成します。 
resource "alicloud_instance" "test_backup_instance" {
  instance_name        = "test_backup_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! keepalived の設定ファイル
    vrrp_instance VI_1 {
        state BACKUP            # セカンダリインスタンスとして設定します。
        interface eth0          # 仮想 IP アドレスがバインドされるネットワークインターフェースです。この例では eth0 を使用します。  
        virtual_router_id 51    # プライマリ/セカンダリクラスターの virtual_router_id です。同一 VPC 内の異なるクラスターには、異なる virtual_router_id 値が必要です。
        nopreempt               # 非preemptive モードに設定します。
        priority 10             # 優先度です。値が大きいほど優先度が高くなります。この例では、優先度を 10 に設定して、このインスタンスをセカンダリインスタンスにします。
        advert_int 1            # ハートビートメッセージを送信する間隔 (秒) です。値が小さいと、設定がネットワークのジッターの影響を受けやすくなり、頻繁なフェイルオーバーや一時的なスプリットブレインシナリオが発生する可能性があります。値が大きいと、プライマリインスタンスに障害が発生した後のフェイルオーバー時間が増加する可能性があります。
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.26   # このインスタンスのプライベート IP アドレスです。この例では 192.168.0.26 を使用します。
        unicast_peer {
            192.168.0.25          # ピアインスタンスのプライベート IP アドレスです。この例では 192.168.0.25 を使用します。複数のセカンダリ ECS インスタンスがある場合は、各ピアインスタンスの IP アドレスを新しい行に記述します。カンマや他の区切り文字は使用しないでください。
        }
        virtual_ipaddress {
            192.168.0.24          # 仮想 IP アドレスです。これを HaVip の IP アドレスに設定します。この例では 192.168.0.24 を使用します。 
        }    
        garp_master_delay 1       # MASTER 状態に遷移してから Gratuitous ARP パケットを送信するまでの遅延時間 (秒) です。 
        garp_master_refresh 5     # Gratuitous ARP メッセージを定期的に送信する間隔 (秒) です。 

        track_interface {
            eth0                  # 仮想 IP アドレスがバインドされるネットワークインターフェースです。この例では eth0 を使用します。
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # Keepalived をインストールするためのセカンダリサーバーの初期化スクリプトを指定します。
  private_ip           = "192.168.0.26"       # セカンダリサーバーのプライベート IP アドレスを指定します。 
  instance_charge_type = "PostPaid"           # 課金方法を従量課金に設定します。
  spot_strategy        = "SpotWithPriceLimit" # 価格上限付きのスポットインスタンスとして設定します。
}

# プライマリサーバーに関連付けます。
resource "alicloud_havip_attachment" "test_havip_attachment" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_master_instance.id # HaVip に関連付けるインスタンスの ID を指定します。
}

# セカンダリサーバーに関連付けます。
resource "alicloud_havip_attachment" "test_havip_attachment_new" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_backup_instance.id # HaVip に関連付けるインスタンスの ID を指定します。
}

コンソール

API

EIP を関連付ける前に、AllocateEipAddress API を呼び出して作成します。

• AssociateEipAddress API を呼び出して EIP を HaVip に関連付けます。

• UnassociateEipAddress API を呼び出して EIP と HaVip の関連付けを解除します。

Terraform

リソース：alicloud_eip_address、alicloud_eip_association

# HaVip のリージョンを指定します。 
provider "alicloud" {
  region = "cn-hangzhou"
}

# HaVip の ID を指定します。
variable "havip_id" {
  default = "havip-8vb0******"  # 実際の HaVip ID に置き換えてください。
}

# EIP を作成します。
resource "alicloud_eip_address" "test_eip" {
  address_name = "test_eip_name"
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# EIP を関連付けます。
resource "alicloud_eip_association" "test_eip_havip_association" {
  allocation_id = alicloud_eip_address.test_eip.id
  instance_type = "HAVIP"
  instance_id   = var.havip_id # HaVip の ID を指定します。
}