Cloud Enterprise Network:リージョン間の VPC 間 IPv6 通信の有効化

コンソール

Terraform

Terraform を使用して、このシナリオの環境を構築できます。Terraform のインストールと設定方法については、Terraform のインストールをご参照ください。

以下の手順では、Linux ホストで Terraform v1.9.8 を実行する方法について説明します。開始する前に、認証を完了していることを確認してください。

ステップ 1：リソースの作成

1. このシナリオ用のディレクトリを作成し、そのディレクトリに移動します。

   mkdir tf-CenIpv6 && cd tf-CenIpv6

2. リソースを定義する main.tf ファイルを作成します。

   touch main.tf

3. main.tf ファイルを開き、次のコードをコピーして貼り付け、ファイルを保存します。このファイルには、このシナリオのリソースとその設定が含まれています。

   variable "pname" {
     description = "リソースのプレフィックス名"
     type        = string
     default     = "tf-CenIpv6"
   }
   
   variable "default_region_id" {
     description = "デフォルトのリージョン ID"
     type        = string
     default     = "cn-hangzhou"
   }
   
   variable "hangzhou_region_id" {
     description = "杭州のリージョン ID"
     type        = string
     default     = "cn-hangzhou"
   }
   
   variable "shanghai_region_id" {
     description = "上海のリージョン ID"
     type        = string
     default     = "cn-shanghai"
   }
   
   variable "hangzhou_az_list" {
     description = "使用するアベイラビリティゾーンのリスト"
     type        = list(string)
     default     = ["cn-hangzhou-j", "cn-hangzhou-k"]
   }
   
   variable "shanghai_az_list" {
     description = "使用するアベイラビリティゾーンのリスト"
     type        = list(string)
     default     = ["cn-shanghai-m", "cn-shanghai-n"]
   }
   
   # --- プロバイダー ---
   provider "alicloud" { # デフォルトは杭州
     region = var.default_region_id
   }
   
   provider "alicloud" {
     alias  = "hangzhou"
     region = var.hangzhou_region_id
   }
   
   provider "alicloud" {
     alias  = "shanghai"
     region = var.shanghai_region_id
   }
   
   # --- 2 つの VPC と 4 つの vSwitch ---
   resource "alicloud_vpc" "vpc1" {
     provider    = alicloud.hangzhou
     vpc_name    = "${var.pname}-vpc1"
     cidr_block  = "10.0.0.0/16"
     enable_ipv6 = true
   }
   resource "alicloud_vpc" "vpc2" {
     provider    = alicloud.shanghai
     vpc_name    = "${var.pname}-vpc2"
     cidr_block  = "172.16.0.0/16"
     enable_ipv6 = true
   }
   resource "alicloud_vswitch" "vsw1-1" {
     provider             = alicloud.hangzhou
     vpc_id               = alicloud_vpc.vpc1.id
     cidr_block           = "10.0.0.0/24"
     zone_id              = var.hangzhou_az_list[0]
     vswitch_name         = "${var.pname}-vsw1-1"
     enable_ipv6          = true
     ipv6_cidr_block_mask = 1 # vSwitch の IPv6 CIDR ブロックのマスク
   }
   resource "alicloud_vswitch" "vsw1-2" {
     provider             = alicloud.hangzhou
     vpc_id               = alicloud_vpc.vpc1.id
     cidr_block           = "10.0.1.0/24"
     zone_id              = var.hangzhou_az_list[1]
     vswitch_name         = "${var.pname}-vsw1-2"
     enable_ipv6          = true
     ipv6_cidr_block_mask = 2
   }
   resource "alicloud_vswitch" "vsw2-1" {
     provider             = alicloud.shanghai
     vpc_id               = alicloud_vpc.vpc2.id
     cidr_block           = "172.16.0.0/24"
     zone_id              = var.shanghai_az_list[0]
     vswitch_name         = "${var.pname}-vsw2-1"
     enable_ipv6          = true
     ipv6_cidr_block_mask = 3
   }
   resource "alicloud_vswitch" "vsw2-2" {
     provider             = alicloud.shanghai
     vpc_id               = alicloud_vpc.vpc2.id
     cidr_block           = "172.16.1.0/24"
     zone_id              = var.shanghai_az_list[1]
     vswitch_name         = "${var.pname}-vsw2-2"
     enable_ipv6          = true
     ipv6_cidr_block_mask = 4
   }
   
   # --- ecs1 ---
   resource "alicloud_instance" "ecs1" {
     provider             = alicloud.hangzhou
     instance_name        = "${var.pname}-ecs1"
     instance_type        = "ecs.e-c1m1.large"
     security_groups      = [alicloud_security_group.sg1.id]
     vswitch_id           = alicloud_vswitch.vsw1-1.id
     image_id             = "aliyun_3_x64_20G_qboot_alibase_20230727.vhd"
     system_disk_category = "cloud_essd"
     private_ip           = "10.0.0.1"
     ipv6_address_count   = 1
     instance_charge_type = "PostPaid"
     user_data = base64encode(<<-EOT
       #!/bin/bash
       echo ecs_ok > /root/ok.txt
       sudo acs-plugin-manager --exec --plugin=ecs-utils-ipv6
     EOT
     )
   }
   
   # --- ecs2 ---
   resource "alicloud_instance" "ecs2" {
     provider             = alicloud.shanghai
     instance_name        = "${var.pname}-ecs2"
     instance_type        = "ecs.e-c1m1.large"
     security_groups      = [alicloud_security_group.sg2.id]
     vswitch_id           = alicloud_vswitch.vsw2-1.id
     image_id             = "aliyun_3_x64_20G_qboot_alibase_20230727.vhd"
     system_disk_category = "cloud_essd"
     private_ip           = "172.16.0.1"
     ipv6_address_count   = 1
     instance_charge_type = "PostPaid"
     user_data = base64encode(<<-EOT
       #!/bin/bash
       echo ecs_ok > /root/ok.txt
       sudo acs-plugin-manager --exec --plugin=ecs-utils-ipv6
     EOT
     )
   }
   
   # セキュリティグループ
   resource "alicloud_security_group" "sg1" {
     provider = alicloud.hangzhou
     name     = "${var.pname}-sg1"
     vpc_id   = alicloud_vpc.vpc1.id
   }
   resource "alicloud_security_group_rule" "allow_inbound_ssh1" {
     provider          = alicloud.hangzhou
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "22/22"
     priority          = 1
     security_group_id = alicloud_security_group.sg1.id
     cidr_ip           = "0.0.0.0/0"
   }
   resource "alicloud_security_group_rule" "allow_inbound_icmp1" {
     provider          = alicloud.hangzhou
     type              = "ingress"
     ip_protocol       = "icmp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "-1/-1"
     priority          = 1
     security_group_id = alicloud_security_group.sg1.id
     cidr_ip           = "0.0.0.0/0"
   }
   resource "alicloud_security_group_rule" "allow_inbound_ipv6_icmp1" {
     provider          = alicloud.hangzhou
     type              = "ingress"
     ip_protocol       = "all"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "-1/-1"
     priority          = 1
     security_group_id = alicloud_security_group.sg1.id
     ipv6_cidr_ip      = "::/0"
   }
   
   resource "alicloud_security_group" "sg2" {
     provider = alicloud.shanghai
     name     = "${var.pname}-sg2"
     vpc_id   = alicloud_vpc.vpc2.id
   }
   resource "alicloud_security_group_rule" "allow_inbound_ssh2" {
     provider          = alicloud.shanghai
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "22/22"
     priority          = 1
     security_group_id = alicloud_security_group.sg2.id
     cidr_ip           = "0.0.0.0/0"
   }
   resource "alicloud_security_group_rule" "allow_inbound_icmp2" {
     provider          = alicloud.shanghai
     type              = "ingress"
     ip_protocol       = "icmp"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "-1/-1"
     priority          = 1
     security_group_id = alicloud_security_group.sg2.id
     cidr_ip           = "0.0.0.0/0"
   }
   resource "alicloud_security_group_rule" "allow_inbound_ipv6_icmp2" {
     provider = alicloud.shanghai
   
     type              = "ingress"
     ip_protocol       = "all"
     nic_type          = "intranet"
     policy            = "accept"
     port_range        = "-1/-1"
     priority          = 1
     security_group_id = alicloud_security_group.sg2.id
     ipv6_cidr_ip      = "::/0"
   }
   
   
   # --- CEN とトランジットルーター ---
   resource "alicloud_cen_instance" "cen1" {
     cen_instance_name = "${var.pname}-cen1"
   }
   resource "alicloud_cen_transit_router" "tr1" {
     provider            = alicloud.hangzhou
     transit_router_name = "${var.pname}-tr1"
     cen_id              = alicloud_cen_instance.cen1.id
   }
   resource "alicloud_cen_transit_router" "tr2" {
     provider            = alicloud.shanghai
     transit_router_name = "${var.pname}-tr2"
     cen_id              = alicloud_cen_instance.cen1.id
   }
   # トランジットルーターのシステムルートテーブル ID を取得します。
   data "alicloud_cen_transit_router_route_tables" "tr1" { # トランジットルーターのシステムルートテーブルを取得します。
     transit_router_id               = alicloud_cen_transit_router.tr1.transit_router_id
     transit_router_route_table_type = "System"
   }
   data "alicloud_cen_transit_router_route_tables" "tr2" {
     transit_router_id               = alicloud_cen_transit_router.tr2.transit_router_id
     transit_router_route_table_type = "System"
   }
   
   # トランジットルーターピア
   resource "alicloud_cen_transit_router_peer_attachment" "peer" {
     provider                      = alicloud.hangzhou
     cen_id                        = alicloud_cen_instance.cen1.id
     transit_router_id             = alicloud_cen_transit_router.tr1.transit_router_id
     peer_transit_router_region_id = var.shanghai_region_id
     peer_transit_router_id        = alicloud_cen_transit_router.tr2.transit_router_id
     bandwidth_type                = "DataTransfer"
     bandwidth                     = 1
     auto_publish_route_enabled    = true # デフォルトは false
   }
   resource "alicloud_cen_transit_router_route_table_association" "ass_peer1" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr1.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_peer_attachment.peer.transit_router_attachment_id
   }
   resource "alicloud_cen_transit_router_route_table_propagation" "propa_peer1" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr1.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_peer_attachment.peer.transit_router_attachment_id
   }
   resource "alicloud_cen_transit_router_route_table_association" "ass_peer2" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr2.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_peer_attachment.peer.transit_router_attachment_id
   }
   resource "alicloud_cen_transit_router_route_table_propagation" "propa_peer2" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr2.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_peer_attachment.peer.transit_router_attachment_id
   }
   
   # CIDR リスト
   variable "cidr_list" {
     description = "プライベート CIDR ブロックのリスト"
     type        = list(string)
     default     = ["10.0.0.0/8", "172.16.0.0/12", "192.168.0.0/16"]
   }
   
   # アタッチメント 1
   resource "alicloud_cen_transit_router_vpc_attachment" "attach1" {
     provider          = alicloud.hangzhou
     cen_id            = alicloud_cen_instance.cen1.id
     transit_router_id = alicloud_cen_transit_router.tr1.transit_router_id
     vpc_id            = alicloud_vpc.vpc1.id
     zone_mappings {
       zone_id    = var.hangzhou_az_list[0]
       vswitch_id = alicloud_vswitch.vsw1-1.id
     }
     zone_mappings {
       zone_id    = var.hangzhou_az_list[1]
       vswitch_id = alicloud_vswitch.vsw1-2.id
     }
     transit_router_vpc_attachment_name    = "attach1"
     transit_router_vpc_attachment_options = { ipv6Support : "enable" }
     auto_publish_route_enabled            = true # デフォルトは false
   }
   resource "alicloud_cen_transit_router_route_table_association" "ass1" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr1.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach1.transit_router_attachment_id
   }
   resource "alicloud_cen_transit_router_route_table_propagation" "propa1" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr1.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach1.transit_router_attachment_id
   }
   resource "alicloud_route_entry" "vpc1_to_tr1" {
     provider              = alicloud.hangzhou
     count                 = 3
     route_table_id        = alicloud_vpc.vpc1.route_table_id
     destination_cidrblock = var.cidr_list[count.index]
     nexthop_type          = "Attachment"
     nexthop_id            = alicloud_cen_transit_router_vpc_attachment.attach1.transit_router_attachment_id
   }
   
   # アタッチメント 2
   resource "alicloud_cen_transit_router_vpc_attachment" "attach2" {
     provider          = alicloud.shanghai
     cen_id            = alicloud_cen_instance.cen1.id
     transit_router_id = alicloud_cen_transit_router.tr2.transit_router_id
     vpc_id            = alicloud_vpc.vpc2.id
     zone_mappings {
       zone_id    = var.shanghai_az_list[0]
       vswitch_id = alicloud_vswitch.vsw2-1.id
     }
     zone_mappings {
       zone_id    = var.shanghai_az_list[1]
       vswitch_id = alicloud_vswitch.vsw2-2.id
     }
     transit_router_vpc_attachment_name    = "attach2"
     transit_router_vpc_attachment_options = { ipv6Support : "enable" }
     auto_publish_route_enabled            = true # デフォルトは false
   }
   resource "alicloud_cen_transit_router_route_table_association" "ass2" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr2.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach2.transit_router_attachment_id
   }
   resource "alicloud_cen_transit_router_route_table_propagation" "propa2" {
     transit_router_route_table_id = data.alicloud_cen_transit_router_route_tables.tr2.tables[0].id
     transit_router_attachment_id  = alicloud_cen_transit_router_vpc_attachment.attach2.transit_router_attachment_id
   }
   resource "alicloud_route_entry" "vpc2_to_tr2" {
     provider              = alicloud.shanghai
     count                 = 3
     route_table_id        = alicloud_vpc.vpc2.route_table_id
     destination_cidrblock = var.cidr_list[count.index]
     nexthop_type          = "Attachment"
     nexthop_id            = alicloud_cen_transit_router_vpc_attachment.attach2.transit_router_attachment_id
   }
   
   output "ecs1_login_address" {
     value = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=${var.hangzhou_region_id}&instanceId=${alicloud_instance.ecs1.id}"
   }
   
   output "ecs2_login_address" {
     value = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=${var.shanghai_region_id}&instanceId=${alicloud_instance.ecs2.id}"
   }

4. ディレクトリ内で Terraform を初期化します。

   terraform init

5. リソースを作成します。Terraform はまず実行プランをプレビューします。確認後、 yes と入力してリソースの作成を開始します。

   terraform apply

ステップ 2：接続性の確認

VPC1 と VPC2 の間の IPv6 通信が有効になりました。次のように接続性を確認します。

1. ECS2 インスタンス (インスタンス名： tf-CenIpv6-ecs2) にログインします。

   Terraform の出力で、ECS2 のログイン URL を見つけ、ブラウザにコピーして開きます。ログイン時には、認証方法として [一時 SSH キーベース] を選択します。

   Outputs：
   
   ecs1_login_address = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=cn-hangzhou&instanceId=i-bp1g"
   ecs2_login_address = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=cn-shanghai&instanceId=i-uf6j"

2. ECS2 インスタンスで、次のコマンドを実行して IPv6 アドレスを確認します。

   ifconfig

   [root@iZxxx byZ ~]# ifconfig
   eth0: flags=4163<UP,BROADCAST,RUNNING,MULTICAST>  mtu 1500
           inet 192.xxx.27  netmask 255.255.255.0  broadcast 192.xxx.255
           inet6 fe80::xxx:0:21c  prefixlen 64  scopeid 0x20<link>
           inet6 240b:xxx:xxx:a97c:9875  prefixlen 128  scopeid 0x0<global>
           ether xxx:1c  txqueuelen 1000  (Ethernet)
           RX packets 2063  bytes 387038 (377.9 KiB)
           RX errors 0  dropped 0  overruns 0  frame 0
           TX packets 2560  bytes 378127 (369.2 KiB)
           TX errors 0  dropped 0  overruns 0  carrier 0  collisions 0

   出力の inet6 240b:xxx:xxx:a97c:9875 prefixlen 128 scopeid 0x0<global> は、ECS2 に割り当てられた IPv6 グローバルアドレスです。

3. ECS1 インスタンス (インスタンス名： tf-CenIpv6-ecs1) にログインします。

   Terraform の出力で、ECS1 のログイン URL を見つけ、ブラウザにコピーして開きます。ログイン時には、認証方法として [一時 SSH キーベース] を選択します。

   Outputs：
   
   ecs1_login_address = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=cn-hangzhou&instanceId=i-bp1g4zxxx"
   ecs2_login_address = "https://ecs-workbench.alibabacloud.com/?from=EcsConsole&instanceType=ecs&regionId=cn-shanghai&instanceId=i-uf6ja1xxx"

4. 次のコマンドを実行して、ECS1 インスタンスから VPC2 の ECS2 インスタンスに ping を実行し、接続性を確認します。

   ping6 <ECS2 の IPv6 アドレス>

   [root@iZ5ts             hipZ ~]# ping6 240b:xxx:xxx:xxx:xxx:a97c:9875
   PING 240b:                          a97c:9875(240b:4xxx:xxx:xxx:xxx:a97c:9875) 56 data bytes
   64 bytes from 240b:xxx:xxx:xxx:xxx:a97c:9875: icmp_seq=1 ttl=62 time=192 ms
   64 bytes from 240b:xxx:xxx:xxx:xxx:a97c:9875: icmp_seq=2 ttl=62 time=191 ms
   64 bytes from 240b:xxx:xxx:xxx:xxx:a97c:9875: icmp_seq=3 ttl=62 time=191 ms
   64 bytes from 240b:xxx:xxx:xxx:xxx:a97c:9875: icmp_seq=4 ttl=62 time=191 ms
   64 bytes from 240b:xxx:xxx:xxx:xxx:a97c:9875: icmp_seq=5 ttl=62 time=191 ms
   ^Z
   [2]+  Stopped                 ping6 240b:xxx:xxx:xxx:xxx:a97c:9875

   図に示されている応答は、VPC 間の IPv6 通信が成功していることを示します。

ステップ 3：リソースの解放

リソースが不要になったら、次のコマンドを実行してリソースを解放します。

terraform destroy --auto-approve