:Terraform によるプラン、サイト、DNS レコードの作成

プロバイダーと Terraform のバージョンの定義

まず、providers.tf という名前の設定ファイルを作成します。次のコードをファイルにコピーして、すべてのプロバイダーの設定とバージョン制約を管理します。

terraform {
  required_providers {
    alicloud = {
      source  = "aliyun/alicloud"
      version = "1.266.0"  # Terraform のバージョンは定期的に更新されます。最新バージョンについては、Terraform の公式サイトをご確認ください。
    }
  }
}

provider "alicloud" {
  region = "ap-southeast-1"
}

リソース変数の定義

コードの再利用性を高めるために、入力変数とローカル変数を宣言します。variables.tf という名前の設定ファイルを作成し、次のコードをコピーします。

# サイトのアクセスタイプ。有効な値： CNAME、NS
variable "site_type" {
  default = "NS"
}
# 課金方法。有効な値はサブスクリプションのみです。
variable "payment_type" {
  default = "Subscription"
}
# サービス範囲。有効な値：
# domestic (中国本土)、overseas (全世界、中国本土を除く)、global (全世界)
variable "coverage_name" {
  default = "overseas"
}
# 自動支払いを有効にします。
variable "auto_pay" {
  default = "true"
}
# プラン名。有効な値：
# entranceplan_intl (Entrance)、basicplan_intl (Pro)、vipplan_intl (Premium)
variable "plan_name" {
  default = "entranceplan_intl"
}
# サイト名。実際のドメイン名に置き換えてください。
variable "site_name" {
  default = "aliyundoc.com"
}
# オリジンのドメイン名。
variable "record_value" {
  default = "www.example.com"
}
# オリジンポート。
variable "record_port" {
  default = "80"
}
# DNS レコード名、つまり高速化ドメイン名。
variable "record_name" {
  default = "_udp._sip.aliyundoc.com"
}
# DNS レコードタイプ。
variable "record_type" {
  default = "SRV"
}

リソースの定義

最後に、main.tf という名前の設定ファイルを作成し、次のコードをコピーします。このファイルには、主要なリソース宣言が含まれています。

# プランの作成
resource "alicloud_esa_rate_plan_instance" "my_plan" {
  type         = var.site_type
  auto_renew   = "false"
  period       = "1"
  payment_type = var.payment_type
  coverage     = var.coverage_name
  auto_pay     = var.auto_pay
  plan_name    = var.plan_name
}

# サイトの作成
resource "alicloud_esa_site" "my_site" {
  site_name   = var.site_name
  instance_id = alicloud_esa_rate_plan_instance.my_plan.id
  coverage    = var.coverage_name
  access_type = var.site_type
}

# DNS レコードの追加
resource "alicloud_esa_record" "my_record" {
  data {
    value    = var.record_value
    weight   = "1"
    priority = "1"
    port     = var.record_port
  }

  ttl         = "100"
  record_name = var.record_name
  comment     = "This is a remark"
  site_id     = alicloud_esa_site.my_site.id
  record_type = var.record_type
}

プランの確認

1. ESA コンソールにログインし、[プラン管理] ページに移動します。

2. [プラン管理] ページに、以下の図に示すように、新しいプランが表示されます。

   

サイトの確認

ESA コンソールで、サイト管理 を選択します。以下の図に示すように、新しいサイトが表示されます。

DNS レコードの確認

1. ESA コンソールで、サイト管理 を選択し、サイト 列で対象のサイトをクリックします。

2. ナビゲーションウィンドウで、DNS > レコード を選択します。以下の図に示すように、新しい DNS レコードが表示されます。