一般的な Terraform テンプレートの例 - Resource Orchestration Service

このトピックでは、一般的に使用される Terraform テンプレートの例を紹介します。これには、Elastic Compute Service (ECS) インスタンス、ApsaraDB RDS インスタンス、および Server Load Balancer (SLB) インスタンスを個別に作成するために使用されるテンプレートが含まれます。

ECS インスタンスの作成

次のサンプルコードは、仮想プライベートクラウド (VPC)、vSwitch、セキュリティグループ、および ECS インスタンスを作成するために使用されるテンプレートの例を示しています。

説明

[コード] タブをクリックするだけで、サンプルコードを実行できます。

variable "region"{
  // リージョンを定義します。
  default = "cn-beijing"
}

provider "alicloud"{
  region = var.region
}

variable "instance_type" {
  // インスタンスタイプを定義します。
  type    = string
  default = "ecs.e-c1m1.large"
}

data "alicloud_zones" "default" {
  available_instance_type     = var.instance_type
  available_resource_creation = "VSwitch"
  available_disk_category     = "cloud_essd"
}

variable "vpc_cidr_block" {
  // VPCのCIDRブロックを定義します。
  default = "172.16.0.0/16"
}

variable "vsw_cidr_block" {
  // vSwitchのCIDRブロックを定義します。
  default = "172.16.0.0/24"
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

resource "alicloud_vpc" "vpc" {
  vpc_name   = "vpc-test_${random_integer.default.result}"
  cidr_block = var.vpc_cidr_block
}

resource "alicloud_security_group" "group" {
  name   = "test_${random_integer.default.result}"
  vpc_id = alicloud_vpc.vpc.id
}

resource "alicloud_vswitch" "vswitch" {
  vpc_id       = alicloud_vpc.vpc.id
  cidr_block   = var.vsw_cidr_block
  zone_id      = data.alicloud_zones.default.zones[0].id
  vswitch_name = "vswitch-test-${random_integer.default.result}"
}

resource "alicloud_instance" "instance" {
  availability_zone          = data.alicloud_zones.default.zones[0].id
  security_groups            = alicloud_security_group.group.*.id
  instance_type              = var.instance_type
  system_disk_category       = "cloud_essd"
  system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
  system_disk_description    = "test_foo_system_disk_description"
  image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
  instance_name              = "test_ecs_${random_integer.default.result}"
  vswitch_id                 = alicloud_vswitch.vswitch.id
  internet_max_bandwidth_out = 10
  password                   = "Terraform@Example"
}

ApsaraDB RDS インスタンスの作成

次のサンプルコードは、VPC、vSwitch、および ApsaraDB RDS インスタンスを作成するために使用されるテンプレートの例を示しています。

説明

[コード] タブをクリックするだけで、サンプルコードを実行できます。

variable "region" {
  // リージョンを定義します。
  default = "cn-beijing"
}

provider "alicloud" {
  region = var.region
}

data "alicloud_zones" "default" {
  available_resource_creation = "VSwitch"
  available_disk_category     = "cloud_essd"
}

variable "vpc_cidr_block" {
  // VPCのCIDRブロックを定義します。
  default = "172.16.0.0/16"
}

variable "vsw_cidr_block" {
  // vSwitchのCIDRブロックを定義します。
  default = "172.16.0.0/24"
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

resource "alicloud_vpc" "vpc" {
  vpc_name   = "vpc-test_${random_integer.default.result}"
  cidr_block = var.vpc_cidr_block
}

resource "alicloud_vswitch" "vswitch" {
  vpc_id       = alicloud_vpc.vpc.id
  cidr_block   = var.vsw_cidr_block
  zone_id      = data.alicloud_zones.default.zones[0].id
  vswitch_name = "vswitch-test-${random_integer.default.result}"
}

resource "alicloud_db_instance" "example" {
  engine               = "MySQL"
  engine_version       = "5.6"
  instance_type        = "rds.mysql.s2.large"
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  instance_name        = "my_db_${random_integer.default.result}"
  vswitch_id           = alicloud_vswitch.vswitch.id
  monitoring_period    = "60"
}

SLB インスタンスの作成

次のサンプルコードは、VPC、vSwitch、および SLB インスタンスを作成するために使用されるテンプレートの例を示しています。

説明

[コード] タブをクリックするだけで、サンプルコードを実行できます。

variable "region" {
  // リージョンを定義します。
  default = "cn-beijing"
}

provider "alicloud" {
  region = var.region
}

data "alicloud_zones" "default" {
  available_resource_creation = "VSwitch"
  available_disk_category     = "cloud_essd"
}

variable "vpc_cidr_block" {
  // VPCのCIDRブロックを定義します。
  default = "172.16.0.0/16"
}

variable "vsw_cidr_block" {
  // vSwitchのCIDRブロックを定義します。
  default = "172.16.0.0/24"
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

resource "alicloud_vpc" "vpc" {
  vpc_name   = "vpc-test_${random_integer.default.result}"
  cidr_block = var.vpc_cidr_block
}

resource "alicloud_vswitch" "vswitch" {
  vpc_id       = alicloud_vpc.vpc.id
  cidr_block   = var.vsw_cidr_block
  zone_id      = data.alicloud_zones.default.zones[0].id
  vswitch_name = "vswitch-test-${random_integer.default.result}"
}

resource "alicloud_slb_load_balancer" "default" {
  load_balancer_name = "my_slb_${random_integer.default.result}"
  load_balancer_spec = "slb.s2.small"
  vswitch_id         = alicloud_vswitch.vswitch.id
}