DBMS_SQL - - Alibaba Cloud ドキュメントセンター

DBMS_SQL パッケージは、Oracle データベースと互換性のあるアプリケーションインターフェイスと、Oracle 動的 SQL 機能と互換性のある POLARDB を提供しています。 DBMS_SQL パッケージを使用すると、アプリケーションを作成するときではなく、実行時にクエリやその他のコマンドを作成することができます。 Oracle と互換性のある POLARDB は、動的 SQL のネイティブサポートを提供しています。 DBMS_SQL パッケージは、ご使用のアプリケーションを変更せずに Oracle データベースと互換性のある動的 SQL を使用する方法を提供します。

DBMS_SQL パッケージは、動的 SQL 文を実行するときに現在のユーザーが必要な権限を持っていることを前提としています。

表 1. DBMS_SQL 関数とストアドプロシージャ
関数/ストアドプロシージャ	関数またはストアドプロシージャ	戻り値の型	説明
BIND_VARIABLE(c, name, value [, out_value_size ])	ストアドプロシージャ	N/A	値を変数にバインドします。
BIND_VARIABLE_CHAR(c, name, value [, out_value_size ])	ストアドプロシージャ	N/A	CHAR 値を変数にバインドします。
BIND_VARIABLE_RAW(c, name, value [, out_value_size ])	ストアドプロシージャ	N/A	RAW 値を変数にバインドします。
CLOSE_CURSOR(c IN OUT)	ストアドプロシージャ	N/A	カーソルを閉じます。
COLUMN_VALUE(c, position, value OUT [, column_error OUT [, actual_length OUT ]])	ストアドプロシージャ	N/A	列の値を変数に返します。
COLUMN_VALUE_CHAR(c, position, value OUT [, column_error OUT [, actual_length OUT ]])	ストアドプロシージャ	N/A	CHAR 列の値を変数に返します。
COLUMN_VALUE_RAW(c, position, value OUT [, column_error OUT [, actual_length OUT ]])	ストアドプロシージャ	N/A	RAW 列の値を変数に返します。
DEFINE_COLUMN(c, position, column [, column_size ])	ストアドプロシージャ	N/A	SELECT リストの列を定義します。
DEFINE_COLUMN_CHAR(c, position, column, column_size)	ストアドプロシージャ	N/A	SELECT リストの CHAR 列を定義します。
DEFINE_COLUMN_RAW(c, position, column, column_size)	ストアドプロシージャ	N/A	SELECT リストの RAW 列を定義します。
DESCRIBE_COLUMNS	ストアドプロシージャ	N/A	カーソル結果セットを保持する列を定義します。
EXECUTE(c)	関数	INTEGER	カーソルを実行します。
EXECUTE_AND_FETCH(c [, exact ])	関数	INTEGER	カーソルを実行し、単一の行をフェッチします。
FETCH_ROWS(c)	関数	INTEGER	カーソルから行をフェッチします。
IS_OPEN(c)	関数	BOOLEAN	カーソルがオープンかどうかを確認します。
LAST_ROW_COUNT	関数	INTEGER	フェッチされた行の累積数を返します。
OPEN_CURSOR	関数	INTEGER	カーソルをオープンします。
PARSE(c, statement, language_flag)	ストアドプロシージャ	N/A	文を解析します。

Oracle と互換性のある POLARDB の DBMS_SQL パッケージは、Oracle のバージョンと比較すると部分的に実装されています。 Oracle と互換性のある POLARDB は、前の表にリストされている関数とストアドプロシージャのみをサポートしています。

次の表に、DBMS_SQL パッケージで使用できるパブリック変数を示します。

表 2. DBMS_SQL パブリック変数
パブリック変数	データ型	値	説明
native	INTEGER	1	Oracle 構文との互換性のために提供されています。詳細については、DBMS_SQL.PARSE をご参照ください。
V6	INTEGER	2	Oracle 構文との互換性のために提供されています。詳細については、DBMS_SQL.PARSE をご参照ください。
V7	INTEGER	3	Oracle 構文との互換性のために提供されています。詳細については、DBMS_SQL.PARSE をご参照ください。

BIND_VARIABLE

BIND_VARIABLE ストアドプロシージャは、SQL コマンドで IN または IN OUT バインド変数に値を関連付ける機能を提供します。

BIND_VARIABLE(c INTEGER, name VARCHAR2,
  value { BLOB | CLOB | DATE | FLOAT | INTEGER | NUMBER |
          TIMESTAMP | VARCHAR2 }
  [, out_value_size INTEGER ])

パラメーター


パラメーター	説明
c	バインド変数を含む SQL コマンドのカーソルの ID。
name	SQL コマンドのバインド変数の名前。
value	割り当てる値。
out_value_size	name が IN OUT 変数の場合、このパラメーターは出力値の最大長を定義します。このパラメーターを指定しない場合には、現在の値の長さはデフォルトで最大長になります。

例

次の匿名ブロックは、バインド変数を使用してemp テーブルに行を挿入します。

DECLARE
    curid           INTEGER;
    v_sql           VARCHAR2(150) := 'INSERT INTO emp VALUES ' ||
                        '(:p_empno, :p_ename, :p_job, :p_mgr, ' ||
                        ':p_hiredate, :p_sal, :p_comm, :p_deptno)';
    v_empno         emp.empno%TYPE;
    v_ename         emp.ename%TYPE;
    v_job           emp.job%TYPE;
    v_mgr           emp.mgr%TYPE;
    v_hiredate      emp.hiredate%TYPE;
    v_sal           emp.sal%TYPE;
    v_comm          emp.comm%TYPE;
    v_deptno        emp.deptno%TYPE;
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    v_empno    := 9001;
    v_ename    := 'JONES';
    v_job      := 'SALESMAN';
    v_mgr      := 7369;
    v_hiredate := TO_DATE('13-DEC-07','DD-MON-YY');
    v_sal      := 8500.00;
    v_comm     := 1500.00;
    v_deptno   := 40;
    DBMS_SQL.BIND_VARIABLE(curid,':p_empno',v_empno);
    DBMS_SQL.BIND_VARIABLE(curid,':p_ename',v_ename);
    DBMS_SQL.BIND_VARIABLE(curid,':p_job',v_job);
    DBMS_SQL.BIND_VARIABLE(curid,':p_mgr',v_mgr);
    DBMS_SQL.BIND_VARIABLE(curid,':p_hiredate',v_hiredate);
    DBMS_SQL.BIND_VARIABLE(curid,':p_sal',v_sal);
    DBMS_SQL.BIND_VARIABLE(curid,':p_comm',v_comm);
    DBMS_SQL.BIND_VARIABLE(curid,':p_deptno',v_deptno);
    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('Number of rows processed: ' || v_status);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

Number of rows processed: 1

BIND_VARIABLE_CHAR

BIND_VARIABLE_CHAR ストアドプロシージャは、CHAR 値を SQL コマンドの IN または IN OUT バインド変数に関連付ける機能を提供します。

BIND_VARIABLE_CHAR(c INTEGER, name VARCHAR2, value CHAR
  [, out_value_size INTEGER ])

パラメーター


パラメーター	説明
c	バインド変数を含む SQL コマンドのカーソルの ID。
name	SQL コマンドのバインド変数の名前。
value	割り当てる CHAR 型の値。
out_value_size	name が IN OUT 変数の場合、このパラメーターは出力値の最大長を定義します。このパラメーターを指定しない場合には、現在の値の長さはデフォルトで最大長になります。

BIND_VARIABLE_RAW

BIND_VARIABLE_RAW ストアドプロシージャは、SQL コマンドで RAW 値を IN または IN OUT バインド変数に関連付ける機能を提供します。

BIND_VARIABLE_RAW(c INTEGER, name VARCHAR2, value RAW
  [, out_value_size INTEGER ])

パラメーター


パラメーター	説明
c	バインド変数を含む SQL コマンドのカーソルの ID。
name	SQL コマンドのバインド変数の名前。
value	割り当てる RAW 型の値。
out_value_size	name が IN OUT 変数の場合、このパラメーターは出力値の最大長を定義します。このパラメーターを指定しない場合には、現在の値の長さはデフォルトで最大長になります。

CLOSE_CURSOR

CLOSE_CURSOR ストアドプロシージャは、カーソルをクローズします。カーソルがクローズされると、カーソルに割り当てられていたリソースが解放され、カーソルは使用できなくなります。

CLOSE_CURSOR(c IN OUT INTEGER)

パラメーター


パラメーター	説明
c	クローズするカーソルの ID。

例

次の例は、オープンしたカーソルをクローズする方法を示しています。

DECLARE
    curid           INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
            .
            .
            .
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

COLUMN_VALUE

COLUMN_VALUE ストアドプロシージャは、カーソルから値を受け取る変数を定義します。

COLUMN_VALUE(c INTEGER, position INTEGER, value OUT { BLOB |
  CLOB | DATE | FLOAT | INTEGER | NUMBER | TIMESTAMP | VARCHAR2 }
  [, column_error OUT NUMBER [, actual_length OUT INTEGER ]])

パラメーター


パラメーター	説明
c	定義されている変数にデータを返すカーソルの ID。
position	カーソル内の返されたデータの位置。カーソルの最初の値は位置 1 です。
value	以前のフェッチ呼び出しによってカーソルで返されたデータを受け取る変数。
column_error	エラーが生じた場合、このパラメーターは列に関連付けられたエラーコードを示します。
actual_length	切り捨て前のデータの実際の長さ。

例

次の例は、COLUMN_VALUE ストアドプロシージャを使用してカーソルから値を受け取る匿名ブロックの一部を示しています。

DECLARE
    curid           INTEGER;
    v_empno         NUMBER(4);
    v_ename         VARCHAR2(10);
    v_hiredate      DATE;
    v_sal           NUMBER(7,2);
    v_comm          NUMBER(7,2);
    v_sql           VARCHAR2(50) := 'SELECT empno, ename, hiredate, sal, ' ||
                                    'comm FROM emp';
    v_status        INTEGER;
BEGIN
            .
            .
            .
    LOOP
        v_status := DBMS_SQL.FETCH_ROWS(curid);
        EXIT WHEN v_status = 0;
        DBMS_SQL.COLUMN_VALUE(curid,1,v_empno);
        DBMS_SQL.COLUMN_VALUE(curid,2,v_ename);
        DBMS_SQL.COLUMN_VALUE(curid,3,v_hiredate);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,5,v_comm);
        DBMS_OUTPUT.PUT_LINE(v_empno || '   ' || RPAD(v_ename,10) || '  ' ||
            TO_CHAR(v_hiredate,'yyyy-mm-dd') || ' ' ||
            TO_CHAR(v_sal,'9,999.99') || ' ' ||
            TO_CHAR(NVL(v_comm,0),'9,999.99'));
    END LOOP;
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

COLUMN_VALUE_CHAR

COLUMN_VALUE_CHAR ストアドプロシージャは、カーソルから CHAR 値を受け取る変数を定義します。

COLUMN_VALUE_CHAR(c INTEGER, position INTEGER, value OUT CHAR
  [, column_error OUT NUMBER [, actual_length OUT INTEGER ]])

パラメーター


パラメーター	説明
c	定義されている変数にデータを返すカーソルの ID。
position	カーソル内の返されたデータの位置。カーソルの最初の値は位置 1 です。
value	前のフェッチ呼び出しによってカーソルで返されたデータを受け取るデータ型 CHAR の変数。
column_error	エラーが生じた場合、このパラメーターは列に関連付けられたエラーコードを示します。
actual_length	切り捨て前のデータの実際の長さ。

COLUMN_VALUE_RAW

COLUMN_VALUE_RAW ストアドプロシージャは、カーソルから RAW 値を受け取る変数を定義します。

COLUMN_VALUE_RAW(c INTEGER, position INTEGER, value OUT RAW
  [, column_error OUT NUMBER [, actual_length OUT INTEGER ]])

パラメーター


パラメーター	説明
c	定義されている変数にデータを返すカーソルの ID。
position	カーソル内の返されたデータの位置。カーソルの最初の値は位置 1 です。
value	以前のフェッチ呼び出しによってカーソルで返されたデータを受け取る RAW データ型の変数。
column_error	エラーが生じた場合、このパラメーターは列に関連付けられたエラーコードを示します。
actual_length	切り捨て前のデータの実際の長さ。

DEFINE_COLUMN

DEFINE_COLUMN ストアドプロシージャは、カーソルで戻されて検索される SELECT リスト内の列または式を定義します。

DEFINE_COLUMN(c INTEGER, position INTEGER, column { BLOB |
  CLOB | DATE | FLOAT | INTEGER | NUMBER | TIMESTAMP | VARCHAR2 }
  [, column_size INTEGER ])

パラメーター


パラメーター	説明
c	SELECT コマンドに関連付けられたカーソルの ID。
position	定義されている SELECT リスト内の列または式の位置。
column	SELECT 結果セットの指定された位置にある列または式のデータ型と一致する変数。
column_size	返りデータの最大長。列のデータ型が VARCHAR2 の場合は、column_size パラメーターを指定する必要があります。 column_size を超える返りデータは、column_size パラメーターで指定された最大長に切り捨てられます。

例

次の例は、DEFINE_COLUMN ストアドプロシージャを使用して、emp テーブルの empno、ename、hiredate、sal、および comm 列を定義する方法を示しています。

DECLARE
    curid           INTEGER;
    v_empno         NUMBER(4);
    v_ename         VARCHAR2(10);
    v_hiredate      DATE;
    v_sal           NUMBER(7,2);
    v_comm          NUMBER(7,2);
    v_sql           VARCHAR2(50) := 'SELECT empno, ename, hiredate, sal, ' ||
                                    'comm FROM emp';
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    DBMS_SQL.DEFINE_COLUMN(curid,1,v_empno);
    DBMS_SQL.DEFINE_COLUMN(curid,2,v_ename,10);
    DBMS_SQL.DEFINE_COLUMN(curid,3,v_hiredate);
    DBMS_SQL.DEFINE_COLUMN(curid,4,v_sal);
    DBMS_SQL.DEFINE_COLUMN(curid,5,v_comm);
            .
            .
            .
END;

次の例は、まったく同じ結果を生成する前述の例の代替を示しています。データ型の長さは無関係であることにご注意ください。 empno、sal、および comm 列は、v_num が NUMBER(1) として定義されている場合でも、それぞれ NUMBER(4) および NUMBER(7,2) と同等のデータを返します。上記の例では、COLUMN_VALUE ストアドプロシージャの各宣言は、適切な最大サイズで構成されています。 ename 列は、DEFINE_COLUMN 呼び出しの length パラメーターで定義されているように、最大 10 文字の長さのデータを返します。 v_varchar に対して宣言されたデータ型 VARCHAR2(1) で示される長さは無視されます。返りデータの実際のサイズは、COLUMN_VALUE ストアドプロシージャによって決定されます。

DECLARE
    curid           INTEGER;
    v_num           NUMBER(1);
    v_varchar       VARCHAR2(1);
    v_date          DATE;
    v_sql           VARCHAR2(50) := 'SELECT empno, ename, hiredate, sal, ' ||
                                    'comm FROM emp';
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    DBMS_SQL.DEFINE_COLUMN(curid,1,v_num);
    DBMS_SQL.DEFINE_COLUMN(curid,2,v_varchar,10);
    DBMS_SQL.DEFINE_COLUMN(curid,3,v_date);
    DBMS_SQL.DEFINE_COLUMN(curid,4,v_num);
    DBMS_SQL.DEFINE_COLUMN(curid,5,v_num);
            .
            .
            .
END;

DEFINE_COLUMN_CHAR

DEFINE_COLUMN_CHAR ストアドプロシージャは、カーソルで返され、取得される SELECT リスト内の CHAR 列または式を定義します。

DEFINE_COLUMN_CHAR(c INTEGER, position INTEGER, column CHAR, column_size INTEGER)

パラメーター


パラメーター	説明
c	SELECT コマンドに関連付けられたカーソルの ID。
position	定義されている SELECT リスト内の列または式の位置。
column	CHAR 変数。
column_size	返りデータの最大長。 column_size を超える返りデータは、column_size 文字に切り捨てられます。

DEFINE_COLUMN_RAW

DEFINE_COLUMN_RAW ストアドプロシージャは、カーソルで返され、取得される SELECT リスト内の RAW 列または式を定義します。

DEFINE_COLUMN_RAW(c INTEGER, position INTEGER, column RAW,
  column_size INTEGER)

パラメーター


パラメーター	説明
c	SELECT コマンドに関連付けられたカーソルの ID。
position	定義されている SELECT リスト内の列または式の位置。
column	RAW 変数。
column_size	返りデータの最大長。 column_size を超える返りデータは、column_size 文字に切り捨てられます。

DESCRIBE_COLUMNS

DESCRIBE_COLUMNS ストアドプロシージャは、カーソルによって返される列を記述します。

DESCRIBE_COLUMNS(c INTEGER, col_cnt OUT INTEGER, desc_t OUT
  DESC_TAB);

パラメーター


パラメーター	説明
c	カーソルの ID。
col_cnt	カーソル結果セットの列数。
desc_tab	カーソルによって返される各列の説明を含むテーブル。説明は DESC_REC 型であり、以下の値が含まれています。


列名	データ型
col_type	INTEGER
col_max_len	INTEGER
col_name	VARCHAR2(128)
col_name_len	INTEGER
col_schema_name	VARCHAR2(128)
col_schema_name_len	INTEGER
col_precision	INTEGER
col_scale	INTEGER
col_charsetid	INTEGER
col_charsetform	INTEGER
col_null_ok	BOOLEAN

EXECUTE

EXECUTE 関数は、解析済み SQL コマンドまたは SPL ブロックを実行します。

status INTEGER EXECUTE(c INTEGER)

パラメーター


パラメーター	説明
c	実行される解析済み SQL 文または SPL ブロックのカーソル ID。
status	SQL コマンドが DELETE、INSERT、または UPDATE の場合、このパラメーターは処理されたレコードの数を示します。このパラメーターは、他のコマンドでは意味がありません。

例

次の匿名ブロックは、dept テーブルに行を挿入します。

DECLARE
    curid           INTEGER;
    v_sql           VARCHAR2(50);
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    v_sql := 'INSERT INTO dept VALUES (50, ''HR'', ''LOS ANGELES'')';
    DBMS_SQL.PARSE(curid, v_sql, DBMS_SQL.native);
    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('Number of rows processed: ' || v_status);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

EXECUTE_AND_FETCH

EXECUTE_AND_FETCH 関数は、解析された SELECT コマンドを実行し、1 行をフェッチします。

status INTEGER EXECUTE_AND_FETCH(c INTEGER
  [, exact BOOLEAN ])

パラメーター


パラメーター	説明
c	実行する SELECT コマンドのカーソルの ID。
exact	このパラメーターが TRUE に設定されている場合、結果セットの行数が 1 でない場合に例外が生じます。このパラメーターが FALSE に設定されている場合、例外は生じません。このパラメーターのデフォルト値は FALSE です。このパラメーターが TRUE に設定され、結果セットにレコードが含まれていない場合、NO_DATE_FOUND 例外が生じます。このパラメーターが TRUE に設定されていて、結果セットに複数のレコードが含まれている場合、TOO_MANY_ROWS 例外が生じます。
status	行がフェッチされると、このパラメーターに 1 が返されます。行がフェッチされない場合、このパラメーターには 0 が返されます。例外が生じた場合には、値は返されません。

例

次のストアドプロシージャは、EXECUTE_AND_FETCH 関数と従業員の名前を使用して 1 人の従業員を取得します。従業員が見つからない場合、または同じ名前の従業員が複数見つかった場合は、例外が生じます。

CREATE OR REPLACE PROCEDURE select_by_name(
    p_ename         emp.ename%TYPE
)
IS
    curid           INTEGER;
    v_empno         emp.empno%TYPE;
    v_hiredate      emp.hiredate%TYPE;
    v_sal           emp.sal%TYPE;
    v_comm          emp.comm%TYPE;
    v_dname         dept.dname%TYPE;
    v_disp_date     VARCHAR2(10);
    v_sql           VARCHAR2(120) := 'SELECT empno, hiredate, sal, ' ||
                                     'NVL(comm, 0), dname ' ||
                                     'FROM emp e, dept d ' ||
                                     'WHERE ename = :p_ename ' ||
                                     'AND e.deptno = d.deptno';
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    DBMS_SQL.BIND_VARIABLE(curid,':p_ename',UPPER(p_ename));
    DBMS_SQL.DEFINE_COLUMN(curid,1,v_empno);
    DBMS_SQL.DEFINE_COLUMN(curid,2,v_hiredate);
    DBMS_SQL.DEFINE_COLUMN(curid,3,v_sal);
    DBMS_SQL.DEFINE_COLUMN(curid,4,v_comm);
    DBMS_SQL.DEFINE_COLUMN(curid,5,v_dname,14);
    v_status := DBMS_SQL.EXECUTE_AND_FETCH(curid,TRUE);
    DBMS_SQL.COLUMN_VALUE(curid,1,v_empno);
    DBMS_SQL.COLUMN_VALUE(curid,2,v_hiredate);
    DBMS_SQL.COLUMN_VALUE(curid,3,v_sal);
    DBMS_SQL.COLUMN_VALUE(curid,4,v_comm);
    DBMS_SQL.COLUMN_VALUE(curid,5,v_dname);
    v_disp_date := TO_CHAR(v_hiredate, 'MM/DD/YYYY');
    DBMS_OUTPUT.PUT_LINE('Number    : ' || v_empno);
    DBMS_OUTPUT.PUT_LINE('Name      : ' || UPPER(p_ename));
    DBMS_OUTPUT.PUT_LINE('Hire Date : ' || v_disp_date);
    DBMS_OUTPUT.PUT_LINE('Salary    : ' || v_sal);
    DBMS_OUTPUT.PUT_LINE('Commission: ' || v_comm);
    DBMS_OUTPUT.PUT_LINE('Department: ' || v_dname);
    DBMS_SQL.CLOSE_CURSOR(curid);
EXCEPTION
    WHEN NO_DATA_FOUND THEN
        DBMS_OUTPUT.PUT_LINE('Employee ' || p_ename || ' not found');
        DBMS_SQL.CLOSE_CURSOR(curid);
    WHEN TOO_MANY_ROWS THEN
        DBMS_OUTPUT.PUT_LINE('Too many employees named, ' ||
            p_ename || ', found');
        DBMS_SQL.CLOSE_CURSOR(curid);
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('The following is SQLERRM:');
        DBMS_OUTPUT.PUT_LINE(SQLERRM);
        DBMS_OUTPUT.PUT_LINE('The following is SQLCODE:');
        DBMS_OUTPUT.PUT_LINE(SQLCODE);
        DBMS_SQL.CLOSE_CURSOR(curid);
END;

EXEC select_by_name('MARTIN')

Number    : 7654
Name      : MARTIN
Hire Date : 09/28/1981
Salary    : 1250
Commission: 1400
Department: SALES

FETCH_ROWS

FETCH_ROWS 関数は、カーソルから行を取得します。

status INTEGER FETCH_ROWS(c INTEGER)

パラメーター


パラメーター	説明
c	行のフェッチに使用されるカーソルの ID。
status	行がフェッチされると、このパラメーターに 1 が返されます。行がフェッチされない場合、このパラメーターには 0 が返されます。

例

次の例では、emp テーブルから行をフェッチし、結果を表示します。

DECLARE
    curid           INTEGER;
    v_empno         NUMBER(4);
    v_ename         VARCHAR2(10);
    v_hiredate      DATE;
    v_sal           NUMBER(7,2);
    v_comm          NUMBER(7,2);
    v_sql           VARCHAR2(50) := 'SELECT empno, ename, hiredate, sal, ' ||
                                    'comm FROM emp';
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    DBMS_SQL.DEFINE_COLUMN(curid,1,v_empno);
    DBMS_SQL.DEFINE_COLUMN(curid,2,v_ename,10);
    DBMS_SQL.DEFINE_COLUMN(curid,3,v_hiredate);
    DBMS_SQL.DEFINE_COLUMN(curid,4,v_sal);
    DBMS_SQL.DEFINE_COLUMN(curid,5,v_comm);

    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('EMPNO  ENAME       HIREDATE    SAL       COMM');
    DBMS_OUTPUT.PUT_LINE('-----  ----------  ----------  --------  ' ||
        '--------');
    LOOP
        v_status := DBMS_SQL.FETCH_ROWS(curid);
        EXIT WHEN v_status = 0;
        DBMS_SQL.COLUMN_VALUE(curid,1,v_empno);
        DBMS_SQL.COLUMN_VALUE(curid,2,v_ename);
        DBMS_SQL.COLUMN_VALUE(curid,3,v_hiredate);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,5,v_comm);
        DBMS_OUTPUT.PUT_LINE(v_empno || '   ' || RPAD(v_ename,10) || '  ' ||
            TO_CHAR(v_hiredate,'yyyy-mm-dd') || ' ' ||
            TO_CHAR(v_sal,'9,999.99') || ' ' ||
            TO_CHAR(NVL(v_comm,0),'9,999.99'));
    END LOOP;
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

EMPNO  ENAME       HIREDATE    SAL       COMM
-----  ----------  ----------  --------  --------
7369   SMITH       1980-12-17    800.00       .00
7499   ALLEN       1981-02-20  1,600.00    300.00
7521   WARD        1981-02-22  1,250.00    500.00
7566   JONES       1981-04-02  2,975.00       .00
7654   MARTIN      1981-09-28  1,250.00  1,400.00
7698   BLAKE       1981-05-01  2,850.00       .00
7782   CLARK       1981-06-09  2,450.00       .00
7788   SCOTT       1987-04-19  3,000.00       .00
7839   KING        1981-11-17  5,000.00       .00
7844   TURNER      1981-09-08  1,500.00       .00
7876   ADAMS       1987-05-23  1,100.00       .00
7900   JAMES       1981-12-03    950.00       .00
7902   FORD        1981-12-03  3,000.00       .00
7934   MILLER      1982-01-23  1,300.00       .00

IS_OPEN

IS_OPEN 関数は、指定されたカーソルがオープンしているかどうかをチェックする機能を提供します。

status BOOLEAN IS_OPEN(c INTEGER)

パラメーター


パラメーター	説明
c	チェックするカーソルの ID。
status	カーソルがオープンしている場合、このパラメーターは TRUE に設定されます。カーソルがオープンしていない場合、このパラメーターは FALSE に設定されます。

LAST_ROW_COUNT

LAST_ROW_COUNT 関数は、フェッチされた行の総数を返します。

rowcnt INTEGER LAST_ROW_COUNT

パラメーター


パラメーター	説明
rowcnt	返されたレコードの総数

例

次の例では、LAST_ROW_COUNT 関数を使用して、クエリでフェッチされた行の総数を表示します。

DECLARE
    curid           INTEGER;
    v_empno         NUMBER(4);
    v_ename         VARCHAR2(10);
    v_hiredate      DATE;
    v_sal           NUMBER(7,2);
    v_comm          NUMBER(7,2);
    v_sql           VARCHAR2(50) := 'SELECT empno, ename, hiredate, sal, ' ||
                                    'comm FROM emp';
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid,v_sql,DBMS_SQL.native);
    DBMS_SQL.DEFINE_COLUMN(curid,1,v_empno);
    DBMS_SQL.DEFINE_COLUMN(curid,2,v_ename,10);
    DBMS_SQL.DEFINE_COLUMN(curid,3,v_hiredate);
    DBMS_SQL.DEFINE_COLUMN(curid,4,v_sal);
    DBMS_SQL.DEFINE_COLUMN(curid,5,v_comm);

    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('EMPNO  ENAME       HIREDATE    SAL       COMM');
    DBMS_OUTPUT.PUT_LINE('-----  ----------  ----------  --------  ' ||
        '--------');
    LOOP
        v_status := DBMS_SQL.FETCH_ROWS(curid);
        EXIT WHEN v_status = 0;
        DBMS_SQL.COLUMN_VALUE(curid,1,v_empno);
        DBMS_SQL.COLUMN_VALUE(curid,2,v_ename);
        DBMS_SQL.COLUMN_VALUE(curid,3,v_hiredate);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,4,v_sal);
        DBMS_SQL.COLUMN_VALUE(curid,5,v_comm);
        DBMS_OUTPUT.PUT_LINE(v_empno || '   ' || RPAD(v_ename,10) || '  ' ||
            TO_CHAR(v_hiredate,'yyyy-mm-dd') || ' ' ||
            TO_CHAR(v_sal,'9,999.99') || ' ' ||
            TO_CHAR(NVL(v_comm,0),'9,999.99'));
    END LOOP;
    DBMS_OUTPUT.PUT_LINE('Number of rows: ' || DBMS_SQL.LAST_ROW_COUNT);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

EMPNO  ENAME       HIREDATE    SAL       COMM
-----  ----------  ----------  --------  --------
7369   SMITH       1980-12-17    800.00       .00
7499   ALLEN       1981-02-20  1,600.00    300.00
7521   WARD        1981-02-22  1,250.00    500.00
7566   JONES       1981-04-02  2,975.00       .00
7654   MARTIN      1981-09-28  1,250.00  1,400.00
7698   BLAKE       1981-05-01  2,850.00       .00
7782   CLARK       1981-06-09  2,450.00       .00
7788   SCOTT       1987-04-19  3,000.00       .00
7839   KING        1981-11-17  5,000.00       .00
7844   TURNER      1981-09-08  1,500.00       .00
7876   ADAMS       1987-05-23  1,100.00       .00
7900   JAMES       1981-12-03    950.00       .00
7902   FORD        1981-12-03  3,000.00       .00
7934   MILLER      1982-01-23  1,300.00       .00
Number of rows: 14

OPEN_CURSOR

OPEN_CURSOR 関数は、新しいカーソルを作成します。動的 SQL 文を解析して実行するには、カーソルを使用する必要があります。オープン後、カーソルをクローズして再度オープンする必要なしに、同じまたは異なる SQL 文でカーソルを再利用することができます。

c INTEGER OPEN_CURSOR

パラメーター


パラメーター	説明
c	新しく作成されるクラスターの名前

例

次の例はジョブ出力を定義する方法です。

DECLARE
    curid           INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
            .
            .
            .
END;

PARSE

PARSE ストアドプロシージャは、SQL コマンドまたは SPL ブロックを解析します。 SQL コマンドが DDL コマンドの場合、すぐに実行され、EXECUTE 関数を呼び出す必要はありません。

PARSE(c INTEGER, statement VARCHAR2, language_flag INTEGER)

パラメーター


パラメーター	説明
c	開いているカーソルの ID。
文	解析される SQL コマンドまたは SPL ブロック。 SQL コマンドはセミコロン (;) で終了できません。 SPL ブロックはセミコロン (;) で終了する必要があります。
language_flag	Oracle 構文との互換性のために提供されている言語フラグ。 DBMS_SQL.V6、DBMS_SQL.V7、または DBMS_SQL.native を使用します。このフラグは無視され、すべての構文は Oracle 形式と互換性のある POLARDB であると見なされます。

例

次の匿名ブロックは、job という名前のテーブルを作成します。 DDL 文は PARSE ストアドプロシージャによってすぐに実行され、EXECUTE 関数を呼び出す必要がないことにご注意ください。

DECLARE
    curid           INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(curid, 'CREATE TABLE job (jobno NUMBER(3), ' ||
        'jname VARCHAR2(9))',DBMS_SQL.native);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

次のコードスニペットは、2 つの行をジョブテーブルに挿入します。

DECLARE
    curid           INTEGER;
    v_sql           VARCHAR2(50);
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    v_sql := 'INSERT INTO job VALUES (100, ''ANALYST'')';
    DBMS_SQL.PARSE(curid, v_sql, DBMS_SQL.native);
    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('Number of rows processed: ' || v_status);
    v_sql := 'INSERT INTO job VALUES (200, ''CLERK'')';
    DBMS_SQL.PARSE(curid, v_sql, DBMS_SQL.native);
    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_OUTPUT.PUT_LINE('Number of rows processed: ' || v_status);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;

Number of rows processed: 1
Number of rows processed: 1

次の匿名ブロックは、DBMS_SQL パッケージを使用して、2 つの INSERT 文を含むブロックを実行します。ブロックの終わりには終了セミコロン (;) が含まれていますが、前の例では、個々の INSERT 文には終了セミコロン (;) がないことにご注意ください。

DECLARE
    curid           INTEGER;
    v_sql           VARCHAR2(100);
    v_status        INTEGER;
BEGIN
    curid := DBMS_SQL.OPEN_CURSOR;
    v_sql := 'BEGIN ' ||
               'INSERT INTO job VALUES (300, ''MANAGER''); '  ||
               'INSERT INTO job VALUES (400, ''SALESMAN''); ' ||
             'END;';
    DBMS_SQL.PARSE(curid, v_sql, DBMS_SQL.native);
    v_status := DBMS_SQL.EXECUTE(curid);
    DBMS_SQL.CLOSE_CURSOR(curid);
END;